Problème de collage des données sur une plage : erreur d'exécution 13

**capi81** · 13/02/2026, 11h23

Bonjour
Je viens ce matin vous solliciter de l'aide.
En effet, j'ai un fichier qui me permet de gérer la facturation de mon restaurant depuis 2020.
Depuis le mardi, nous rencontrons un problème avec le même fichier qui n'a pas été modifié.
Je signale aussi que nous n'avons pas changé de version windows ou office.
Voici le problème;
lorsqu'on lance l'usf, on renseigne le mdp (DAN), on choisi le serveur(test1 ou test2), lorsqu'on fini de renseigner les éléments de la commande et qu'on valide par la commande "VALIDER", on reçoit le message d'erreur suivant : erreur d'exécition "13" , incompatibilité de type.
Il faut noter que la validation de la commande entraine la copie des données vers la feuille "ETAT_VENTE" et le débogage souligne la ligne de ce code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

.Range("d" & ligExport) = CDbl(Me.Controls("TextBox_Mtant" & I))

Pour les besoins de teste, je vous partage le lien du fichier:
https://www.transfernow.net/dl/202602138hWkGM2V

ci-dessous le code intégral pour appréciation:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Private Sub Etat_Vente()
Dim ligExport As Long
Dim I As Integer
 
'Ce code permet d'alimenter la feuil ETAT_VENTE
ligExport = Feuil2.Range("f" & Rows.Count).End(xlUp).Row + 1
 
'Affectation de la cellule contanant le numéro de facture à incrémenter
 
If Me.TextBox_Réf <> "" Then
    For I = 1 To 10 'pour toutes les lignes
        If Me.Controls("ComboBox_Bois" & I) <> "" And Me.Controls("TextBox_Qte" & I) <> "" Then  'si tous les contrôles de la ligne sont remplis
 
            'export
            With Feuil2
                .Unprotect "zzzzz"
                .Range("a" & ligExport) = Date - IIf(Hour(Now) < 6, 1, 0)
                .Range("b" & ligExport) = Me.Controls("ComboBox_Bois" & I)
                .Range("c" & ligExport) = CDbl(Me.Controls("TextBox_Qte" & I))
                .Range("d" & ligExport) = CDbl(Me.Controls("TextBox_Mtant" & I))
                .Range("e" & ligExport) = Me.Serveur
                .Range("f" & ligExport) = Me.TextBox_Réf
                .Range("g" & ligExport) = Me.CodeExpl
                .Range("h" & ligExport) = CDbl(Val(Me.TextBox_Encais))
                .Range("i" & ligExport) = CDbl(Val(Me.TextBox_Reste))
                .Range("j" & ligExport) = CDbl(Val(Me.TextBox_Avoir))
                .Range("k" & ligExport) = Format(Now(), "hh:mm")
                .Range("o" & ligExport) = CDbl(Me.Controls("TextBox_PV" & I))
            End With
 
            'incrémentation de la ligne
            ligExport = ligExport + 1
        End If
    Next I
End If
'Feuil2.Protect "zzzzz"
 
End Sub

Bonne te heureuse année 2026

**Informt2025** · 13/02/2026, 13h41

Je ne suis pas sur mais les prix sont formatés avec le séparateur millier du genre 6 600
ajouter Val

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

.Range("d" & ligExport) =  CDbl(Val(Me.Controls("TextBox_Mtant" & I)))

**Nain porte koi** · 13/02/2026, 13h53

Hello,

je pense que Informt2025 à raison, ou alors les séparateurs de millier et/ou décimal ont changés.

Je voudrais aussi vous signaler qu'il y a pas mal d'erreur dans les macros.
Bien qu'il y ait la commande "Option Explicit" au début du module il y a des variables non déclarées et des noms de feuille fausses.
Lancer une compilation pour vous en apercevoir (Déboguage, Compiler VBAproject)

Dans Sub Vider_USF il est noté With Feuil13 mais celle ci n'existe pas/plus

un truc qui fonctionne mais qui est bizarre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
        For I = 1 To 10
            .Controls("Combobox_bois" & I) = ""
            .Controls("Textbox_Qte" & I) = ""
            .Controls("TextBox_PV" & I) = ""
            .Controls("TextBox_Mtant" & I) = ""
            .TextBox_Réf = ""
            .Serveur = ""
            .TextBox_Encais = ""
            .TextBox_Avoir = ""
            .TextBox_Reste = ""
        Next I

devrait être défini comme ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
        For I = 1 To 10
            .Controls("Combobox_bois" & I) = ""
            .Controls("Textbox_Qte" & I) = ""
            .Controls("TextBox_PV" & I) = ""
            .Controls("TextBox_Mtant" & I) = ""
        Next I
        .TextBox_Réf = ""
        .Serveur = ""
        .TextBox_Encais = ""
        .TextBox_Avoir = ""
        .TextBox_Reste = ""

pas besoin de vider 10 fois les noms simples

**capi81** · 13/02/2026, 16h15

Bonsoir Informat2025, Nain porte koi
Informat2025: merci pour votre solution qui fonctionne bien.
Je remercie également Nain porte koi pour ses solutions que j'ai aussi appréciées.
J'ai omis de signaler que lorsque je renseigne le montant de l'encaissement dans le textbox "TextBox_Encais", il y'a chamboullement.
Autrement dit, le montant saisi change de valeur et cela n'a rien a voir avec le montant encaissé que le caissier souhaitait saisir.
Merci de m'aider à lever cette préoccupation.

Encore merci pour tout

**Nain porte koi** · 13/02/2026, 17h00

le montant saisi change de valeur et cela n'a rien a voir avec le montant encaissé

Ca change dans quelle proportion ?
Si le caissier saisie 123 et que vous retrouver 456 là y'a un gros problème, mais si c'est 10 000 et que vous retrouver 10 ou 100 y'a déjà une certaine logique

Vous êtes sûr de ne pas avoir touché aux séparateurs de millier et/ou décimal ?

**capi81** · 13/02/2026, 17h34

Bonsoir Nain porte koi
Je crois avoir compris.
voici le code qui initial qui créait le bug:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

TextBox_Encais = Format(TextBox_Encais, "# ##0")

voici le code corrigé tenant compte des acquits du coaching reçu aujourd'hui qui fonctionne bien:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

TextBox_Encais = Format(Val(TextBox_Encais), "# ##0")

J'espère que ma logique ne vas pas me rattraper

Encore merci

**Nain porte koi** · 13/02/2026, 17h38

Le problème que vous allez générer ici

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

TextBox_Encais = Format(Val(TextBox_Encais), "# ##0")

c'est que ça n'est plus une valeur mais un texte, vous ne pourrez donc plus faire de calcul sur TextBox_Encais

**Valtrase** · 13/02/2026, 17h40

Bonjour à tous,
Ha ces mise en formes et conversions....
Si nous regardons le code sur la méthode Change de la zone de texte TextBox_Encais nous voyons cela :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Private Sub TextBox_Encais_Change()
    If TextBox_Total.Value > 0 Then
        TextBox_Reste = Val(TextBox_Encais.Value) - Val(TextBox_Total.Value)
        TextBox_Reste = Format$(TextBox_Reste, "# ##0")
        TextBox_Encais = Format$(TextBox_Encais, "# ##0")
    ElseIf TextBox_Total.Value < 0 Then
        TextBox_Reste = Val(TextBox_Encais.Value) + Val(TextBox_Total.Value)
        TextBox_Reste = Format$(TextBox_Reste, "# ##0")
        TextBox_Encais = Format$(TextBox_Encais, "# ##0")
    End If
End Sub

D'abords un peu de lecture concernant la fonction Val().
Si l'utilisateur entre un chiffre avec une virgule, la fonction Val ne va récupérer que la partie avant la virgule, ce qui aura pour effet de changer le résultat des calculs.
Il faut donc remplacer la virgule par un point et pour cela une petite fonction fera le travail, tout en laissant le visuel aux format Français.
Si vous voulez l'utiliser sur plusieurs formulaires mettez-la dans un module déclarée en Public. Si juste besoin sur le formulaire Facturier_Caisse Alors la mettre dans le module du formulaire et déclarée en Private.
Par contre il faudra changer tous vos appels....

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Public Function TextToDouble(Txt As String) As Double
    Dim CleanVal As String
 
    ' // Supprime les espaces (standards et insécables)
    CleanVal = Replace(Txt, " ", "")
    CleanVal = Replace(CleanVal, Chr(160), "") ' Espace insécable souvent utilisé dans Excel
 
    ' // Harmonise le séparateur décimal (tout en point pour Val)
    CleanVal = Replace(CleanVal, ",", ".")
 
    ' // Conversion sécurisée
    If IsNumeric(CleanVal) Then
        ' Val() est robuste mais CDbl() respecte mieux les grands nombres
        ' Ici, on utilise Val car on a forcé le point
        TextToDouble = Val(CleanVal)
    Else
        TextToDouble = 0
    End If
End Function

Et pour l'appel cela donnerait:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Private Sub TextBox_Encais_Change()
    With TextBox_Reste
        If TextBox_Total.Value > 0 Then
            .Value = TextToDouble(TextBox_Encais.Value) - TextToDouble(TextBox_Total.Value)
            .Value = Format$(.Value, "# ##0")
            TextBox_Encais.Value = Format$(TextBox_Encais, "# ##0")
        ElseIf TextBox_Total.Value < 0 Then
            .Value = TextToDouble(TextBox_Encais.Value) + TextToDouble(TextBox_Total.Value)
            .Value = Format$(.Value, "# ##0")
            TextBox_Encais.Value = Format$(TextBox_Encais.Value, "# ##0")
        End If
    End With
End Sub

**tototiti2008** · 13/02/2026, 18h28

Bonjour,

J'ai pas tout suivi la discussion, mais de mon expérience, tout ce qui est en VBA doit être au format américain (ou en tout cas dans la plupart des cas, c'est tordu donc il y aura surement une exception quelque part)

par exemple, si je veux qu'il m'affiche un nombre au format 1 523,40 dans une msgbox, je ferais

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub test()
Dim Nb As Double
    Nb = 1523.4
    MsgBox Format(Nb, "#,##0.00")
End Sub

Donc utiliser les séparateurs américains dans le format entre guillemets, qui seront traduits automatiquement aux formats locaux en passant à Excel
Je sais pas si ça aide ou si je suis à coté de la plaque

**capi81** · 13/02/2026, 19h10

Bonsoir
je remercie les nouveaux intervenants avec leurs riches contributions.
@Valtrase : je voulais vous apporter cette petite précision : en effet, dans nos saisies, les virgules n'interviennent pas. Est-ce votre solution tient toujours avec cette donne ou je pourrai conserver le code ci-dessous en l'état sans problème?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Private Sub TextBox_Encais_Change()
    If TextBox_Total.Value > 0 Then
        TextBox_Reste = Val(TextBox_Encais.Value) - Val(TextBox_Total.Value)
        TextBox_Reste = Format$(TextBox_Reste, "# ##0")
        TextBox_Encais = Format$(TextBox_Encais, "# ##0")
    ElseIf TextBox_Total.Value < 0 Then
        TextBox_Reste = Val(TextBox_Encais.Value) + Val(TextBox_Total.Value)
        TextBox_Reste = Format$(TextBox_Reste, "# ##0")
        TextBox_Encais = Format$(TextBox_Encais, "# ##0")
    End If
End Sub

Nain porte koi : tenant compte de votre observation sur mon code, je dois le maintenir comme cela vous voulez dire:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

TextBox_Encais = Format(TextBox_Encais, "# ##0")

En rappel le textbox_encais constate le montant remis par le client tout simplement.

**Valtrase** · 13/02/2026, 19h38

@capi81,
Je serais tenté de dire, qui peut le plus peut le moins, Par contre si pas de virgule je ne vois pas ce qui interfère dans le code pouvez-vous nous donner un peu plus d'explications ? Valeurs saisies et résultats.
Cela nous aidera, pour vous aiguiller au mieux.

**Informt2025** · 13/02/2026, 21h26

Normalement le formatage ne doit pas entrer dans les calcules mais juste pour l'affichage des données surtout si le programme est utilisé sur plusieurs postes qui pourraient avoir des formats numéros différents c'est une erreur de design.

cette ligne à corriger aussi (prix unitaire) je pense

.Range("o" & ligExport) = CDbl(Me.Controls("TextBox_PV" & I))

Un autre remarque lorsque TextBox_Total est modifié le champs Rest reste inchangé avec une ancienne valeur
ajouter dans TextBox_Total_Change

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub TextBox_Total_Change()
TextBox_Reste = ""
End Sub

**capi81** · 14/02/2026, 00h19

Envoyé par Valtrase

@capi81,
Je serais tenté de dire, qui peut le plus peut le moins, Par contre si pas de virgule je ne vois pas ce qui interfère dans le code pouvez-vous nous donner un peu plus d'explications ? Valeurs saisies et résultats.
Cela nous aidera, pour vous aiguiller au mieux.

Bonsoir Valtrase
en réalité, j'ai constaté que le textbox_encaiss, lorsque je commence à saisir le montant reçu du client, je constate une anomalie dans la saisie. par exemple lorsque je commence à saisir 5000 comme montant encaissé, à partir de 50 ou 500 saisi, le montant du textbox_encais change brutalement, je lis 365xx (x étant d'autres chiffre), ce qui n'a rien a voir avec les 5000 que je devrais saisir. c'est ce qui ma amené à intégrer "val" dans le format et ca marche. si c'est du bricolage, merci de m'aider avec la meilleure formule.

**capi81** · 14/02/2026, 00h24

Envoyé par Informt2025

Normalement le formatage ne doit pas entrer dans les calcules mais juste pour l'affichage des données surtout si le programme est utilisé sur plusieurs postes qui pourraient avoir des formats numéros différents c'est une erreur de design.

cette ligne à corriger aussi (prix unitaire) je pense

.Range("o" & ligExport) = CDbl(Me.Controls("TextBox_PV" & I))

Un autre remarque lorsque TextBox_Total est modifié le champs Rest reste inchangé avec une ancienne valeur
ajouter dans TextBox_Total_Change

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub TextBox_Total_Change()
TextBox_Reste = ""
End Sub

Bonsoir Informt2025
Le code suivant

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

.Range("o" & ligExport) = CDbl(Me.Controls("TextBox_PV" & I))

a été modifié.
Voici la nouvelle donne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

.Range("o" & ligExport) = CDbl(val(Me.Controls("TextBox_PV") & I))

n autre remarque lorsque TextBox_Total est modifié le champs Rest reste inchangé avec une ancienne valeur
ajouter dans TextBox_Total_Change

Effectivement, c'est lorsqu'on renseigne le textbox_encais que le champ reste est impacté sinon ca ne joue pas trop sur le résultat souhaité.

**Informt2025** · 14/02/2026, 13h59

Bonjour,

J'ai créé un module de classe pour regrouper les Textboxs et les ComboBoxs c'est plus propre pour gérer les éventements et le formatage, une propriété a été ajoutée à la fiche Fields("nom du controle") pour lire et écrire dans contrôles qui utilisent le formatage.

Effectivement, c'est lorsqu'on renseigne le textbox_encais que le champ reste est impacté sinon ca ne joue pas trop sur le résultat souhaité.

Rest est consulté au moment de la validation et comparé au Total donc il doit être recalculé automatiquement pour éviter qu'une valeur erronée soit enregistrée, probablement l'utilisateur suit une logique bien précise mais ça n’empêche pas de modifier un article à la dernière minute.

Dans le nouveau fichier si tu ne veux pas le calcul auto désactive cette ligne:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Case "TextBox_Total": UpdateRestAvoir

**capi81** · 14/02/2026, 18h46

Bonsoir Informt2025
Je vous remercie pour le travail abattu dont le but est de faciliter les choses.
Je viens de réaliser quelques tests et voici mes constats:
Lorsque je choisi un produit, après avoir renseigné sa quantité(2 par exemple),le montant qui s'affiche dans textbox_montant est -547862 au lieu de 1400.
Cela signifie qu'il y'a un problème dans le calcul.

Merci de revoir

**Valtrase** · 14/02/2026, 20h26

Bonsoir à tous,
@capi81,
Je pense que l'utilisation de plusieurs zones de texte est un peu restrictif non ? (Si plus de dix entrées).
Ne serait-il pas plus judicieux d'utiliser une zone de liste ? (A moins que vous vouliez avoir la possibilité de changer le prix de chaque entrée.)

**capi81** · 16/02/2026, 10h18

Bonjour Valtrase
Merci pour votre proposition.
Un exemple me permettrait de mieux l'apprécier si possible.

Cordialement

**Thumb down** · 16/02/2026, 14h28

bonjour,
cdbl prend en compte les paramètres régionaux.

si sur un PC qui dispose d'un pavé numérique tu écriras [.] point et non [,] virgule comment décimal et la erreur.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

.Range("d" & ligExport) = val(replace(Me.Controls("TextBox_Mtant" & I),",","."))

val utilise le point comme décimal, en remplaçant la virgule par le point tu n'auras plus ce genre d'erreur.

cdbl("10.20") genaire un erreur , type incompatible, si la décimal dans les paramètres régionaux est la virgule.