Discussion :

[tototiti2008]

Bonjour,

J'essaie d'analyser le contenu de cellules et j'aimerais faire un code VBA qui arrive a déterminer le type de données le plus probable stocké dans la cellule
Les types différenciés que je voudrais identifier sont :
Type Texte
Type Nombre entier
Type Nombre décimal
Type Date (sans heure)
Type Heure (sans date)
Type Date Heure

Je pensais commencer par analyser le format de cellule appliqué à la cellule, et si le format est Standard, analyser la valeur stockée
Je me demandais si je me compliquais la vie et qu'il y avait une méthode magique dont j'ignorais l'existence, ou si ça vous semble cohérent comme approche

Merci

[Informt2025]

Bonjour,

Pourquoi VarType n'a pas marché ou tu veux convertir les données à partir du texte brute

[tototiti2008]

Bonjour,

non, si les données sont en texte brut, je veux que ça soit considéré comme du texte
ce qui m'intéresse c'est la façon dont la cellule l'interprète
vartype est intéressant, merci,
mais vartype refait une conversion, j'aurais aimé savoir le type déjà interprété par la cellule
et vartype a des limites (ça pourrait être une bonne base tout de même)
vartype renvoie date pour les dates seules et les date heure
vartype renvoie nombre décimal pour les heures seules

[tototiti2008]

Re,

mais vartype refait une conversion

Pour être plus précis, il n'y a pas de type heure en VBA, bien qu'Excel semble interpréter les heures correctement
Donc on a un petit décalage de type de ce côté là

[Thumb down]

bonjour,
tu es sous quelle système d'exploitation, windows, Mac ?

tu peux fournir un fichier annonimisé ?

[Valtrase]

Bonjour à tous,
C'est possible avec une petite fonction qui utilise la fonction VBA 'TypeName'

Pour la fonction TypeName c'est par ici...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Function GetTypeOff(cellule As Range) As Variant
    If cellule.Value <> vbNullString Then
        GetTypeOff = TypeName(cellule.Value)
    End If
End Function

[Informt2025]

Il est très difficile pour reconnaître le type Time qu'à part le nombre format qui est enregistré comme double.
donc soit cell.NumberFormat
ou évaluer la formule Cellule("format'), pour récupérer la catégorie du format
MsgBox Evaluate("=CELL(""format"",A3)")

[tototiti2008]

Bonjour,

Merci de vos réponses

tu es sous quelle système d'exploitation, windows, Mac ?

Windows 10
Fichier joint (juste des cellules avec les différents types que j'aimerais identifier)

TypeName a les mêmes résultats que VarType,
pas de différenciation Entier/Décimal (ça va pas trop difficile à compléter par des tests)
pas de différentiation Date/Date Heure (ça va aussi)
pas de différentiation Décimal/Heure (là je vais être obligé de lire le Numberformat de la cellule, je pense)

[tototiti2008]

Re,

Voilà ce que ça donne (ajouté les booléens, vides et une catégorie autre)
Merci de vos propositions qui m'ont mis sur la voie

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
Enum TypCol
    EstVide = -1
    EstTexte = 0
    EstEntier = 1
    EstDec = 2
    EstDate = 3
    EstHeure = 4
    EstDateHeure = 5
    EstBooleen = 6
    EstAutre = 7
End Enum
 
Function AnalyseTypeCel(Cellule As Range) As TypCol
    If VarType(Cellule.Value) = 10 Then 'message d'erreur
        AnalyseTypeCel = EstAutre
    Else
        If Cellule.Value <> "" Then
            Select Case VarType(Cellule.Value)
                Case 5 'Décimal
                    If Int(Cellule.Value) = Cellule.Value Then
                        AnalyseTypeCel = EstEntier
                    Else
                        If Cellule.NumberFormat Like "*h*" Then
                            AnalyseTypeCel = EstHeure
                        Else
                            AnalyseTypeCel = EstDec
                        End If
                    End If
                Case 7 'Date
                    If Int(Cellule.Value) = Cellule.Value Then
                        AnalyseTypeCel = EstDate
                    Else
                        AnalyseTypeCel = EstDateHeure
                    End If
                Case 8 'Texte
                    AnalyseTypeCel = EstTexte
                Case 11 'Booleen
                   AnalyseTypeCel = EstBooleen
                Case Else
                   AnalyseTypeCel = EstAutre
            End Select
        Else
            AnalyseTypeCel = EstVide
        End If
    End If
End Function

[Thumb down]

bonjour,

Valeur	Constante	Type
0	vbEmpty	Non initialisé
1	vbNull	Null
2	vbInteger	Integer (16 bits)
3	vbLong	Long (32 bits)
4	vbSingle	Single
5	vbDouble	Double
6	vbCurrency	Currency
7	vbDate	Date
8	vbString	String
9	vbObject	Object
10	vbError	Erreur Excel
11	vbBoolean	Boolean
12	vbVariant	Variant
13	vbDataObject	DataObject
14	vbDecimal	Decimal (dans Variant)
17	vbByte	Byte

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub test()
Debug.Print MyType(ActiveCell), MyType(ActiveCell, True)
End Sub
Function MyType(Cellule As Range, Optional txt As Boolean)
Dim Tp: Tp = Array(" Non initialisé", "Null", "Integer", "Long", "Single", "Double", "Currency", "Date", "String", "Object", "Erreur Excel", "Boolean ", "Variant ", "DataObject", "Decimal (dans Variant) ", "Byte", "LongLong (VBA 64 bits) ")
 Select Case VarType(Cellule.Value)
    Case 5: MyType = IIf(Int(Cellule) = Cellule, 2, 5)
    Case Else: MyType = VarType(Cellule.Value)
 End Select
 If txt Then MyType = Tp(MyType)
End Function