Discussion :

[Qwazerty]

Salut

J'importe une liste Sharepoint via Power Query.
Sharepoint utilise un encodage des caractères spéciaux dans les noms de champs. C'est le code Hexa du caractère enficher dans une chaine remarquable. Par exemple Espace à pour valeur Hexa 20, Sharepoint remplace les Espace par _x0020_.

[Edit]
Le but serait d'isoler la partie numérique pour ensuite faire la conversion.
Les noms ressemblent à ça "Date_x0020_de_x0020_r_x00e9_alis", il peut y avoir plusieurs caractères spéciaux par nom.

Je voudrais autant que possible éviter d'avoir un tableau de conversion
[/Edit]

J'ai bien tenter Chat GPT mais les code qu'il me sort soit plante, soit ne font pas le job.

Quelqu'un aurait-il une solution pour remettre les caractères en lieu est place des codes implantés par Sharepoint?

++
Qwaz

[Qwazerty]

Salut

En guidant ChatGPT sur une logique de split, convertion, join le résultat est mieux

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
//Code créé par Chat GPT avec un peu d'aide pour le guider 
//Et ce site pour Expression.Evaluate trouvé dnas les commentaires https://blog.crossjoin.co.uk/2018/09/23/converting-decimal-numbers-to-hexadecimal-in-power-query-m/
//Il permet de remplacer les codes _x0000_ par l'équivalent unicod
let
    Fct_SP_Car_Hexa_To_String = (originalName as text) as text =>
    let
        Parts = Text.Split(originalName, "_x"),
        Transformed = List.Transform(Parts, each
            if Text.Length(_) >= 5 and Text.Range(_, 0, 4) = Text.Select(Text.Range(_, 0, 4), {"0".."9", "a".."f", "A".."F"}) then
                Character.FromNumber(Expression.Evaluate("0x" & Text.Range(_, 0, 4))) & Text.Range(_, 5)
            else
                _
        ),
        Result = Text.Combine(Transformed, "")
    in
        Result
in
    Fct_SP_Car_Hexa_To_String

ChatGPT sort quand même souvent des fonctions qui sont sensées être native mais qui n'existe pas au final.
Ou des utilisation de fonctions qui ne sont pas correct. Il voulait par exemple utiliser Number.FromText("0x0026"), sauf que ça ne fonctionne pas, j'ai trouvé le contournement sur le site Chris Webb's, dans un commentaire qui proposait l'utilisation de Expression.Evaluate

Merci à ceux qui auront prit le temps de me lire
++
Qwaz

[Raccourcix]

Bonjour

le temps de me plonger dans la question ce matin il y a quelques minutes que ChatGPT me devance lorsque je veux poster ma réponse

je propose

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
= Text.Combine(
      List.Transform(
        Text.Split([un champ texte], "_"), 
        each if Text.StartsWith(_, "x") and Text.Length(_)=5
          then (try Character.FromNumber(Number.From(Text.End(_,4))) otherwise _)
          else _))

Stéphane

[Qwazerty]

Salut

Je te remercie pour cette proposition.
J'ai intégré ton code mais il y a un soucis, le split étant fait à partit de "_", j'ai des noms de champs qui intègrent des underscores et ceux-ci ne doivent pas être remplacer.

J'aurai voulu modifier en remplaçant par "_x" mais ça ne fonctionnera pas dans la suite, même,en testant si la chaine commence par "0", le fait de couper par "_" permettait d'avoir uniquement la valeur hexa et il n'est donc pas possible de tester si la longueur vaut 4, puisque du texte reste accroché à la suite.

Peut-être en testant si 0 au début et "_" au 5ème caractère, je vais regarder

[Edit]
J'ai tenté ça mais il ne replace pas comme il faut et j'ai du mal avec le débogage des expression dans Power Query

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
= (originalName as text) as text =>
    let
        Result = Text.Combine(
        List.Transform(
            Text.Split(originalName, "_x"), 
            each if Text.StartsWith(_, "0") and Text.Middle(_,5,1)="_" then (
                try Text.Replace(_,  Text.Start(_,5),Character.FromNumber(Expression.Evaluate("0x" & Text.Start(_,4)))) otherwise _
            ) else _
        ))
    in
        Result

J'ai découpé en partie

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
let
    Source = "0020_de",
    Cara = Character.FromNumber(Expression.Evaluate("0x" & Text.Start(Source,4))),
    Modif = Text.Replace(Source, Text.Start(Source,5),Cara)
in
    Modif

Et là ça fonctionne...

[/Edit]
++
Qwaz

[Raccourcix]

Je n'ai pas le temps de faire des tests maintenant mais la fonction Text.Middle commence à l'index 0. Donc pour le _ en 5eme position c'est Text.Middle(_,4,1)="_".
Stéphane

[Qwazerty]

Salut

Bien vu, c'était le soucis

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
let
    Fct_SP_Car_Hexa_To_String_Raccourcix = (originalName as text) as text =>
    let
        Result = Text.Combine(
        List.Transform(
            Text.Split(originalName, "_x"), 
            each if Text.StartsWith(_, "0") and Text.Middle(_,4,1)="_" then (
                Text.Replace(_,  Text.Start(_,5),Character.FromNumber(Expression.Evaluate("0x" & Text.Start(_,4))))
            ) else _
        ))
    in
        Result
in
    Fct_SP_Car_Hexa_To_String_Raccourcix

Je te remercie, du coup je vais utiliser ce code ci, intelligence humaine n'est pas encore morte

++
Qwaz