Discussion :

[Olivierporcinet]

Bonjour,

Voici mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub Worksheet_Change(ByVal Target As Range)
    If Not (Application.Intersect(Range("D7:D31"), Target) Is Nothing) Then
        MsgBox "Cell " & Target.Address & " has changed."
    End If
End Sub

Celui-ci fonctionne parfaitement mais ne fonctionne pas si la cellule est calculée.

J'aimerais que ce code soit en colonne "G" et se base sur la colonne "D"

Formule en colonne "G" : =DATEDIF(D7;AUJOURDHUI();"y"


Qui peut m'aider, merci.

Belle journée.

[Malick]

Salut,

Je pense que tu pourrais explorer la piste avec Worksheet_Calculate, car Worksheet_Change intervient lorsqu'il y a une modification d'une cellule directement par l'utilisateur et non suite à une modification par calcul.

[Olivierporcinet]

oui, merci, c'est ce que je pensais mais je bloque avec Worksheet.Calculate

[Franc]

Salut, voici une possibilité. On stocke les valeurs initiales à l'activation de la feuille, ensuite on détecte les changements suite à un recalcul avec Worksheet_Calculate.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Dim OldValues As Object
 
Private Sub Worksheet_Activate()
    ' Stockage des anciennes valeurs de la colonne G
    Set OldValues = CreateObject("Scripting.Dictionary")
 
    Dim cell As Range
    For Each cell In Range("G7:G31")
        OldValues(cell.Address) = cell.Value
    Next cell
End Sub
 
Private Sub Worksheet_Calculate()
    Dim cell As Range
    For Each cell In Range("G7:G31")
        ' Vérifier si la valeur a changé
        If OldValues.Exists(cell.Address) Then
            If OldValues(cell.Address) <> cell.Value Then
                MsgBox "La cellule " & cell.Address & " a changé. Nouvelle valeur : " & cell.Value
                ' Mettre à jour la valeur stockée
                OldValues(cell.Address) = cell.Value
            End If
        Else
            ' Ajouter une nouvelle entrée si la cellule n'existe pas encore dans le dictionnaire
            OldValues(cell.Address) = cell.Value
        End If
    Next cell
End Sub

[Olivierporcinet]

merci mais j'ai une erreur dans WorkSheet_Calculate :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 If OldValues.Exists(cell.Address) Then

[Franc]

Quelle erreur précisément ?

[Olivierporcinet]

"Erreur d'exécution '91'

Variable objet ou variable de bloc With non définie

[Franc]

Ajoute cette ligne au début de la macro Worksheet_Calculate:
If OldValues Is Nothing Then Set OldValues = CreateObject("Scripting.Dictionary")

Si ça ne fonctionne pas, envoie un petit fichier exemple avec quelques données anonymisées pour tester.

[Olivierporcinet]

Tout fonctionne.

Un super grand merci.

Belle après-midi.