Discussion :

[ag-capdft57]

Bonjour.

Après presque 2 jours de recherches infructueuse pour créer une macro, je viens solliciter votre aide.

Voici mon besoin :

Je voudrais copier toutes les valeurs des cellules de la colonne B d'un tableau Excel nommé Tableau1 situé dans une feuille nommée Test1 dans la première cellule vide de la colonne B d'un tableau Excel nommé Tableau2, situé dans une feuille nommée Test2.

Voici mon code actuel qui me renvoi une erreur :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Sub CopierValeursColonneB()
 
    Dim wsSource As Worksheet
    Dim wsDest As Worksheet
    Dim sourceTable As ListObject
    Dim destTable As ListObject
    Dim sourceRange As Range
    Dim destRange As Range
    Dim nextRow As Long
 
    ' Définir les feuilles de calcul
    Set wsSource = ThisWorkbook.Sheets("Test2")
    Set wsDest = ThisWorkbook.Sheets("Test1")
 
    ' Définir les tableaux
    Set sourceTable = wsSource.ListObjects("Tableau1")
    Set destTable = wsDest.ListObjects("Tableau2")
 
    ' Définir la plage de cellules à copier (colonne B du tableau source)
    Set sourceRange = sourceTable.ListColumns("B").DataBodyRange
 
    ' Trouver la première cellule vide dans la colonne B du tableau de destination
    With destTable.ListColumns("B").DataBodyRange
        If .Cells(.Cells.Count).Value <> "" Then
            nextRow = .Cells(.Cells.Count).Row + 1
        Else
            nextRow = .Find("*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row + 1
        End If
    End With
 
    ' Définir la plage de cellules de destination
    Set destRange = destTable.ListColumns("B").DataBodyRange.Cells(nextRow, 1).Resize(sourceRange.Rows.Count, 1)
 
    ' Copier les valeurs des cellules de la colonne B du tableau source vers la colonne B du tableau de destination
    destRange.Value = sourceRange.Value
 
End Sub

Systématiquement, je reçois l'erreur 9 "L'indice n'appartient pas à la sélection".

Si j'utilise cette macro sur des plages de données (en l'adaptant), la copie des données se fait bien.

Avez-vous une idée d'où provient le problème ?

[Malick]

Salut,

Peut-être des pistes :

Est-ce qu'il n'y a pas inversions sur la définition des variables ?

' Définir les feuilles de calcul
Set wsSource = ThisWorkbook.Sheets("Test2") ====> la feuille Source c'est Test1
Set wsDest = ThisWorkbook.Sheets("Test1") ====> la feuille Destination c'est Test2

Est-ce que les tableaux existent bien respectivement dans les deux feuilles ? Sinon VBA enverra aussi l'erreur 9

Aussi, ListColumns("B") est censé prendre le nom de la colonne du tableau en question et non pas la lettre B qui représente le nom de la colonne de cette feuille Excel.

[ag-capdft57]

Merci pour votre réponse rapide Malick.

Le problème venait effectivement fait qu'il fallait mettre le nom de la colonne du tableau et non pas celui de la colonne de la feuille.

Cependant, ma macro bloque maintenant sur la ligne suivante :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

nextRow = .Find("*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row + 1

avec le message d'erreur suivant : "variable objet ou variable de bloc with non définie".

Une idée ?

[Malick]

Peut-être qu'il faudra reposter le code complet après la correction faite sur le nom de colonne.
Cela permettra aux éventuels membres de pouvoir aider aussi

[Philippe Tulliez]

Bonjour,
Si vous expliquiez avec illustration à l'appui ce que vous cherchez à faire ce serait plus simple que d'afficher un code VBA qui nous oblige à traduire vos intentions.

[ag-capdft57]

Bonjour.

J'ai mis mon fichier en pièce jointe (j'espère avoir suivi la bonne procédure, étant donné que c'est la première fois).

Le but est de copier les valeurs au format texte (il s'agit de formule dans le véritable fichier) de la colonne B "Concaténation fournisseur + lot / code BPU" de la feuille 'VHM (Lot 1)"
dans la colonne B "Fournisseur - lot - Référence BPU" du tableau de la feuille 'PIECES EN STOCKS' et ce à partir de la première cellule vide de la colonne B.

Pour répondre à la demande de Malick, voici le code bloquant à la ligne 30 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Sub CopierValeursColonnesTexte()
 
    Dim wsSource As Worksheet
    Dim wsDest As Worksheet
    Dim sourceTable As ListObject
    Dim destTable As ListObject
    Dim sourceRange As Range
    Dim nextRow As Long
 
    ' Définir les feuilles de calcul
 
    Set wsSource = ThisWorkbook.Sheets("VHM (Lot 1)")
    Set wsDest = ThisWorkbook.Sheets("PIECES EN STOCKS")
 
    ' Définir les tableaux
 
    Set sourceTable = wsSource.ListObjects("VHMLOT1")
    Set destTable = wsDest.ListObjects("PiecesStock")
 
    ' Définir la plage de cellules à copier (colonne "Concaténation fournisseur + lot / code BPU" du tableau source)
 
    Set sourceRange = sourceTable.ListColumns("Concaténation fournisseur + lot / code BPU").DataBodyRange
 
    ' Trouver la première cellule vide dans la colonne "Fournisseur - lot - Référence BPU" du tableau de destination
 
    With destTable.ListColumns("Fournisseur - lot - Référence BPU").DataBodyRange
        If .Cells(.Cells.Count).Value <> "" Then
            nextRow = .Cells(.Cells.Count).Row + 1
        Else
            nextRow = .Find("*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row + 1
        End If
    End With
 
    ' Copier les valeurs des cellules de la colonne source vers la colonne de destination au format texte
 
    sourceRange.Copy
    wsDest.Cells(nextRow, destTable.ListColumns("Fournisseur - lot - Référence BPU").Index).PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
 
    ' Nettoyer le presse-papiers
 
    Application.CutCopyMode = False
 
End Sub

Merci de votre aide.

[Malick]

Salut,

Voici le fichier corrigé avec le code légèrement modifié (voir les commentaires)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
Sub CopierValeursColonnesTexte()
 
    Dim wsSource As Worksheet
    Dim wsDest As Worksheet
    Dim sourceTable As ListObject
    Dim destTable As ListObject
    Dim sourceRange As Range
    Dim nextRow As Long
    Dim lastCell As Range
    ' Définir les feuilles de calcul
 
    Set wsSource = ThisWorkbook.Sheets("VHM (Lot 1)")
    Set wsDest = ThisWorkbook.Sheets("PIECES EN STOCKS")
 
    ' Définir les tableaux
 
    Set sourceTable = wsSource.ListObjects("VHMLOT1")
    Set destTable = wsDest.ListObjects("PiecesStock")
 
    ' Définir la plage de cellules à copier (colonne "Concaténation fournisseur + lot / code BPU" du tableau source)
 
    Set sourceRange = sourceTable.ListColumns("Concaténation fournisseur + lot / code BPU").DataBodyRange
 
    ' Trouver la première cellule vide dans la colonne "Fournisseur - lot - Référence BP
 
        With destTable.ListColumns("Fournisseur - lot - Référence BPU").DataBodyRange
            Set lastCell = .Find("*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious)
 
            ' On vérifie si la méthode .Find a trouvé quelque chose
 
            If Not lastCell Is Nothing Then
                nextRow = lastCell.Row + 1
            Else
                ' Si le tableau est vide, démarrer à la première ligne du DataBodyRange
                nextRow = .Cells(1, 1).Row
            End If
        End With
 
   ' With destTable.ListColumns("Fournisseur - lot - Référence BPU").DataBodyRange
    '    If .Cells(.Cells.Count).Value <> "" Then
   '         nextRow = .Cells(.Cells.Count).Row + 1
     '   Else
      '      nextRow = .Find("*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row + 1
      '  End If
    'End With
 
    ' Copier les valeurs des cellules de la colonne source vers la colonne de destination au format texte
 
    sourceRange.Copy
    wsDest.Cells(nextRow, destTable.ListColumns("Fournisseur - lot - Référence BPU").Index).PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
 
    ' Nettoyer le presse-papiers
 
    Application.CutCopyMode = False
 
End Sub

[ag-capdft57]

Merci beaucoup Malick.

Cela fonctionne parfaitement comme je le souhaitais.

Bonne fin de journée.