Discussion :

[informer]

Bonjour,

Je veux traiter des colonnes multivaluées pour que chaque valeur d'un champ multivalué se décompose en autant de ligne que de valeurs multivaluées. Autrement dit je pars de



Et veux arriver à ça (Copie partielle du résultat)



Mon problème est de ne pas écrire en dur les colonnes à transformer en liste. Le code ci-dessous ne transforme que la dernière colonne d'une liste et non pas la totalité des champs de la liste, pourquoi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
= let 
    lstColName = Table.ColumnNames(Typage) //, anyOut = lstColName
    ,lstFieldForExpand = List.Skip (lstColName, 2) //, anyOut = lstFieldForExpand
     //,tblWithList = Table.TransformColumns(Typage,{{"Location", each  Text.Split(_,",")}, {"Business", each Text.Split(_,",")},{"Department",  each Text.Split(_,",")}}), anyOut = tblWithList 
    ,tblWithList = List.Accumulate (lstFieldForExpand, "", (anyInitOut,anyCurr)=> Table.TransformColumns(Typage,{anyCurr, each Text.Split(_,",")})), anyOut = tblWithList
in anyOut

Merci par avance pour votre aide

[Raccourcix]

Bonsoir
Pas d'ordinateur pendant 10 jours, je déconnecte
Je pense que je partirai sur un List.Transform pour générer le 2e argument de Table.TransformColumns à partir de la liste ListFieldForExpand
Stéphane

[informer]

Bonsoir
Pas d'ordinateur pendant 10 jours, je déconnecte
Je pense que je partirai sur un List.Transform pour générer le 2e argument de Table.TransformColumns à partir de la liste ListFieldForExpand
Stéphane

J'ai suivi ton conseil qui est bien sûr la bonne solution


= let
lstColName = Table.ColumnNames(Typage)
,lstFieldForExpand = List.Skip (lstColName, 2)
,tblWithList = Table.TransformColumns( Typage,List.Transform(lstFieldForExpand, each {_, each Text.Split(_,",")})) , anyOut = tblWithList
in anyOut





Merci et bonne déconnexion numérique !

[Raccourcix]

Bonjour

de retour...

notez que List.Accumulate n'est pas inutile pour développer les colonnes avec des listes afin d'éviter les 3 étapes successives évoquées sur le forum Microsoft
https://community.fabric.microsoft.c...le/m-p/4422744

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
let
  lstColName = Table.ColumnNames(Typage),
  lstFieldForExpand = List.Skip (lstColName, 2),
  tblWithList = Table.TransformColumns( Typage,List.Transform(lstFieldForExpand, each {_, each Text.Split(_,",")})),
  anyOut = List.Accumulate(lstFieldForExpand, tblWithList, (state, current) => Table.ExpandListColumn(state, current))
in anyOut

A partir de la table tblWithList, chacune des colonnes de lstFieldForExpand va être développée successivement.


Enfin, le troisième argument de la fonction List.Accumulate peut même être simplifié car les 2 arguments state et current sont présents et dans l'ordre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
let
  lstColName = Table.ColumnNames(Typage),
  lstFieldForExpand = List.Skip (lstColName, 2),
  tblWithList = Table.TransformColumns( Typage,List.Transform(lstFieldForExpand, each {_, each Text.Split(_,",")})),
  anyOut = List.Accumulate(lstFieldForExpand, tblWithList, Table.ExpandListColumn)
in anyOut

Stéphane

[informer]

Merci Stéphane et heureux de te lire à nouveau. Je passe maintenant sur DAX avec un nouveau post

A+