Discussion :

[informer]

Bonjour,

Les colonnes {Name, Volume(24h), Cirulation Supply} se terminent par un acronyme que je voudrai supprimer dans une seule opération et non pas en 3 qui s'enchainent

Serait-il possible de modifier ce code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
= Table.ReplaceValue(#"Add col Nom",
each [Name],
each Text.RemoveRange([Name],Text.Length([Name])-Text.Length([Acronyme]), Text.Length([Acronyme])),
Replacer.ReplaceText,
{"Name"}
)

Merci par avance

[Raccourcix]

Bonjour

en remarquant que vous voulez récupérer le texte avant l'espace, sélectionnez les 3 colonnes puis menu transformer, extraire, texte avant le délimiteur

cela donne un code du type

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
= Table.TransformColumns(Source, 
{{"Name", each Text.BeforeDelimiter(_, " "), type text}, 
 {"Volume(24h)", each Text.BeforeDelimiter(_, " "), type text}, 
 {"Cirulation Supply", each Text.BeforeDelimiter(_, " "), type text}})

code plus court avec un Table.ReplaceValue (mais peut être pas plus rapide) ici le x désigne les 3 champs les uns après les autres, y et z étant null car ils ne servent à rien

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

= Table.ReplaceValue(Source, null, null, (x,y,z) => Text.BeforeDelimiter(x," "),{"Name", "Volume(24h)", "Cirulation Supply"})

ou avec votre idée de Text.RemoveRange
ici le y désigne la longueur de l'acronyme.
notez que dans votre solution, vous conservez un espace à la fin de chaque valeur (j'ajoute un -1 à la position et un + 1 à la longueur à supprimer)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

= Table.ReplaceValue(Source, each Text.Length([Acronyme]), null, (x,y,z) => Text.RemoveRange(x,Text.Length(x)-y-1,y+1),{"Name", "Volume(24h)", "Cirulation Supply"})

je pense qu'un Text.Start est plus naturel

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

= Table.ReplaceValue(Source,each Text.Length([Acronyme]),null, (x,y,z) => Text.Start(x,Text.Length(x)-y-1),{"Name", "Volume(24h)", "Cirulation Supply"})

Stéphane

[informer]

Bonjour Stéphane,


Merci pour les solutions apportées avec leurs explications
Merci également pour l'astuce permettant d'avoir le code qui s'applique à plusieurs colonnes. C'est vraiment 👍

J'en profite pour savoir s'il est possible de créer une fonction personnalisée (let... in... Je présume ) appelée avec en paramètre les noms des colonnes ?

[Raccourcix]

J'en profite pour savoir s'il est possible de créer une fonction personnalisée (let... in... Je présume ) appelée avec en paramètre les noms des colonnes ?

Merci du retour

On peut créer une fonction personnalisée mais je ne comprends pas l'objectif

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

(une_table as table, une_liste_de_colonnes as list) as table => Table.ReplaceValue(une_table , null, null, (x,y,z) => Text.BeforeDelimiter(x," "), une_liste_de_colonnes )

Stéphane

[informer]

Bonjour Stéphane,


Merci encore pour votre aide et ma dernière demande était purement théorique pour information.