Discussion :

[voxov]

Bonjour,

Mes messages dans Outlook sont classés dans des folders. Par exemple: Inbox/projets/SAD123.

J'ai une application Access à partir de laquelle je voudrais pouvoir ouvrir un folder Outlook afin de voir (dans Outlook, pas la version web de Outlook) les messages qui y sont classés.
En d'autres termes, mon application Access gère des projets et je voudrais pouvoir, sur un clic, ouvrir le folder dans Outlook qui contient les messages classés pour ce projet.
Mon application Access aurait le nom du folder Outlook visé (ex. Inbox/projets/SAD123). Elle devrait activer Outlook (pas la version web de Outlook.) et ouvrir le folder indiqué. La consultation des messages se ferait dans Outlook.

Merci d'avance pour vos éclairages et suggestions.

JL

[EricDgn]

Bonjour,

Une façon de faire (qui m'a été soufflée par Mistral):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Option Compare Database
Option Explicit
 
'--- indispensable: avoir activé la référence  Microsoft Outlook xx.x Object Library
 
Private Sub btnOpenOutlookFolder_Click()
    Dim olApp As Outlook.Application
    Dim olNamespace As Outlook.Namespace
    Dim olFolder As Outlook.MAPIFolder
    Dim folderPath As String
 
    ' Initialiser l'application Outlook
    Set olApp = New Outlook.Application
    Set olNamespace = olApp.GetNamespace("MAPI")
 
    ' Définir le chemin du dossier Outlook
    folderPath = "Inbox\projets\SAD123"
 
    ' Ouvrir le dossier spécifié
    On Error Resume Next
    Set olFolder = olNamespace.Folders("MonAdresseEmail@blabla.com").Folders("Inbox").Folders("projets").Folders("SAD123")
    On Error GoTo 0
 
    If olFolder Is Nothing Then
        MsgBox "Le dossier spécifié n'a pas été trouvé.", vbExclamation
    Else
        olFolder.Display
    End If
 
    ' Libérer les objets
    Set olFolder = Nothing
    Set olNamespace = Nothing
    Set olApp = Nothing
End Sub

Cordialement.

[voxov]

Merci EricDgn.

Le code que tu as proposé ne fonctionne pas.
Le problème est sur la ligne 21.

A l'exécution, la ligne 21

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set olFolder = olNamespace.Folders("MonAdresseEmail@blabla.com").Folders("Inbox").Folders("projets").Folders("SAD123")

rend: olFolder = Nothing

et alors je reçois logiquement la pop-up "Le dossier spécifié n'a pas été trouvé."

JL

[EricDgn]

Bonjour,

Le problème vient de ce qu'il faut respecter strictement les libellés (en respectant les accents s'il y en a) et la hiérarchie. Eventuellement ceci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

    Set olFolder = olNamespace.Folders("MonAdresseEmail@blabla.com").Folders("Boîte de réception").Folders("projets").Folders("SAD123")

où MonAdresseEmail@blabla.com est à remplacer par l'adresse email qui se trouve indiquée dans votre Outlook.

Cordialement.

[micniv]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set olFolder = olNamespace.Folders("libellé de la BAL").Folders("Boîte de réception").Folders("Classement").Folders("05 projets").Folders("MAI")

Ca fonctionne correctement chez moi
Seulement quelques précautions :
il faut saisir le libellé de la boite mail (car le libellé peut être différent du mail)
si ton OTL est en français , mettre "Boîte de réception") au lieu de "inbox"
...

[voxov]

Effectivement, le code fonctionne avec la ligne ci-dessous:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set olFolder = olNamespace.Folders("MonAdresseEmail@blabla.com").Folders("Boîte de réception").Folders("projets").Folders("SAD123")

Mais si on veut paramétrer comme suit:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set olFolder = olNamespace.Folders(MyEmail).Folders(MyInbox).Folders(MyProjets).Folders(me.MyFolder)

avec MyEmail, MyInbox, MyProjets définis comme constantes string (pour faire simple), et me.MyFolder défini comme Text Box dans le Form, ça ne va plus.

Le problème vient du me.MyFolder.

Alors si on met d'abord le contenu de la Text Box dans une variable string et que l'on passe cette variable dans le olFolder, ça fonctionne sans problème:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
dim MystrFolder as string
MystrFolder = me.MyFolder
Set olFolder = olNamme.MyFolderespace.Folders(MyEmail).Folders(MyInbox).Folders(MyProjets).Folders(MystrFolder)

Je ne sais pas pourquoi utiliser la text box directement ne marche pas.

Merci pour vos inputs.

[tee_grandbois]

bonsoir,

Je ne sais pas pourquoi utiliser la text box directement ne marche pas.

tout simplement parce que me.MyFolder est un objet (de type contrôle d'un formulaire), il faut donc passer par une variable pour récupérer la valeur de cet objet comme tu as su le faire ici:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
dim MystrFolder as string
MystrFolder = me.MyFolder

on aurait pu écrire:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

MystrFolder = me.MyFolder.Value

mais comme Value est la propriété par défaut d'un contrôle, il n'est pas nécessaire de le préciser