Discussion :

[Pouic1605]

Bonjour à tous.
Je suis nouveau sur le forum et je débute en VBA en Access.

Via VBA, je cherche à envoyer un seul et unique mail à plusieurs destinataires. Mes destinataires se trouvent dans une table nommée "Destinataires" et elle est composée de 2 colonnes. La 1ere se nomme "Mail" et reprend les adresses mails. La 2e colonne se nomme "Type" et dedans il est marqué "To" ou "Cc" pour définir si la personne doit être en copie ou recevoir directement le mail.

Pour l'instant, j'ai repris ce code VBA, mais les adresses mails sont écrites directement dans le code (désolé pour le lien mais tout mon travail se trouve sur mon PC du boulot https://www.experts-access.com/micro...en-vba-access/). Mon objectif est de définir les destinataires en fonction des données dans ma table, afin que s'il y a un changement de destinataires, il y a juste à l'adapter dans la table plutôt que dans le code.

La seule chose que j'ai réussi à trouver c'est un mail par personne, mais j'ai absolument besoin d'un seul mail avec tout le.monde dedans.

Merci beaucoup pour votre aide.

[User]

Bonjour,

Il faudrait copier cette fonction dans un module standard :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Option Compare Database
 
 
Public Function EmailsDestinataires(NomTable As String, ChampEmail As String, TypeEnvoi As String) As String
 
    Dim rst As DAO.Recordset
 
    Set rst = CurrentDb.OpenRecordset("select * from " & NomTable & " where Type='" & TypeEnvoi & "'")
 
    EmailsDestinataires = ""
 
    Do Until rst.EOF
 
        EmailsDestinataires = EmailsDestinataires & rst(ChampEmail) & "; "
 
        rst.MoveNext
 
    Loop
 
    If Len(EmailsDestinataires) > 0 Then
        EmailsDestinataires = Left(EmailsDestinataires, Len(EmailsDestinataires) - 2)
    End If
 
End Function

Ensuite mettre à jour les propriétés To et CC de l'objet mailitem comme ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
'...
objOutlookMsg.To = EmailsDestinataires("Destinataires", "Mail", "To")
objOutlookMsg.CC = EmailsDestinataires("Destinataires", "Mail", "Cc")
'...

Les e-mails sont séparés par des points-virgules.

Cdlt,

[Pouic1605]

Merci beaucoup. Cela fonctionne parfaitement.