Discussion :

[fred106064]

Bonjour à tous,

Je vous explique mon "probleme"

Photographe scolaire je cherche une solution pour exporter automatiquement une liste d'eleves sous excel ( colonne A Nom Colonne B Prénom ) vers leur photos respectives

1er nom prenom -> 1ere photo etc etc

j'ai déjà une version "beta" qui marche (dossier racine c:\TEMP pour les photos a modifier ) mais j'aimerai l'améliorer en mettant deux boutons supplémentaires : DOSSIER SOURCE et dossier DESTINATION

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub rename()
   Dim StrFile As String
   Dim WD As String
   WD = "D:\temp\"
    StrFile = Dir(WD)
        Set Rng = Range("Tab")
            For Each c In Rng
            If c.Next.Value <> "" Then
                Name WD + StrFile As WD + UCase(c.Value) + " " + UCase(c.Next.Value) + ".jpg"
                 StrFile = Dir
            End If
            Next
End Sub

cela me permettrai de gagner du temps.

Merci par avance

[EricDgn]

Bonjour,

Quelque chose de ce genre:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Option Explicit
 
Sub Rename()
    Dim sDossSource As String, sDossDest As String, sFile As String, c As Range
    sDossSource = DossierChoisi()
    sDossDest = DossierChoisi()
    If MsgBox("Transférer / renommer les fichiers" & vbLf & _
              "        du dossier " & sDossSource & vbLf & _
              "dans le dossier " & sDossDest, _
              vbYesNo + vbDefaultButton2, "Oui/Non?") = vbYes Then
        sFile = Dir(sDossSource)
        For Each c In Range("Tab")
            If c.Next.Value <> "" Then
                FileCopy sDossSource + sFile, sDossDest + UCase(c.Value) + " " + UCase(c.Next.Value) + ".jpg"  '--- copie/renomme la photo
                Kill sDossSource + sFile  '--- supprime la photo
                sFile = Dir
            End If
        Next
    End If
End Sub
 
Public Function DossierChoisi() As String
    DossierChoisi = ""
    With Application.FileDialog(4)          '--- 4 = msoFileDialogFolderPicker
        .InitialFileName = "D:\"
        .AllowMultiSelect = False
        .InitialView = 2                    '--- 2 = msoFileDialogViewDetails
        .Title = "Cliquer sur le dossier puis cliquer sur OK"
        If .Show <> 0 Then
            DossierChoisi = .SelectedItems(1) & "\"
        End If
    End With
End Function

L'utilisation de c.Next me semble assez bizarre, mais bon, je laisse.

Cordialement.

[fred106064]

super ca marche bien

et si je veux juste un dossier source et que ca modifie directement les noms de photo sans demander de dossier de destination?

[EricDgn]

Alors, simplifier la première routine:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub Rename()
    Dim sDoss As String As String, sFile As String, c As Range
    sDoss = DossierChoisi()
    If MsgBox("Renommer les fichiers du dossier " & sDoss, _
              vbYesNo + vbDefaultButton2, "Oui/Non?") = vbYes Then
        sFile = Dir(sDoss)
        For Each c In Range("Tab")
            If c.Next.Value <> "" Then
                Name sDoss + sFile As sDoss + UCase(c.Value) + " " + UCase(c.Next.Value) + ".jpg"  '--- renomme la photo
                sFile = Dir
            End If
        Next
    End If
End Sub

Cdt

[fred106064]

Erreur de syntaxe

sub rename en jaune et "Dim sDoss As String As String, sFile As String, c As Range" en bleu

[EricDgn]

Effectivement:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Dim sDoss As String, sFile As String, c As Range

Cordialement