Discussion :

[azzangot]

Re bonjour,

Toujours dans le cadre de l'apprentissage de la manipulation des données de tables, voilà ce que je souhaiterais réaliser :
Après avoir triée la table T_Prenom1 par prénom, transferer les enregistrements de la table T_Prenom1 vers T_Prenom2, mais en concatenant le champ Couleur dans 1 seul enregistrement et ce pour chaque prénom.
Exemple :

Table T_Prenom1 (Source)

Antoine Rose
Antoine Marron
Céline Bleu
Céline Rouge
Céline Vert

Table T_Prenom2 (Destination)

Antoine Rose + Marron
Céline Bleu + Rouge + Vert

Je vous joins la base pour test.
Merci pour votre aide,
a+
Prenom2.zip

[hyperion13]

Salut
Dans votre apprentissage pensez à utiliser le moteur de recherche de DEV

[azzangot]

Bonjour et merci hyperoipn13, j'ai regardé le doc que vous m'avez envoyé, mais je ne m'y retrouve pas, trop complexe pour mon niveau.

J'ai tenté le code ci-dessous, qui fonctionne sur les 2 premiers enregistrements, mais qui bug arrivé au 3èm, sans que je m'en explique la raison.
Le message d'erreur est le suivant : Erreur d'execution 3021; Aucun enregistrement en cours. Le curseur se positionne sur rst.Edit
Je joins mon fichier pour test.
En vous remerciant pour votre aide,
cordialement,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
If Not Me.T_Prenom1.Form.RecordsetClone.EOF Then

    With Me.T_Prenom1.Form.RecordsetClone
        .MoveFirst
        Do While Not .EOF
        rst.AddNew
            If vPrenom = !Prenom Then
                rst.MovePrevious
                rst.Edit
                rst!couleur = rst!couleur & cPlus & !couleur
                rst.Update
            Else: vPrenom = !Prenom
                rst!ID = !ID
                rst!Prenom = !Prenom
                rst!Age = !Age
                rst!couleur = !couleur
                rst.Update
            End If
        .MoveNext
        Loop
    End With
End If

[loufab]

Bonjour,

Tu devrais tracer l'exécution avec Debug.print [instruction à vérifier] pour savoir pourquoi au 3ème (parce que c'est le premier prenom qui est identique ?).

Du point de vue fonctionnel je ne comprend pas ton code.

Tu passe en addnew puis un edit et tu fais des moveprevious et un update dans chaque cas.

A noter que pour faire ce type de manipulation il faut normalement passé par SQL et non pas VBA.

Cordialement

[hyperion13]

Surtout que le sujet a déjà été posé et qu'une solution avait également été donnée !
A part clôturer le sujet avez-vous mis en application la solution proposée ? Car elle fonctionne !

[azzangot]

Bonjour à tous,

merci pour vos réponses Foulab et Hyperion13 !

Effectivement Hyperion13, je n'ai aucun doute que le code vers lequel vous me renvoyez fonctionne, sauf que personnellement je ne le comprends pas.
Une fois encore, votre réponse affirme que cela fonctionne et vous en ajoutez l'image comme preuve, mais votre réponse ne m'explique pas pourquoi mon code ne fonctionne pas et c'est ce qui m'interesse...

Cordialement,

[hyperion13]

... mais votre réponse ne m'explique pas pourquoi mon code ne fonctionne pas et c'est ce qui m'interesse ...

Avez-vous au moins compris la rédaction de votre sub?
Je vous renvoie au Post#4 de Loufab que je salue

Si la fonction clé en main d'Allen Browne ne convient pas, parce que vous ne la comprenez pas, je vous renvoie à cette fonction qui est hyper simple à comprendre. Je l'ai adapté des fois que ...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Public Function RecupCouleur(ID As Long) As String
Dim rst As DAO.Recordset
Dim strSql As String
 
strSql = "SELECT Couleur FROM T_Prenom1 WHERE ID = " & ID
Set rst = CurrentDb.OpenRecordset(strSql)
 
Do While Not rst.EOF
    RecupCouleur = RecupCouleur & rst.Fields(0).Value & " - " ' tant que l'ID est identique on met bout à bout les couleurs
    rst.MoveNext
Loop
 
RecupCouleur = Left(RecupCouleur, Len(RecupCouleur) - 3) ' 3 parce que la L9 comprend un espace un trait d'union et un autre espace à la fin de la ligne
 
Set rst = Nothing
End Function

et la qry

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
SELECT DISTINCT ID, Prenom, RecupCouleur([ID]) AS Couleurs
FROM T_Prenom1
ORDER BY Prenom

[azzangot]

merci pour vos réponses,

Oui effectivement, j'ai découvert grace aux explications de Foulab cette commande debug.print que j'ignorais.
Cela me permet de constater que ma variable contient bien la bonne information et que c'est bien à partir du 3èm enregistrement que ca bug, ou plutôt, pour être plus précis, au second passage dans le then de ma condition if.
On peut d'ailleurs voir le resultat dans la table T_Prenom2.
Mais pourquoi ? Cela je ne me l'explique pas encore.
Quant à vos efforts Hyperion13, pour m'apporter une solution, je les apprecie sincèrement même avec cette pointe d'irronie qui vous carractérise (j'ai lu d'autres de vos réponses sur le forum) mais hélàs, ils ne repondent pas à ma question pourtant triviale. Pourquoi mon code bug ?

Bien à vous,

[loufab]

Je viens de jeter un coup d'oeil au fichier transmis.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
rst.MovePrevious
rst.Edit

Quand on fait un moveprevious après l'ouverture d'un recordset il faut s'attendre à ne plus être sur un enregistrement.

Si tu souhaites utiliser DAO il faut au minimum que tu regardes comment ça fonctionne. Suivre un tuto est faire les manips indiquées c'est peut-être le plus simple pour comprendre.

Donc voici ce que tu dois lire :
https://warin.developpez.com/access/dao/?page=partie_5#

Cordialement,

[hyperion13]

... Quant à vos efforts Hyperion13, pour m'apporter une solution, je les apprecie sincèrement même avec cette pointe d'irronie (ironie) qui vous carractérise (caractérise) (j'ai lu d'autres de vos réponses sur le forum)...

... mais hélàs, ils ne repondent pas à ma question pourtant triviale. Pourquoi mon code bug ?...

C'est vous avec vos savoirs et connaissances qui avez rédigé ces lignes. Donc c'est à vous d'expliquer ce que votre bloc With doit réaliser. De comprendre pourquoi les couleurs associées à un prénom ne se mettent pas toutes bout à bout.

[tee_grandbois]

bonjour,

Effectivement Hyperion13, je n'ai aucun doute que le code vers lequel vous me renvoyez fonctionne, sauf que personnellement je ne le comprends pas.
Une fois encore, votre réponse affirme que cela fonctionne et vous en ajoutez l'image comme preuve, mais votre réponse ne m'explique pas pourquoi mon code ne fonctionne pas et c'est ce qui m'interesse...

en complément des réponses de loufab et Hyperion13 je peux dire pourquoi ton code ne fonctionne pas:
tu effectues un MovePrevious après un AddNew (que, d'ailleurs, tu exécutes systématiquement à chaque MoveNext du RecordsetClone en lecture alors qu'il devrait se faire uniquement à chaque changement de prénom).
et il est indiqué dans l'aide de Microsoft learn Autres méthodes pour se déplacer dans un recordset (c'est le paragraphe en anglais mais traduit grâce à un traducteur trouvé sur le net: The behavior of the various Move methods of the Recordset object depends, to some extent, on the data within the Recordset. etc.):

Le comportement des différentes méthodes de déplacement de l’objet Recordset dépend, dans une certaine mesure, des données contenues dans le Recordset. Les nouveaux enregistrements ajoutés à l’ensemble de documents sont d’abord ajoutés dans un ordre particulier, qui est défini par la source de données et peut dépendre implicitement ou explicitement des données du nouvel enregistrement. Par exemple, si un tri ou une jointure est effectué dans la requête qui remplit l’ensemble de documents, le nouvel enregistrement sera inséré à l’endroit approprié dans l’ensemble de documents. Si l’ordre n’est pas explicitement spécifié lors de la création de Recordset, les modifications apportées à l’implémentation de la source de données peuvent entraîner la modification par inadvertance de l’ordre des lignes retournées. De plus, les fonctions de tri, de filtrage et d’édition du Recordset peuvent affecter l’ordre et éventuellement les lignes du Recordset qui seront visibles.

Je ne sais pas si ton code entre dans un de ces cas (certainement avec Edit) mais j'ai constaté qu'il était impossible de se repositionner sur le bon enregistrement, même si cela peut fonctionner pour le premier enregistrement (mais vu qu'il n'y en a pas d'autres...), d'autant plus que les enregistrements des tables Access sont regroupés par blocs (ou pages), il me semble.
Et un peu plus loin on lit:

Par conséquent, MoveNext, MovePrevious, MoveFirst, MoveLast et Move sont tous sensibles aux autres opérations effectuées sur le même Recordset. ADO essaiera toujours de maintenir votre position actuelle jusqu’à ce que vous la déplacez explicitement, mais il est parfois difficile de comprendre les effets d’un déplacement ultérieur.

En gros, on ne sait pas trop quel effet aura un déplacement dans un RecordSet. Ce que je sais par expérience, c'est qu'il est hasardeux de vouloir faire AddNew , MovePrevious et puis Edit pour tenter de mettre à jour un enregistrement venant d'être inséré.
La solution la plus simple a été donné par Hyperion13 et je pense que tu devrais essayer de comprendre son code avant de te lancer dans du code VBA plus complexe et donc, à priori, encore moins compréhensible pour toi.
Je te poste tout de même ton code corrigé, bonne lecture:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
Private Sub Btn_Transfert_Click()
 
Dim dbs As DAO.Database: Set dbs = CurrentDb
Dim rst As DAO.Recordset  ' pour insert T_2
Dim rst2 As DAO.Recordset ' pour MAJ T_2
Dim Sql As String
Dim vPrenom As String
Dim vID As Long
Const cPlus As String = " + "
 
DoCmd.SetOrderBy "Prenom", "T_Prenom1"
 
Sql = "DELETE * FROM T_Prenom2;"
dbs.Execute Sql, dbFailOnError
 
If Not Me.T_Prenom1.Form.RecordsetClone.EOF Then
 
    With Me.T_Prenom1.Form.RecordsetClone
        .MoveFirst
        Do While Not .EOF
            If vPrenom = !Prenom Then
            ' mise à jour des autres couleurs pour l'enregistrement créé
                Sql = "select * from T_Prenom2 where ID=" & vID & ";"
                Set rst2 = dbs.OpenRecordset(Sql, dbOpenDynaset)
                rst2.Edit
                rst2!couleur = rst2!couleur & cPlus & !couleur
                rst2.Update
            Else
                Set rst = dbs.OpenRecordset("T_Prenom2", dbOpenTable)
                rst.AddNew
                'rupture sur le prénom
                vPrenom = !Prenom
               ' mais on préfèrera l'identifiant numérique, au moins pour la requête de MAJ
                vID = !ID
                rst!ID = !ID
                rst!Prenom = !Prenom
                rst!Age = !Age
                rst!couleur = !couleur
                rst.Update
                ' on libère la table pour un prochain accès à l'enregistrement créé
                rst.Close
         End If
       .MoveNext
        Loop
    End With
End If
 
rst2.Close
dbs.Close
Set rst = Nothing: Set rst2 = Nothing
Set dbs = Nothing
 
Me.T_Prenom2.Form.Requery
 
End Sub

[azzangot]

Bonjour à tous !

En tout premier lieu, un grand merci à vous tous pour vos réponses, je vois que vous ne vous ménagez pas pour tenter de m’apporter des solutions.
Je viens à l'instant de prendre connaissance de votre message tee_grandbois. Effectivement, la manipulation des recordest n'est pas forcément intuitive et nécessite un certain corpus de connaissance que je ne possède pas encore, mais j'ai pour autant résolu mon problème.

Je suis reparti d'un autre fichier que m'avait mis au point Hyperion13 en juin 2021. En le modifiant pour qu'il réponde à mon nouveau besoin, j'ai constaté les mêmes causes aux mêmes effets. Au second passage dans le then de ma condition if, le bug apparaissait.
J'ai ensuite eu l'idée d'ajouter des enregistrements dans ma table T_Prenom2, plutôt que de partir d'une table vide et là, le bug n'apparaissait plus. Cependant, je me suis rendu compte que seul le 1er enregistrement était toujours modifié. J'ai compris à ce stade qu'un UPDATE n'incrémente pas automatiquement la position du recordest. Je me suis donc replongé dans l'aide en ligne Microsoft et il y est expliqué ceci :

En appliquant la propriété Bookmark = LastModified au recordset, cela a résolu le problème.
Ci-dessous mon code corrigé.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
Private Sub Btn_Transfert_Click()
 
Dim dbs As DAO.Database: Set dbs = CurrentDb
Dim rst As DAO.Recordset
Dim Sql As String
Dim vPrenom As String
Const cPlus As String = " + "
 
DoCmd.SetOrderBy "Prenom", "T_Prenom1"
 
Sql = "DELETE * FROM T_Prenom2;"
DoCmd.RunSQL Sql
 
Sql = "SELECT * FROM T_Prenom2;"
Set rst = dbs.OpenRecordset(Sql, 2, 512)
 
If Not Me.T_Prenom1.Form.RecordsetClone.EOF Then
 
    With Me.T_Prenom1.Form.RecordsetClone
        .MoveFirst
        Do While Not .EOF
        rst.AddNew
            If vPrenom = !Prenom Then
                rst.Edit
                rst!couleur = rst!couleur & cPlus & !couleur
            Else: vPrenom = !Prenom
                rst!ID = !ID
                rst!Prenom = !Prenom
                rst!Age = !Age
                rst!couleur = !couleur
            End If
         rst.Update
         rst.Bookmark = rst.LastModified
        .MoveNext
        Loop
    End With
End If
 
rst.Close
dbs.Close
Set rst = Nothing
Set dbs = Nothing
 
Me.T_Prenom2.Form.Requery
 
End Sub

Encore merci pour votre aide et j’espère ne pas avoir trop fait de faute d’orthographe !
Cordialement,

[tee_grandbois]

bonsoir,
bravo, j'avoue que je n'avais jamais utilisé LastModified du Recordset pour mettre à jour le signet (bookmark).
Comme quoi, on en apprend tous les jours

[azzangot]

Oui merci à vous !
Je pense à présent qu’il est temps de clore ce sujet, mais avant tout, quelques précisions.
J’ai à la base une formation de programmeur en assembleur et ultérieurement, j’ai acquis quelques connaissances en programmation orientée objet sous un logiciel nommé Paradox. Ça date… Autant que je m’en souvienne, la manipulation des enregistrements était différente du VBA. Pour être tout à fait transparent, je n’ai jamais pratiqué ces métiers à titre professionnel, mais simplement en amateur. Je viens sur ce forum, car je le trouve très intéressant et très riche d’informations. On peut y passer des heures. Le fait de pouvoir échanger avec d’autres personnes est primordial pour la compréhension et la transmission des connaissances. Il est aussi élémentaire, que cela se passe dans le respect et en toute bienveillance. Je n’ai pas lu la charte du site, je le reconnais, mais je suis certain que cela y est mentionné. Même un expert éminent a le droit de ne pas savoir et je suis ravis d’avoir pu apporter ma modeste contribution sur ce sujet précis.
Cordialement

[chrtophe]

J'ai lu en diagonale, mais pour faire ce qui est demandé, il serait plus efficace de passer par une requête SQL.