Discussion :

[Constant49]

Bonjour
Je débute sur VBA, je maitrise mal la syntaxe et j’ai du mal à réaliser un code assez simple.
A l’aide de ce forum et de l’enregistreur, j’ai créé un code qui a pour objet :
1. à partir du classeur ouvert, d’en ouvrir un second : OK
2. de recherche dans une colonne la dernière cellule vide puis d’y affecter une valeur égale à N+1 par rapport à la valeur précédente : OK
3. de copier – coller cette valeur ainsi affectée, dans mon classeur d’origine : KO
Mon code bloque sur cette ligne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

HADDOCK.Sheets("Projet").Range("B15").FormulaR1C1 = BDD.Sheets("BDD").ActiveCell.Offset(0, 0).Value

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub Enregistrer_Projet()
' cette macro ouvre le classeur BDD, affecte un numéro de chrono N+1 par rapport au précédent, 
' puis enregistre et referme BDD et colle dans le fichier depuis lequel la macro s'exécute, le numéro de chrono ainsi attribué.

Dim BDD As Workbook, HADDOCK As Workbook
Set HADDOCK = ThisWorkbook

    Workbooks.Open Filename:= _
        "G:\dse\1 - DAT GHT 49\SI ACHATS\OUTIL LOCAL\HADDOCK BASE DE DONNEES.xlsx"
    Range("A1").Select

Set BDD = ActiveWorkbook
    BDD.Sheets("BDD").Cells(Rows.Count, 1).End(xlUp)(2).Select
    ActiveCell.Offset(0, 0).FormulaR1C1 = ActiveCell.Offset(-1, 0) + 1
    
    HADDOCK.Sheets("Projet").Range("B15").FormulaR1C1 = BDD.Sheets("BDD").ActiveCell.Offset(0, 0).Value

    ActiveWorkbook.Save
    ActiveWindow.Close
    HADDOCK.Save
End Sub

Pourriez-vous m’aider et m’expliquer la cause de l’erreur ?
Merci.

[Jean-Philippe André]

Salut,

FormulaR1C1 s'attend à recevoir une formule, donc une chaîne de caractères qui débute par le signe "=".

Est-ce bien ton cas ?

[Constant49]

FormulaR1C1 s'attend à recevoir une formule, donc une chaîne de caractères qui débute par le signe "=".
Est-ce bien ton cas ?

Ah ben non en effet. Dans ActiveCell.Offset(-1, 0) + 1 il y a simplement un nombre entier positif qui se met dans ma cellule dans la ligne de code précédente : ActiveCell.Offset(-1, 0) + 1

Par quoi puis-je remplacer FormulaR1C1 ?

[Tête de chat]

Bonjour,

Activecell n'est pas un membre de WorkSheet mais de Application (il y a une cellule active pour la session Excel). Donc effectivement la propriété ActiveCell n'est pas gérée par l'objet BDD.Sheets("BDD").

Après on sent bien effectivement un manque de maîtrise

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set HADDOCK = ThisWorkbook

ne sert à rien. ThisWorkBook est un objet WorkBook tout à fait honorable et peut être manipulé en tant que tel. Il ne bougera pas en cours d'exécution contrairement à ActiveWorkbook. Si tu y tiens tu peux changer son codename et le renommer Haddock dans la fenêtre de propriété mais on ne va peut-être pas tout compliquer du premier coup.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Workbooks.Open Filename:= "G:\dse\1 - DAT GHT 49\SI ACHATS\OUTIL LOCAL\HADDOCK BASE DE DONNEES.xlsx"
Set BDD = ActiveWorkbook

peut avantageusement être remplacé par par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set BDD = Workbooks.Open (G:\dse\1 - DAT GHT 49\SI ACHATS\OUTIL LOCAL\HADDOCK BASE DE DONNEES.xlsx")

qui va faire l'ouverture ET l'affectation de BDD sans risque d'interférence

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
    BDD.Sheets("BDD").Cells(Rows.Count, 1).End(xlUp)(2).Select
    ActiveCell.Offset(0, 0).FormulaR1C1 = ActiveCell.Offset(-1, 0) + 1

Donc tu te places après la dernière cellule remplie de la colone A et tu fais un +1 vs la ligne précédente.
là 1. il faut éviter d'utiliser les select et active, c'est mal 2. ça tombe bien on réutilise la cellule plus loin on va la stocker dans une range.
De plus comme tu travailles sur la valeur, on va utiliser value plutôt que formula.
Accessoirement un offset(0,0) ne sert à rien on se déplace de 0 dans les deux axes, donc autant s'en passer.
Ça donne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
    Dim Numero as Range
    Set Numero = BDD.Sheets("BDD").Cells(Rows.Count, 1).End(xlUp)(2)
    Numero.Value = Numero.Offset(-1, 0).Value + 1
    ThisWorkBook.Sheets("Projet").Range("B15").Value = Numero.Value

Idem pour les active

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
    ActiveWorkbook.Save
    ActiveWindow.Close

maintenant qu'on tient notre classeur par BDD, on oublie tout ce qui est active...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
BDD.Save
BDD.Close

Pas testé, j'espère qu'il n'y a pas trop de coquilles, je te laisse réassembler tout ça

[Tête de chat]

Bonjour Jean-Philippe

je prends le risque de contredire un modérateur

FormulaR1C1 s'attend à recevoir une formule, donc une chaîne de caractères qui débute par le signe "="

Non on peut tout à fait affecter directement une valeur numérique (0, 666, 34+55) ou un string quelconque ("toto") qui seront donc pris comme une value, mais sans provoquer d'erreur.
Mais effectivement si on affecte "R[-1]C+1" alors qu'on voulait mettre "=R[-1]C+1" on va être déçu ...

[Constant49]

Ces réponses dépassent mes espérances ! Voilà résolue une macro qui m'a pris la tête cet après-midi.

Je vous remercie des explications. J'attends une formation débuter en VBA... D'ici là c'est dur !

Constant