Discussion :

[Apoulit]

Bonjour,
j'ai une requête qui reprend les champs d'une table avec un tri par références.
Je voudrais savoir comment détecter dans une boucle qu'elle sera la référence suivante et si c'est la même pouvoir récupérer la valeur suivante liée à cette même référence pour la soustraire et écrire le résultat.
Si celle si change la valeur sera nulle.
Rien ne vaut une petite image pour explications



J'ai fait un début de code ...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
 
 
Function ESSAI()
 
On Error GoTo errHnd
 
 
Dim base As Database: Dim enr As Recordset
Dim nb As Long: Dim compteur As Long
 
Set base = CurrentDb()
Set enr = base.OpenRecordset("R_journal_stock")
 
nb = enr.RecordCount
 
 
'MsgBox nb
 
 
 
 
 
 
DoCmd.SetWarnings False
 
    Dim db As DAO.Database: Set db = CurrentDb
    Dim rst As DAO.Recordset
    Dim strSQL As String
    Dim I As Integer
 
    strSQL = "Select Reference, Date_ip, Quantite, Consomation From R_journal_stock"
    Set rst = db.OpenRecordset(strSQL, dbOpenDynaset, dbSeeChanges)
    If Not rst.EOF Then
 
        rst.MoveFirst
        Do While rst.EOF = False
            rst.Edit
            If Nz(rst("Reference"), "") <> "" Then
 
            'Nz(rst("Consomation")) = Nz(rst("Consomation")) - Nz(rst("Consomation"))...d'aprés
 
 
            End If
 
            rst.Update
            rst.MoveNext
 
 
 
        Loop
    End If
    rst.Close
    Set rst = Nothing
    Set db = Nothing
 
 
 
 
 
 DoCmd.SetWarnings True
 
 
Exit Function
errHnd:
MsgBox "Erreur N° " & Err.Number & vbLf & Err.Description, , Err.Source
End Function

Si quelqu'un à une idée merci d'avance.

[deedolith]

Salut,

Basiquement, il te faut ouvrir 2 recordsets (ou cloner le premier), disons A et B sur la même requête, et comparer l'enregistrement N du recordset A, avec l'enregistrement N+1 du recordset B.

[tee_grandbois]

bonsoir,

j'ai une requête qui reprend les champs d'une table avec un tri par références.

je pense qu'il faut trier également par date et l'appliquer sur le jeu d'enregistrements lu:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

    strSQL = "SELECT Reference, Date_ip, Quantite, Consomation FROM R_journal_stock ORDER BY Reference, Date_ip;"

Je voudrais savoir comment détecter dans une boucle qu'elle sera la référence suivante et si c'est la même
pouvoir récupérer la valeur suivante liée à cette même référence pour la soustraire et écrire le résultat.
Si celle si change la valeur sera nulle.

si j'ai bien compris, tu souhaites récupérer la quantité suivante pour mettre à jour la consommation de l'enregistrement précédent ? ce n'est pas la plus simple des boucles à réaliser.
Pour récupérer la valeur d'un enregistrement suivant, le mieux c'est d'effectuer un Movenext (si on n'est pas en fin de fichier) après avoir sauvegardé le signet de l'enregistrement lu (ou bookmark en anglais et comme expliqué dans ce tuto), récupérer les données de l'enregistrement suivant, puis revenir à l'enregistrement en cours via le signet et enfin, la mise à jour peut se faire:

Code VBA :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
Function ESSAI()
 
On Error GoTo errHnd
 
    Dim db As DAO.Database: Set db = CurrentDb
    Dim rst As DAO.Recordset
    Dim strSQL As String
 
    Dim stReference As String
    Dim lgQteSuiv As Long
    Dim BytPosition() As Byte
 
    strSQL = "SELECT Reference, Date_ip, Quantite, Consomation FROM R_journal_stock ORDER BY Reference, Date_ip;"
    Set rst = db.OpenRecordset(strSQL, dbOpenDynaset, dbSeeChanges)
 
    If Not rst.EOF Then
        'pour mettre à jour le Recordcount
        rst.MoveLast: rst.MoveFirst
 
        Do Until rst.EOF
            If Nz(rst("Reference"), "") <> "" Then       ' ???? à quoi sert ce IF  ?
                ' sauvegarde du signet de l'enregistrment actif
                BytPosition = rst.Bookmark
 
              ' lecture enr. suivant si pas sur dernier enregistrement
                If rst.AbsolutePosition + 1 <> rst.RecordCount Then
                    rst.MoveNext
                    ' récup reference suivante
                    stReference = Nz(rst("Reference"), "")
                    ' récup quantité suivante
                    lgQteSuiv = Nz(rst("Quantite"), 0)
                    ' restauration du signet de l'enregistrement actif
                    rst.Bookmark = BytPosition
                    rst.Edit
              ' Maj de la consommation précédente
                    If rst("Reference") = stReference Then
                        rst("Consomation") = Nz(rst("quantite"), 0) - lgQteSuiv
                        rst.Update
                    Else
                        rst("Consomation") = Null
                    End If
                End If
            End If
            rst.MoveNext
 
        Loop
    End If
 
    rst.Close
    Set rst = Nothing
    Set db = Nothing
 
Exit Function
errHnd:
MsgBox "Erreur N° " & err.Number & vbLf & err.Description, , err.Source
End Function

[Apoulit]

Un grand merci tee grandbois !

[tee_grandbois]

bonsoir,
désolé, j'ai oublié une instruction rst.Update dans le Else :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
                    If rst("Reference") = stReference Then
                        rst("Consomation") = Nz(rst("quantite"), 0) - lgQteSuiv
                        rst.Update
                    Else
                        rst("Consomation") = Null
                        rst.Update
                    End If

[Apoulit]

Bonsoir,
oui j'avais corrigé