Discussion :

[TagadaJ]

Bonjour,

Novice en Windev, je suis en train de m'y mettre et après une approche un peu suspicieuse, je commence à lui trouver beaucoup de qualités.
Je suis passé par la formation vidéo en ligne et l'auto-formation. J'arrive maintenant dans la réalisation d'un petit projet.

Je voudrais pouvoir ajouter des images dans une fenêtre par programmation : ceci j'y arrive facilement avec ChampClone() et l'indirection.
Je voudrais pouvoir déplacer les images à la souris dans la fenêtre : ceci j'y arrive en ajoutant une procédure à l'évènement WM_LBUTTONDOWN

Pour dupliquer mon champ image :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
sNomImage est une chaîne
gnImage_Nbre++
sNomImage = "TABLE_UI_" + gnTable_Nbre
ChampClone("IMG_UI",sNomImage,10,80)
Evénement(Déplacer, {sNomImage +"..Nom"}, WM_LBUTTONDOWN)

La procédure pour bouger l'image (je l'ai trouvée sur le forum de PCSoft

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
 
PROCÉDURE Déplacer()
 
//On récupère la position du curseur au niveau de l'image
nXPos, nYPos est un entier
nXPos=SourisPosX()
nYPos=SourisPosY()
 
//tant que le clic gauche est enfoncé
TANTQUE ToucheEnfoncée(teBoutonG) = Vrai
	Multitâche(-1)
	//On récupère la position du curseur sur la fenêtre
	Res est un entier = CurseurPos(cpClient)
	SI Res <> -1 ALORS
		//On déplace le champ
		{MoiMême..Nom,indChamp}..X = PoidsFaible(Res) - nXPos
		{MoiMême..Nom,indChamp}..Y = PoidsFort(Res) - nYPos
	FIN
FIN

Maintenant, j'aimerais pouvoir redimensionner mon image à la souris : sans trouver de solution à ce problème.

J'ai vu également dans un poste qu'il existerait un exemple "WD poignée", mais que je ne trouve pas dans les exemples fournis avec ma version de Windev (une ancienne version 23), ce serait dans les nouvelles versions ?

[tbc92]

Je viens de trouver des commentaires sur cet exemple WD Poignées qui datent de 2007, donc cet exemple était déjà fourni.

Déjà, quel est le fonctionnement précis voulu.
On clique sur l'image (ou peut-être double-clic) et ce clic ajoute 4 poignées à l'image. Voire 8 poignées. Et quand ces poignées sont là, c'est plus facile (euh...).
Reste à définir quelle opération fera disparaître les poignées.
Puis à programmer ça.

[Voroltinquo]

Au fil des versions, certains exemples ont disparu.
WD poignées existe en WD 20 mais plus en 25.

[serendib]

Je viens de trouver des commentaires sur cet exemple WD Poignées qui datent de 2007, donc cet exemple était déjà fourni.

On clique sur l'image (ou peut-être double-clic) et ce clic ajoute 4 poignées à l'image. Voire 8 poignées. Et quand ces poignées sont là, c'est plus facile (euh...).
Reste à définir quelle opération fera disparaître les poignées.
Puis à programmer ça.

C'est exactement ce que fait l'exemple WD Poignée !

Je l'ai en WD55 mais il puisqu'il existe en WD20 quelqu'un pourrait lui envoyer.
Il migrera l'exemple pour son WD23.

[wd_newbie]

Tu as déjà fait le plus gros du boulot

Une solution, mettre, par exemple une forme (rond ... carré ) en le positionnement hors de la fenêtre : FRM_Poignee

Dans ta fonction "déplacer" tu ajoutes un code pour positionner la poignée au clic et lors du déplacement elle suit ton image :

Dans l'exemple gsElementActive est l'image en cours, si tu veux en mettre plusieurs

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
 
PROCÉDURE Déplacer()
 
//On récupère la position du curseur au niveau de l'image
nXPos, nYPos est un entier
nXPos=SourisPosX()
nYPos=SourisPosY()
 
// -- activer élement -- 
gsElementActive = MoiMême..Nom 
 
FRM_Poignee..Altitude = 1000000 // toujours au-dessus 
 
//tant que le clic gauche est enfoncé
TANTQUE ToucheEnfoncée(teBoutonG) = Vrai //et ToucheEnfoncée(teShift)
	Multitâche(-1)
	//On récupère la position du curseur sur la fenêtre
	Res est un entier = CurseurPos(cpClient)
	SI Res <> -1 ALORS
		//On déplace le champ
		{MoiMême..Nom,indChamp}..X = PoidsFaible(Res) - nXPos
		{MoiMême..Nom,indChamp}..Y = PoidsFort(Res) - nYPos
		FRM_Poignee..X = {gsElementActive + "..X",indChamp} +  {gsElementActive + "..Largeur",indChamp} - (FRM_Poignee..Largeur /2)
		FRM_Poignee..Y = {gsElementActive + "..Y",indChamp} +  {gsElementActive + "..Hauteur",indChamp}- (FRM_Poignee..Hauteur /2)
 
	FIN
FIN

et dans le code "Bouton gauche enfoncé" de la forme poignée, presque le même code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
 
 
//On récupère la position du curseur au niveau de l'image
nXPos, nYPos est un entier
nXPos=SourisPosX()
nYPos=SourisPosY()
 
 
//tant que le clic gauche est enfoncé
TANTQUE ToucheEnfoncée(teBoutonG) = Vrai //ET ToucheEnfoncée(teShift)
	Multitâche(-1)
	//On récupère la position du curseur sur la fenêtre
	Res est un entier = CurseurPos(cpClient)
	SI Res <> -1 ALORS
		//On déplace le champ
		FRM_Poignee..X = PoidsFaible(Res) - nXPos
		FRM_Poignee..Y = PoidsFort(Res) - nYPos
 
		{gsElementActive + "..Largeur",indChamp} = FRM_Poignee..X -{gsElementActive + "..X",indChamp} +(FRM_Poignee..Largeur/2)
		{gsElementActive + "..Hauteur",indChamp} = FRM_Poignee..Y -{gsElementActive + "..Y",indChamp} +(FRM_Poignee..Hauteur/2)
 
 
	FIN
FIN

A affiner, mais c'est fonctionnel

[TagadaJ]

Merci beaucoup, j'ai pu avancer avec l'astuce