Discussion :

[pubzyker]

Bonjour à tous,

J'aimerais calculer la Moving range comme montrer sur la photo, seulement cela ne marche pas j'ai essayé tous les calculs que j'ai pu voir sur internet mais tous le font à partir d'une date.

Alors que moi je veux le faire entre différents groupe qui ont tous un numéro unique.

Par exemple dans l'image, la premiere valeur de la colonne Moving Range devrait être nul puisque c'est la première mais ensuite cela devrait être : 4,92 - 4,76 = 0.16 pour la deuxieme ligne de la colonne Moving Range.

Etc ... similaire à un moving range classique sur Excel.

Pouvez vous m'aider ?

[pubzyker]

Aucune réponse ?

[XavierAllart]

Bonjour

Une solution consiste à ajouter 2 colonnes d'index, l'une commençant à 0, l'autre à 1
Fusionner la requête avec elle-même, sur le champ index.0 pour l'une et l'index.1 pour l'autre
Développer la table pour en extrait la colonne "data"
Calculer la différence entre les 2 colonnes data
Supprimer les colonnes devenues inutiles

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
 
let
    Source = Excel.CurrentWorkbook(){[Name="Tableau1"]}[Content],
    #"Type modifié" = Table.TransformColumnTypes(Source,{{"Groupe", Int64.Type}, {"data", type number}}),
    #"Index ajouté" = Table.AddIndexColumn(#"Type modifié", "Index", 1, 1, Int64.Type),
    #"Index ajouté1" = Table.AddIndexColumn(#"Index ajouté", "Index.1", 0, 1, Int64.Type),
    #"Requêtes fusionnées1" = Table.NestedJoin(#"Index ajouté1", {"Index.1"}, #"Index ajouté1", {"Index"}, "Index ajouté1", JoinKind.LeftOuter),
    #"Index ajouté1 développé" = Table.ExpandTableColumn(#"Requêtes fusionnées1", "Index ajouté1", {"data"}, {"Index ajouté1.data"}),
    #"Lignes triées" = Table.Sort(#"Index ajouté1 développé",{{"Index", Order.Ascending}}),
    #"Personnalisée ajoutée" = Table.AddColumn(#"Lignes triées", "Moving Range", each [Index ajouté1.data]-[data]),
    #"Colonnes supprimées1" = Table.RemoveColumns(#"Personnalisée ajoutée",{"Index", "Index.1", "Index ajouté1.data"}),
    #"Type modifié1" = Table.TransformColumnTypes(#"Colonnes supprimées1",{{"Moving Range", type number}}),
    Arrondi = Table.TransformColumns(#"Type modifié1",{{"Moving Range", each Number.Round(_, 2), type number}})
in
    Arrondi

Cordialement

[danixdb]

Bonjour pubzyker, le Forum,

Autre possibilité avec là aussi ajout d'une colonne Index

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
 
let
    Source = Excel.CurrentWorkbook(){[Name="tabData"]}[Content],
    ModificationTypeDonnees = Table.TransformColumnTypes(Source,{{"Numéro Groupe", Int64.Type}, {"Data", type number}}),
    AjoutIndexColonne = Table.AddIndexColumn(ModificationTypeDonnees, "Index", 0, 1, Int64.Type),
    CalculEcart = Table.AddColumn(AjoutIndexColonne, "Ecart", each try AjoutIndexColonne[Data]{[Index]-1} - [Data] otherwise null),
    SuppressionColonnes = Table.RemoveColumns(CalculEcart,{"Index"})    
in
    SuppressionColonnes

Cordialement
DabixDB

[comme de bien entendu]

Bonjour, je reviens sur ce sujet, il est possible aussi en Dax d'obtenir un décalage entre deux colonne et de calculer la différence.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Measure = CALCULATE(max('Table'[ColonnePourEffectuerUnCalcul]), FILTER(ALL('Table'), 'Table'[Value] = EARLIER('Table'[Value]) - 1))