Discussion :

[HABILER]

Bonjour,

Le but du code ci dessous est de permuter le nom d'un fichier AAAA - BBB en BBB - AAAA.
Le problème c'est qu'il y a un caractère blanc devant BBB après permutation.

Quelqu'un pourrait-il me conseiller ?

Un grand merci d'avance.

Habiler

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub Perm_Mat_Name()
 
Dim OldFolderName, NewFolderName As String
Dim objFileSystem As Object
 Dim newName As String
 Dim newNameSplit As String
 Dim splitMatrNom() As String
 
Set objFSO = New FileSystemObject
Set mysource = objFSO.GetFolder("C:\PERS")
Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    Dim i As Long
    For Each Folder In mysource.SubFolders
 
 
    splitMatrNom = Split(Folder.Name, "-")
  '  Debug.Print splitMatrNom(1)
 
      'For i = LBound(splitMatrNom) To UBound(splitMatrNom)
     newNameSplit = splitMatrNom(1) & " - " & splitMatrNom(0)
     Debug.Print newNameSplit
        If Folder.Name <> newName Then Folder.Name = newNameSplit
        'Next i
    Next Folder
 
End Sub

[Philippe Tulliez]

Bonjour,
C'est tout à fait normal qu'il y a ait des caractères espacés de trop puisque ce qui sépare les deux mots est un trigramme " - " or vous utilisé la fonction Split avec comme second argument un tiret, il faudrait donc choisir " - "

Exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub t()
  Dim t As Variant
  Dim n As String
  n = "AAA - BBB"
  t = Split(n, " - ")
  n = t(1) & " - " & t(0)
  Debug.Print n
End Sub

[EDIT]
Autre exemple où l'on supprime tous les caractères espacés avant de construire la table avec la fonction Split

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub t()
  Dim t As Variant
  Dim n As String
  n = Trim(Replace("AAA - BBB", " ", ""))
  t = Split(n, "-")
  n = t(1) & " - " & t(0)
  Debug.Print n
End Sub

[deedolith]

3e option, on passe par les regex:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Dim Data As String
Data = "AAAA - BBBB"
 
Dim Rx As Object    '// VbScript.RegExp
Set Rx = CreateObject("VbScript.RegExp")
Rx.Pattern = "(.*) - (.*)"
Data = Rx.Replace(Data, "$2 - $1")

[HABILER]

Merci pour vos réponses rapides.

Mais j'ai perdu de vue que mon code tournait en boucle. il recommence l'opération en sens inverse une fois la 1ére permutation effectuée.

j'essaie avec la fonction is numeric pour ne traiter que les folders commencant par un chiffre mais je me plante.

[jurassic pork]

Hello,

Mais j'ai perdu de vue que mon code tournait en boucle. il recommence l'opération en sens inverse une fois la 1ére permutation effectuée.

tournait en boucle ? c'est à dire ?
Avec ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub Perm_Mat_Name()
Dim OldFolderName, NewFolderName As String
Dim objFSO As Object, mysource As Object, Folder As Object
Dim newName As String, newNameSplit As String, splitMatrNom() As String
 
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set mysource = objFSO.GetFolder("D:\Test\Pers")
For Each Folder In mysource.SubFolders
    splitMatrNom = Split(Folder.Name, " - ")
    newNameSplit = splitMatrNom(1) & " - " & splitMatrNom(0)
    Debug.Print newNameSplit
    If Folder.Name <> newName Then Folder.Name = newNameSplit
    Next Folder
End Sub

et avec AAAA - BBB et CCCC - DDD dans le répertoire D:\Test\Pers
j'obtiens ceci sans qu'il n'y ait de rebouclage :



Ami calmant, J.P