Discussion :

[Mél3790]

Bonjour à toutes et tous,

Je souhaite une macro qui balaye ma colonne A. Si dans ma colonne A la macro trouve des cellules qui contiennent le mot "*AVIS*" alors dans les cellules en face à droite (en colonne C), ça doit écrire OK, sinon PAS OK.

J'espère être claire

Merci beaucoup pour votre aide !

J'ai pourtant fait pas mal de macro, votre site m'a beaucoup aidé, mais là, je ne sais pas pourquoi, je bug lol

Merci encore

Mél.

[Raccourcix]

Bonjour

pourquoi une macro, une formule suffit

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(ESTNUM(CHERCHE("AVIS";A2));"OK";"Pas OK")

Stéphane

[Mél3790]

Bonjour,

Merci beaucoup pour votre réponse et votre intérêt à mon soucis

Je ne souhaite pas une formule car ce n'est pas valable pour toutes les lignes. Il y a des valeurs en colonne C qui sont introduites déjà par d'autres procédures VB.
(je précise que c'est dans le cadre professionnel)

La macro que je souhaite réaliser serait à inscrire en fin de procédure existante pour remplacer les valeurs précédemment introduites.

J'espère est compréhensible :/

Merci

[jurassic pork]

Hello,

Je ne souhaite pas une formule car ce n'est pas valable pour toutes les lignes. Il y a des valeurs en colonne C qui sont introduites déjà par d'autres procédures VB.

Si on fait ce que tu nous décris , en colonne C il ne devrait plus y avoir que des OK ou des PAS OK donc les valeurs introduites en C sont alors écrasées ?

Ami calmant, J.P

[Mél3790]

Par ma première procédure il y a écrit 'À valider'
Donc la macro doit écraser ce mot et écrire OK ou Pas OK en fonction des valeurs en colonne A

[jurassic pork]

Hello,
voici une macro qui devrait faire l'affaire.
Le principe :
On récupère les valeurs de la colonne A (utilisation de la plage nommée Data) dans un tableau
On crée un second tableau de la taille du premier tableau
On balaie les valeurs du premier tableau en les comparant avec l'opérateur Like à "*AVIS*"

L'opérateur logique LIKE est un opérateur d'égalité strictement réservé aux chaines de type texte. Sa particularité est de pouvoir comparer des valeurs à un masque composé de caractères de substitution. Cet opérateur peut être utilisé avec SQL, VBA ou encore dans des expressions."

Si il y a égalité on met OK dans le deuxième tableau sinon PAS OK.
Quand on a fini le balayage on transfert le deuxième tableau dans une plage de même taille que Data mais en colonne C ( Offset(0,2) ) .
le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub ChercheAvis()
Dim myArr As Variant, elem As Variant, x As Integer
myArr = Sheets("Feuille1").Range("Data")
ReDim arrayData(1 To UBound(myArr), 1 To 1) As Variant
x = 1
For Each elem In myArr
    If UCase(elem) Like "*AVIS*" Then
         arrayData(x, 1) = "OK"
    Else
         arrayData(x, 1) = "PAS OK"
    End If
    x = x + 1
Next elem
Sheets("Feuille1").Range("Data").Offset(0, 2).Value = arrayData 'Offset(0,2) -> colonne C
End Sub

Le résultat :


Ami calmant, J.P

[Philippe Tulliez]

Bonjour,
Une autre proposition en écrivant en colonne C, la formule proposée pas Stéphane

Dans cet exemple la première ligne contient les titres et on suppose que la colonne A est remplie de la première à la dernière ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub t2()
  Const FormulaText = "=IF(ISNUMBER(SEARCH(""AVIS"",A2)),""OK"",""Pas OK"")"
  Dim rng As Range
  Set rng = ActiveSheet.Range("A1").CurrentRegion
  With rng
   With .Offset(1, 2).Resize(.Rows.Count - 1, 1)
   .Formula = FormulaText ' Ecriture de la formule sur l'ensemble de la colonne C
   .Value = .Value        ' Suppression de la formule au profit du résultat
   End With
  End With
  Set rng = Nothing
End Sub

[Mél3790]

Bonjour

Vos solutions sont parfaites, je vais l'adapter par rapport à ma première procédure, vous êtes géniaux, merci beaucoup beaucoup beaucoup !! Trop fort !!

A bientôt !!!!!!

Mél.

[Mél3790]

C'est re moi

Je reviens sur le sujet pour un petit + svp

Dans ma colonne A si like "*PV*" alors en colonne C ce qui est écrit ne doit pas être écrasé.

Comment vous feriez en reprenant la macro :

Sub ChercheAvis()
Dim myArr As Variant, elem As Variant, x As Integer
myArr = Sheets("Voiture").Range("Data2")
ReDim arrayData(1 To UBound(myArr), 1 To 1) As Variant
x = 1
For Each elem In myArr
If UCase(elem) Like "*AVIS*" Then
arrayData(x, 1) = "OK"
ElseIf UCase(elem) Like "*BPM*" Then
arrayData(x, 1) = "PAS OK"
Else
End If
x = x + 1
Next elem
Sheets("Voiture").Range("Data2").Offset(0, 2).Value = arrayData
End Sub

[jurassic pork]

Dans ce cas on ne peut plus passer par la solution plage tableau. Il faut balayer les cellules directement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub ChercheAvis()
Dim cellule As Variant
Application.ScreenUpdating = False
For Each cellule In Sheets("Feuille1").Range("Data")
    If UCase(cellule.Value) Like "*AVIS*" Then
         cellule.Offset(0, 2).Value = "OK"
    ElseIf UCase(cellule.Value) Like "*BPM*" Then
         cellule.Offset(0, 2).Value = "PAS OK"
    End If
Next cellule
Application.ScreenUpdating = True
End Sub

[Mél3790]

Et bien parfait, ça fonctionne à la perfection, trop balaise !

merciiiiii !