Discussion :

[Philippe Tulliez]

Bonjour,
Je voudrais réaliser à l’aide de Power Query une liste unique des éléments se trouvant dans la table de gauche mais avec certaines contraintes
S’il y un "X" dans la colonne « Adr », c’est cette ligne qui doit être conservée et s’il y a un "O" dans la colonne « Dispatch » toutes les lignes ayant la même valeur dans la colonne « Facturation » doivent être copiées
Merci pour vos lumières

[Promethee25]

Bonjour Philippe,

Le cas où l'on a à la fois X et O pour des lignes (potentiellement différentes) correspondant à la même facturation et le cas où l'on a ni l'un ni l'autre mais tout de même plusieurs lignes pour la même facturation n'étant pas adressés (car potentiellement impossibles?), j'ai opté pour un OU(X absent, O présent) comme critère de récupération de toutes les lignes pour une facturation donnée, à adapter bien sûr selon le besoin réel.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
let
    Source = Excel.CurrentWorkbook(){[Name="Tableau1"]}[Content],
    #"Changed Type" = Table.TransformColumnTypes(Source,{{"Facturation", type text}, {"Filiale", type text}, {"Adr", type text}, {"Dispatch", type text}, {"Nbre", Int64.Type}}),
    #"Grouped Rows" = Table.Group(#"Changed Type", {"Facturation"}, {{"Lignes", each _, type table}, {"Dispatch O?", each List.Max([Dispatch]), type text}, {"Adr X?", each List.Max([Adr]), type text}}),
    #"Filtered subrows" = Table.AddColumn(#"Grouped Rows", "Lignes filtrées", each if [#"Dispatch O?"] = "O" or [#"Adr X?"] = null then [Lignes] else Table.SelectRows([Lignes], each _[Adr] = "X"), Value.Type(#"Grouped Rows"[Lignes]{0})),
    #"Removed Columns" = Table.RemoveColumns(#"Filtered subrows",{"Lignes", "Dispatch O?", "Adr X?"}),
    #"Expanded {0}" = Table.ExpandTableColumn(#"Removed Columns", "Lignes filtrées", {"Filiale"}, {"Filiale"})
in
    #"Expanded {0}"

On aurait pu faire sans les colonnes intermédiaires "Dispatch O?" et "Adr X?" en travaillant directement sur les tables contenues dans chaque case de la colonne Lignes obtenues par regroupement (par exemple en créant une fonction personnalisée travaillant sur chacune de ces tables) mais la méthode ci-dessus m'a semblé plus simple (avec l'astuce du List.Max pour savoir s'il y a au moins un X ou au moins un O dans les lignes regroupées).
Cette astuce fonctionne bien sur l'exemple où l'on a soit X, soit null (resp. soit O, soit null).

Note que le "Value.Type(#"Grouped Rows"[Lignes]{0})" me permet de récupérer le type de la colonne Lignes (contenant les tables regroupées) et de l'appliquer directement sur la nouvelle colonne "Nouvelles lignes" (contenant les tables regroupées ET filtrées) sans avoir à réfléchir ni maintenir les types colonne par colonne.

[Philippe Tulliez]

Bonjour Promethee,
Un tout grand merci et bravo pour la simplicité
J'étais parti avec une création d'une ou deux tables en mémoire mais je m'étais emmêlé les pinceaux.

[Raccourcix]

Bonjour Philippe, Promethee

Je pense qu'on peut aussi passer par une fusion.
On filtre les X dans le champ Adr, on remplace ces X par des null et on fusionne la source et les lignes que l'on vient de sélectionner en LeftAnti sur les champs "Facturation" et "Adr" pour exclure ces lignes.
Il ne reste plus qu'à supprimer la colonne de fusion

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
let
    Source = Excel.CurrentWorkbook(){[Name="Tableau1"]}[Content],
    #"Lignes filtrées" = Table.SelectRows(Source, each [Adr] = "X"),
    #"Valeur remplacée" = Table.ReplaceValue(#"Lignes filtrées","X",null,Replacer.ReplaceValue,{"Adr"}),
    #"Requêtes fusionnées" = Table.NestedJoin(Source, {"Facturation", "Adr"}, #"Valeur remplacée", {"Facturation","Adr"}, "Filtre", JoinKind.LeftAnti),
    #"Colonnes supprimées" = Table.RemoveColumns(#"Requêtes fusionnées",{"Filtre"})
in
    #"Colonnes supprimées"

Stéphane

[Philippe Tulliez]

Bonjour Stéphane,
Merci pour cette autre solution intéressante mais lorsque un "O" se trouve présent dans la colonne Dispatch et un "X" dans la colonne Adr il faudrait obtenir une ligne par filiale comme la ligne ayant comme code de facturation S011