Discussion :

[bobolecoco]

Bonjour.
J'aimerais qu'une macro se lance à l'ouverture de tout fichier Excel (xls/xlsx).

Ceci marche avec un fichier qu'on ouvrirait alors qu'Excel n'était pas lancé :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub Workbook_Open()
  LES ACTIONS À RÉALISER
End Sub

Mais si Excel est déjà lancé (un autre fichier Excel est déjà ouvert par exemple) et que je j'ouvre un fichier xls/xlsx, la macro ne se lance pas dans ce nouveau fichier ouvert.

J'ai essayé avec Private Sub Worksheet_Activate() et Private Sub Workbook_WindowActivate(ByVal Wn As Excel.Window) en les mettant aussi bien dans ThisWorkbook et dans Module1 sans résultat concluant.

Comment puis-je réaliser ce que je souhaite (lancer une macro à l'ouverture d'un fichier xls, qu'importe si Excel est déjà lancé ou non) ?

Merci d'avance !

[Jean-Philippe André]

Salut,

l'evenement que tu utilises est le bon, mais j'ai du mal à comprendre ton soucis.

Est-ce que tu veux dire que ton code ne s'exécute pas lorsque ton classeur s'ouvre ? Les macros sont-elles bien activées ?

Quel est le contenu de ta macro ?

[hyperion13]

Salut
Probablement un début de piste ici et là

[bobolecoco]

Merci hyperion13, mais ça, c'est déjà fait depuis le début (et indispensable pour que la macro fonctionne sur n'importe quel fichier je pense).

Pour répondre à Jean-Philippe André :

Voici les codes dans "VBAProject (PERSONAL.XLSB)" :
- dans "ThisWorkbook" une première macro qui doit lancer une autre cinq secondes après l'ouverture du fichier :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Private Sub Workbook_Open()
    On Error Resume Next
    Application.OnTime Now + TimeValue("00:00:05"), "Macro1"
End Sub

- dans "Modules" -> "Module1" :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Sub Macro1()
 Range("B2").Select
End Sub

Pour tester, j'ai fait deux fichiers "1.xlsx" et "2.xlsx" (qui sont des documents "vides", ne contenant aucune donnée).
1. Ouvrons "1.xlsx". Au bout de cinq secondes, la cellule B2 est sélectionnée.
Fermons "1.xlsx" et Excel.
2. Ouvrons "2.xlsx". Au bout de cinq secondes, la cellule B2 est sélectionnée cette fois encore.
Fermons "2.xlsx" et Excel.
3. Ouvrons "1.xlsx". Au bout de cinq secondes, la cellule B2 est sélectionnée.
Ouvrons "2.xlsx" en laissant "1.xlsx" et donc Excel ouverts. B2 n'est pas sélectionnée dans "2.xlsx"

Donc la macro n'est pas lancé à l'ouverture du fichier (elle se lance une fois à l'ouverture d'Excel, pas du fichier)

J'espère que c'est plus clair.

[hyperion13]

re,
Je ne l'avais pas remarqué dans votre Post#1

Merci hyperion13, mais ça, c'est déjà fait depuis le début (et indispensable pour que la macro fonctionne sur n'importe quel fichier je pense)

Alors Excel est une application, Workbook est un classeur et Workbook_open est une procédure qui permet d'exécuter des macros à l'ouverture d'un classeur. Et correspond qu'à une seule instance.
Dans votre cas, il faudrait ajouter dans la sub workbook_open() un second OnTime avec un délai un peu plus grand qui appellerait une Macro2 par exemple pour qu'elle fasse une boucle For Each xlWbk In Application.Workbooks et re-déclenche votre Macro1.

[bobolecoco]

Merci hyperion13, ça fonctionne (pas exactement comme je le veux), mais je m'en sors. La macro se relance infiniment.

ThisWorkbook :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Private Sub Workbook_Open()
On Error Resume Next
    Application.OnTime Now + TimeValue("00:00:01"), "Launch"
On Error Resume Next
    Application.OnTime Now + TimeValue("00:00:02"), "SecondLaunch"
End Sub

Module 1 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub Launch()
    Range("B2").Select
End Sub
 
Private Sub SecondLaunch()
  For Each xlWbk In Application.Workbooks()
      Application.OnTime Now + TimeValue("00:00:01"), "ImprimerLePlanning"
      Application.OnTime Now + TimeValue("00:00:02"), "SecondLaunch"
  Exit For
  Next
End Sub

Si dans la macro SecondLaunch je ne mets pas Application.OnTime Now + TimeValue("00:00:02"), "SecondLaunch", alors la macro se relance pour un seul fichier qu'on ouvrirait après le premier. Si je mets Application.OnTime Now + TimeValue("00:00:02"), "SecondLaunch", la macro se relance sans arrêt (je dois ajouter une ligne dans la macro "Launch" qui met une "marque" dans le fichier qui dit que la macro a déjà été lancée et qui s'assure que cette marque n'existe pas avant d’exécuter le contenu de la macro...). Mais ça fonctionne pour mon utilisation.

[Valtrase]

Salut le fil
Si j'ai bien compris lancement de la macro si premier fichier ouvert sinon pas de lancement, donc en regardant du côté des fenêtres ouvertes tu dois pouvoir faire cela non ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Private Sub Workbook_Open()
    If Application.Windows.Count = 1 Then
        ' // Ta Macro
        Call MyMacro
    Else
        MsgBox "Vous avez " & Application.Windows.Count & " classeur(s) ouvert(s)." & vbCrLf _
             & "La macro de démarrage ne sera pas lancée", vbOKOnly Or vbInformation, "Lancement des macros non autorisé"
 
 
    End If
End Sub

[Philippe Tulliez]

Bonjour,
Les procédures événementielles de PERSONNA.XLSB se gèrent de la même manière que celles des AddIns (macros complémentaires)

Toutes les procédures événementielles préfixées Workbook ne concernent que le classeur des macros complémentaires (xlam)
Pour intercepter les événements de tous les autres classeurs, il y a lieu de créer une instance Application

Code à placer dans le module ThisWorkbook du classeur nommé [B]PERSONNA.XLSB[/B

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Option Explicit
Public WithEvents appXls As Excel.Application
 
Private Sub Workbook_Open()
  ' Ouverture de PERSONNAL.XLSB
  Set appXls = Excel.Application
End Sub
 
Private Sub appXls_WorkbookOpen(ByVal Wb As Workbook)
  ' Ouverture de n'importe quel classeur
  If Me.Name <> Workbooks(Workbooks.Count).Name Then
     MsgBox "Vous venez d'ouvrir le classeur " & ActiveWorkbook.Name
  End If
End Sub

Dans cet exemple, à adapter, une boîte de dialogue (MsgBox) affichera le nom du classeur que l'on vient d'ouvrir.

Voir mon tutoriel sur le sujet titré VBA - Excel - Macros complémentaires - Les procédures événementielles