Discussion :

[morobaboumar]

Bonsoir membres du forum,
je recherche la bonne méthode pour générer les rangs d'une classe.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
 
' ++++ Fonct. pour Générer le RANG ANNUEL d'une Classe Arabe
Public Sub RangClasseAnnuelArabe(idetabR As Long, AnneeScol As String, claSar As String)
Dim db As Database
Dim rst As Recordset
Dim SQL As String
Dim i As Integer
Dim j As Integer
Dim K As Integer
Dim Moy As Single
Set db = CurrentDb
SQL = "select * from BILAN_ANNUEL_ARABE where ID_ETABLI = " & idetabR & " and anscol = '" & AnneeScol & "' and ClasseArabe = '" & claSar & "' order by MoyAnnuel desc ;"
    Set rst = db.OpenRecordset(SQL)
    If Not rst.EOF Then
    rst.MoveLast
    rst.MoveFirst
    'bolEx = True
    i = 1
    K = 1
        Do While Not rst.EOF
            rst.Edit
 
 
                If i = 1 Then
                    If GenreEleve(rst.Fields("mle_Eleve")) = "Masculin" Then
                        rst.Fields("Classement") = i & "er"
                    Else
                        rst.Fields("Classement") = i & "ère"
                    End If
 
                Else
 
If Moy = rst.Fields("MoyAnnuel") Then
                        If K = 1 Then   'Traitement du 1er Ex-Equo
                            j = i - 1
                    If GenreEleve(rst.Fields("mle_Eleve")) = "Masculin" Then
                            rst.Fields("Classement") = j & "er ex."
                            K = K + 1
                        Else
                            rst.Fields("Classement") = j & "è ex."
                        End If
                    End If
                    Else
 
                        K = 1
                        rst.Fields("Classement") = i & "è"
                    End If
                End If
 
                rst.Update
                Moy = rst.Fields("MoyAnnuel")
                i = i + 1
                rst.MoveNext
            Loop
    End If
    rst.Close
    Set rst = Nothing
End Sub

Voici les erreurs constatées:




Au lieu de 1er si genre Masculin, 1ère si Féminin. .Et 41ième ex éco le code renvoie 41er ex éco.
Cette discussion est en rapport avec la pièce jointe d'ici https://www.developpez.net/forums/d2...es-intervalle/
Cordialement.

[morobaboumar]

Bonjour membres du forum,
Mon problème au niveau de ce code
se trouve dans les variables (i =1; k=1; j = i - 1; K = K + 1).
N'est ce pas à cause de cela
qu'il y a des erreurs lorsque le code génère le rang?
Cordialement.

[tee_grandbois]

bonjour,

Mon problème au niveau de ce code
se trouve dans les variables (i =1; k=1; j = i - 1; K = K + 1).
N'est ce pas à cause de cela
qu'il y a des erreurs lorsque le code génère le rang?

le problème vient du fait que tu traites la meilleure moyenne de la classe de la même façon que les autres, car il n'y a qu'à ce niveau qu'il y a une distinction:
Par exemple, si 3 élèves ont la meilleure note, ça donne ceci:
1er
1ère ex.
1er ex.
ou cela:
1ère
1er ex.
1ère ex.
donc ton problème est simple: traiter le cas des ex-aequo de la meilleure moyenne ( en la mémorisant lors de la lecture du premier enregistrement, par exemple) en tenant compte du genre puisque pour les autres places c'est toujours "nè"
Personnellement, je ne me serai pas embêté pour si peu dans un monde où la langue française est si maltraitée mais comme j'ai trouvé la solution je te la donne:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
' ++++ Fonct. pour Générer le RANG ANNUEL d'une Classe Arabe
Public Sub RangClasseAnnuelArabe(idetabR As Long, AnneeScol As String, claSar As String)
Dim db As Database
Dim rst As Recordset
Dim SQL As String
Dim i As Integer
Dim j As Integer
Dim K As Integer
Dim Moy As Single
Dim TopMoy As Single  ' détermine la meilleure moyenne de la classe
 
Set db = CurrentDb
SQL = "select * from BILAN_ANNUEL_ARABE where ID_ETABLI = " & idetabR & " and anscol = '" & AnneeScol & "' and ClasseArabe = '" & claSar & "' order by MoyAnnuel desc ;"
    Set rst = db.OpenRecordset(SQL)
    If Not rst.EOF Then
    rst.MoveLast
    rst.MoveFirst
    'bolEx = True
    i = 1
    K = 1
        Do While Not rst.EOF
            rst.Edit
 
 
            If i = 1 Then
                If GenreEleve(rst.Fields("mle_Eleve")) = "Masculin" Then
                    rst.Fields("Classement") = i & "er"
                Else
                    rst.Fields("Classement") = i & "ère"
                End If
 
            Else
 
                If Moy = rst.Fields("MoyAnnuel") Then   'Traitement des ex-aequo
                    If K = 1 Then   'Traitement du 1er Ex-Equo
                        K = K + 1
                        j = i - 1
                                    'Traitement pour les premiers de la classe
                        If Moy = TopMoy Then
                            If GenreEleve(rst.Fields("mle_Eleve")) = "Masculin" Then
                                rst.Fields("Classement") = j & "er ex."
                            Else
                                rst.Fields("Classement") = j & "ère ex."
                            End If
                        Else
                            rst.Fields("Classement") = j & "è ex."
                        End If
                    Else            'Traitement des autres ex-aequo
                        rst.Fields("Classement") = j & "è ex."
                    End If
                Else
                    K = 1
                    rst.Fields("Classement") = i & "è"
                End If
            End If
 
            rst.Update
            Moy = rst.Fields("MoyAnnuel")
            If i = 1 Then TopMoy = Moy      ' on mémorise aussi la meilleure moyenne
            i = i + 1
            rst.MoveNext
        Loop
    End If
    rst.Close
    Set rst = Nothing
End Sub

autre chose: j'éviterai de faire appel systématiquement à des fonctions lorsqu'une information peut être accessible via une jointure:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

GenreEleve(rst.Fields("mle_Eleve")) = "Masculin"

je ferai ceci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 SQL = "SELECT BILAN_ANNUEL_ARABE.*, ELEVE.genre FROM BILAN_ANNUEL_ARABE INNER JOIN ELEVE ON BILAN_ANNUEL_ARABE.mle_Eleve = ELEVE.mleeleve" _
     & " WHERE ID_ETABLI = " & idetabR & " and anscol = '" & AnneeScol & "' and ClasseArabe = '" & claSar & "' order by MoyAnnuel desc ;"

et cela:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If rst.Fields("genre") = "Masculin" Then

mais si tu préfères te compliquer, c'est un choix

[morobaboumar]

Bonjour tee_grandbois,
Je suis émerveillé par votre style.
Si je pourrais faire comme vous.
Expert Senior tee_grandbois, quel excellence.





Je reste dans le cadre de vos conseils.
Merci infiniment.