Discussion :

[OBIWAN64]

Bonjour à toutes et à tous,
Je dispose d'une base de données conçue sous access 2003 et qui tourne actuellement sous access 2019. La base est toujours au format mdb.
Je ne parviens pas à utiliser l'outil permettant d'obtenir les dépendances d'objets. Je ne l'ai pas fait tourner depuis que l'on m'a installé access 2019.
A chaque fois le message suivant apparaît :


J'ai effectué les vérifications suivantes :
Dans les options d'access :
- si les cases relatives à la correction automatique de nom sont cochées, le message apparaît presque instantanément,
- si les cases ne sont pas cochées la dépendance d'objets tourne, mais le message apparaît à la fin et je n'ai pas de résultat.

J'ai également vérifié les droits d'accès, je suis en administrateur sur tous les objets de la base.

Auriez-vous une idée me permettant d'identifier le problème ?

D'avance merci.

[loufab]

Bonjour,

Une fois converti en accdb ça ne fonctionne toujours pas ?

Cordialement,

[OBIWAN64]

Bonjour et merci de me répondre.
Je viens de convertir la base en accdb. Ça ne fonctionne toujours pas.

Je voulais utiliser la dépendance d'objets pour repérer ceux qui seraient "orphelins" ou inutiles et faire du ménage dans la base.
Y aurait-il un autre moyen d'obtenir les dépendances ?

Cordialement.

[User]

Bonjour,

En complément, comment avez-vous fait pour faire fonctionner l'outil sur les objets de votre base de données ?

Importations de vos objets dans l'outil ou inversement en utilisant un complément installé dans votre base ?

Cdlt,

[OBIWAN64]

Bonjour User,
J'ai procédé de la manière suivante : une fois la base ouverte je suis allé dans la barre de menu dans l'onglet "Outils de base de données" et j'ai cliqué sur "Dépendances d'objet".

Cordialement.

[User]

Bonjour,

J'avais compris que vous vouliez utiliser cet outil qui est super :

https://www.developpez.net/forums/d8...ntenant-texte/

Apparemment, juste besoins d'importer le formulaire DépendancesPlus dans votre base

[OBIWAN64]

Bonjour User,
Je te remercie pour le lien.
J'ai intégré le formulaire à ma base de données. Il est vraiment très bien.
Cependant il semble afficher les objets dépendants d'un objet que l'on sélectionne et pas les objets dont dépend cet objet sélectionné (ou alors je m'y suis mal pris).
Et la manipulation doit être opéré pour chaque objet.

J'aurai souhaité une solution globale qui pour chaque objet m'indique le ou les objets dont il dépend et le ou les objets qui dépendent de lui.
Malheureusement je suis toujours coincé avec l'outil des dépendances intégré à access qui ne fonctionne pas.

Cordialement.

[User]

Bonjour,

J'ignore si tu auras toujours ce message, mais tu peux essayer de le faire avec du code VBA en utilisant l'objet Dependencyinfo (récupéré avec GetDependencyInfo) et ses propriétés Dependants et Dependencies :

https://docs.microsoft.com/fr-fr/off...dependencyinfo

Comme indiqué par EricDgn à la fin de cette discussion :

https://www.developpez.net/forums/d1...es-objets-vba/

En listant les objets par type d'objet tu obtiens donc ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
Option Compare Database
Option Explicit
 
'--- https://flylib.com/books/en/1.129.1.105/1/
Public Sub ShowDependencies(intType As AcObjectType, strName As String)
   ' Show dependency information for the specified object
   Dim AO As AccessObject
   Dim AO2 As AccessObject
   Dim DI As DependencyInfo
   'On Error GoTo HandleErr
   ' Get the AccessObject
   Select Case intType
     Case acTable
        Set AO = CurrentData.AllTables(strName)
       Debug.Print "Table: ";
     Case acQuery
       Set AO = CurrentData.AllQueries(strName)
       Debug.Print "Query: ";
     Case acForm
       Set AO = CurrentProject.AllForms(strName)
       Debug.Print "Form: ";
     Case acReport
       Set AO = CurrentProject.AllReports(strName)
       Debug.Print "Report: ";
   End Select
   Debug.Print strName
   ' Get the dependency info
   Set DI = AO.GetDependencyInfo()
   ' Print results
   If DI.Dependencies.Count = 0 Then
     Debug.Print "Pas d'objet dont dépend de cet objet"
   Else
     Debug.Print "Les objets dont depend cet objet:"
     For Each AO2 In DI.Dependencies
       Select Case AO2.Type
         Case acTable
           Debug.Print "  Table: ";
         Case acQuery
           Debug.Print "  Query: ";
         Case acForm
           Debug.Print "  Form: ";
         Case acReport
           Debug.Print "  Report: ";
       End Select
       Debug.Print AO2.Name
     Next AO2
   End If
   If DI.Dependants.Count = 0 Then
     Debug.Print "Pas d'objet dépendant de cet objet"
   Else
     Debug.Print "Ces objets dependent de cet objet:"
     For Each AO2 In DI.Dependants
       Select Case AO2.Type
         Case acTable
           Debug.Print "  Table: ";
         Case acQuery
           Debug.Print "  Query: ";
         Case acForm
           Debug.Print "  Form: ";
         Case acReport
           Debug.Print "  Report: ";
       End Select
       Debug.Print AO2.Name
     Next AO2
   End If
ExitHere:
   Exit Sub
HandleErr:
   MsgBox "Error " & Err.Number & ": " & Err.Description, vbCritical
   Resume ExitHere
End Sub
 
Public Function generateDependances()
    Dim tdf As TableDef
    Dim qry As QueryDef
    Dim obj As AccessObject
 
    For Each tdf In CurrentDb.TableDefs
        If (tdf.Attributes And dbSystemObject) = 0 Then
            ShowDependencies acTable, tdf.Name
        End If
    Next
 
    For Each qry In CurrentDb.QueryDefs
        If Left(qry.Name, 1) <> "~" Then
            ShowDependencies acQuery, qry.Name
        End If
    Next
 
    For Each obj In CurrentProject.AllForms
        ShowDependencies acForm, obj.Name
    Next
 
    For Each obj In CurrentProject.AllReports
        ShowDependencies acReport, obj.Name
    Next
 
End Function

Et pour tester la fonction tu fais simplement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

? generateDependances()

[OBIWAN64]

bonjour User,
C'est exactement ce dont j'ai besoin. Formidable.

Merci à toi.

[hyperion13]

Salut
Je viens de trouver ceci. Sait-on jamais.

[User]

Bonjour,

J'ai commencé un outil pour générer un arbre des dépendances entre objets :



ça me semble bien d'avoir une vue d'ensemble sous forme d'arborescence.

Je joins la base pour les tests, il faut ouvrir le formulaire DependancesObjets.

Cdlt,

[OBIWAN64]

Rebonjour,

hyperion 13, je te remercie. Je l'ai trouvé aussi tout à l'heure. Malheureusement je ne peux pas le tester. Je ne peux installer aucun complément car je n'ai pas d'autorisations de sécurité suffisantes

User, encore merci à toi de te casser la tête pour mon problème. C'est effectivement très visuel et on a une belle vue d'ensemble.
Dans ta base test ça tourne sans problème.
Du coup j'ai essayé d'intégrer le formulaire DependancesObjets à ma base, ainsi que le module M_DependancesObjets. Quand j'ouvre le formulaire au bout d'un moment ça bloque sur la variable tvwChild qui est dans la fonction genArbreDependances avec le message "erreur de compilation variable non définie".
Je ne comprend pas comment la variable peut passer dans ta base test et pas dans ma base.

Cordialement.

[User]

Bonjour,

Je dois encore améliorer l'outil pour gérer notamment les références circulaires que je compte mettre à la racine.

Cdlt,

[User]

Bonjour,

Concernant ton message d'erreur, ça pourrait venir de fichiers mdb ou de bases mdb converties en accdb et que tu ouvre avec une version récente.

Donc, il vaudrait mieux importer les objets de ta base mdb dans une base vierge au format accdb, plutôt que de la convertir.

J'ai mis à jour l'outil, le souci c'est que le formulaire peut être long à charger quand il y a beaucoup d'objets.

Cela vient de la recherche des infos sur les dépendances entre tous les objets qui prend du temps, donc je ne pense pas qu'on puisse améliorer les choses à ce niveau là.

Du coup j'ai créé un système qui permet d'enregistrer les dépendances entre objets dans une table à la fermeture du formulaire.

Ensuite la réouverture du formulaire est rapide, mais il faut quand même l'ouvrir une première fois.


Il faut donc importer les 2 objets dans ta base :

• Formulaire : F_DependancesObjets
• Module : M_DependancesObjets

Ensuite, ouvrir le formulaire F_DependancesObjets. J'ai mis sur l'événement Ouverture une commande pour référencer l'ocx du TreeView :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub Form_Open(Cancel As Integer)
    On Error Resume Next
 
    #If Win64 Then
        References.AddFromFile Environ("SystemRoot") & "\SysWOW64\MSCOMCTL2.OCX"
    #Else
        References.AddFromFile Environ("SystemRoot") & "\SYSTEM32\MSCOMCTL.OCX"
    #End If
 
End Sub

Avec un horrible On Error Resume Next pour passer la référence si elle existe déjà.

Mais tu peux supprimer ces lignes ou désactiver l'événement sur ouverture une fois que l'ocx est référencé.


Après l'ouverture du formulaire F_DependancesObjets, suivant le sens de lecture de la gauche vers la droite :

Un objet de niveau N est référencé dans l'objet relié de niveau N+1.

Exemple :

Table1 -> Formulaire1

Signifie que le Formulaire1 contient une référence à la Table1, sa propriété "Source" indique en fait qu'il est basé et relié à la Table1.

On peut faire l'inverse en remplaçant le mot "Dependants" par "Dependencies" dans le code VBA.

Pour ne pas que ça soit trop compliqué à lire je ne garde à l'ouverture du formulaire que 1 niveau (Racines + Niveau1). Ensuite, libre à toi d'explorer plus loin les dépendances en cliquant sur les noeuds avec un "+".

Tu as aussi la possibilité d'enregistrer les dépendances entre objets, il te le demande quand tu fermes le formulaire F_DependancesObjets, il te crée une table T_Dependances.

Comme ça les infos de dépendances se chargent automatiquement à partir de cette table, quand tu réouvres le formulaire (boîte de dialogue à l'ouverture "souhaitez-vous récupérer les dépendances enregistrées ?" -> oui).

Je regarderai ce week-end s'il reste des bogues dans le code.

Cdlt,

[OBIWAN64]

Bonjour User,
Je vais tester en important tous les objets dans une nouvelle base accdb.
Pour l'instant, avec ma base actuelle lorsque je lance le formulaire F_DependancesObjets j'obtiens le message suivant :


Cordialement.

[User]

Salut,

Est-ce que tu as un des 2 fichiers à référencer sur ta machine :

Office 32bits :

"..\SYSTEM32\MSCOMCTL.OCX"

Office 64bits :

"..\SysWOW64\MSCOMCTL2.OCX"

ça semble être un problème lié au référencement de l'ocx pour gérer le treeView.

Essaie au début de désactiver l'événement sur ouverture du formulaire F_DependancesObjets pour éviter le message d'erreur et voir si la référence s'enregistre :

[OBIWAN64]

Re,
Effectivement les OCX n'étaient pas référencés. Je viens de régler ça.
Le formulaire s'est lancé sans problème. La recherche des dépendances est en cours. J'ai pas mal d'objets donc comme tu l'avais dit ça risque de durer un peu.

Je te tiens au courant.

Cordialement.

[User]

Il faut être patient, pour une base avec environ 75500 dépendances il a mis 4h30 je crois..ensuite il faut pas oublier d'enregistrer les dépendances à la fermeture du formulaire..

[OBIWAN64]

Bonjour User,
Je suis un peu coincé. J'ai relancé le formulaire hier matin, et je l'ai laissé tourner toute la journée (environ 8 h). J'ai dû le stopper car la base est sur l'ordi du boulot et je ne pouvais pas le laisser tourner toute la nuit.

Selon toi est-il possible de fractionner la récupération des dépendances en plusieurs étapes ?

Autre question (mais c'est vrai que je suis loin d'être expert) n'y a-t-il pas dans une table système telle que la table MSysobjects les infos que l'on cherche sur les dépendances ?

Cordialement.

[User]

Salut,

Il y aurait peut-être une solution :

Actuellement le programme liste à la racine tous les objets qui ont une dépendance avec au moins un autre objet.

Donc, si on conserve uniquement les objets de niveau 0, et les objets de niveau 1 qui sont reliés à ceux de niveau 0, normalement tu devrait avoir toutes les dépendances, et l'outil tournerait plus vite ?

Concernant la table MSysobjects elle permet d'avoir la liste des objets et leur type mais pas les dépendances, mais attention car un état ou un formulaire peuvent porter le même nom qu'une table ou une requête.