Discussion :

[FB4200]

Bonjour à tous,

Dans le programme windev que je suis en train de construire, j'imagine utiliser une fenêtre windev pour envoyer un mail.
J'ai bien sur récupéré le port, le smtp, l'identifiant et le mot de passe du compte, j'ai programmé tout ça dans un bouton "envoyer" et ça ne fonctionne pas. Voici le message d'erreur que j'obtiens :

Quelqu'un pourrait-il me dire comment corriger cela ?

D'avance je vous remercie.

[Yusep]

Bonjour.
Votre code?

[FB4200]

Voici mon code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
// Ouvre session SMTP
Masession est un EmailSessionSMTP
Masession..AdresseServeur = SAI_Serveur_SMTP
Masession..Port = SAI_Port
Masession..Nom = SAI_Identifiant
Masession..MotDePasse = SAI_Mot_de_passe
EmailOuvreSession(Masession) 
 
// Construction du message
Monmessage est un Email
Monmessage..Expediteur = SAI_Expéditeur
Monmessage..Sujet = SAI_Objet
Monmessage..Message = HTMLVersTexte(SAI_Texte)
 
//Ajoute un destinataire
Ajoute(Monmessage..Destinataire, LISTE_Destinataire..ValeurAffichée) 
 
// Ajouter éventuellement une pièce jointe
SI SAI_Piecejointemail <> "" ALORS
       EmailChargeFichierAttaché(Monmessage,SAI_Piecejointemail)
FIN
 
// Envoi de l'email
SI EmailEnvoieMessage(Masession,Monmessage) = Faux ALORS
       Erreur("Message non envoyé", ErreurInfo ())
SINON
       ToastAffiche("Message envoyé", toastCourt,cvMilieu,chCentre,VertFoncé)
FIN
 
EmailFermeSession(Masession)

[popoy]

Pour répondre il faut avoir
Les informations saisies dans SMTP et port

[FB4200]

Popoy,

Dans SAI_Serveur_SMTP je mets l'adresse du serveur (en l'occurrence ici celui fournit par ma boite professionnelle) et dans SAI_Port le 465, conformément aux paramètre de ma boite.

[popoy]

Dans l'aide, il est écrit
"SMTP authentifié
L'authentification SMTP ne peut pas être effectuée avec la fonction EmailOuvreSession. Pour ouvrir à la fois une session POP3 et une session SMTP authentifiée il est nécessaire d'utiliser les deux fonctions EmailOuvreSessionPOP3 et EmailOuvreSessionSMTP."
Or tu utilises le port 465
N'y a-t-il pas de SSL ?

[frenchsting]

Bonjour,

+1 popoy,

Il faut vérifier le bon port et l'activation SSL/TLS. Sachant qu'il faut désactiver la gestion TLS par Windev si c'est du TLS1.2... A voir si c'est faisable en WD20.

[Voroltinquo]

Sachant qu'il faut désactiver la gestion TLS par Windev si c'est du TLS1.2... A voir si c'est faisable en WD20.

Cela se fait via la fonction EmailParamètre, pour info:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
EmailParamètre(emailParamètreMode, 1)

Malheureusement pour toi cette fonction n'est disponible que depuis la V22

[FB4200]

Ok merci pour vos retours. Mais dois-je comprendre que ce que je veux faire n'est pas possible avec windev 20 ?

[Voroltinquo]

Tout dépend de la version du protocole TLS utilisée par le serveur

[FB4200]

D'accord. En admettant que la version du protocole TLS soit la bonne, je n'ai pas compris ce que je devais rajouter dans mon code pour que ça marche.
Est-ce que quelqu'un peut me dire ce que je dois rajouter svp ? Merci.

[frenchsting]

Bonjour,

Pour répondre à ta question, essaye déjà ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

MaSession.Option = emailOptionSécuriséTLS

Si cela te met une erreur de compilation ou si cela ne fonctionne pas, il te faudra passer par une autre solution pour envoyer tes méls: piloter un logiciel de messagerie, écrire un module d'envoi de mél dans une autre version de WD, ou changer carrément de version WD...

[Yusep]

Bonjour.
Avec WD15 je n'ai pas de problemes.
Je regarderais ce soir et je te dis

[FB4200]

Bonjour,

Pour répondre à ta question, essaye déjà ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

MaSession.Option = emailOptionSécuriséTLS

Si cela te met une erreur de compilation ou si cela ne fonctionne pas, il te faudra passer par une autre solution pour envoyer tes méls: piloter un logiciel de messagerie, écrire un module d'envoi de mél dans une autre version de WD, ou changer carrément de version WD...

Merci, je vais essayer ce code et je verrai.

[FB4200]

Bonjour.
Avec WD15 je n'ai pas de problemes.
Je regarderais ce soir et je te dis

Je suis preneur de toute solution Yusep

[Yusep]

Ceci fonctionne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
PROCEDURE EnviarGmail(UsuarioSMTP, Mot_de_passe, ServidorSMTP, CuentaCliente, CuentaTecnico, Asunto, Cuerpo, Adjuntos="")
 
// Tester Internet
// Connexion Internet active ?
ResConnexion est un  booléen = InternetConnecté()
SI ResConnexion = Vrai ALORS
    //Info("Une connexion Internet est active")
    SI Ping("www.google.es")=Faux ALORS
        Erreur("No hay conexión con Internet")
        RETOUR
    FIN
SINON
    Erreur("No hay conexión con Internet")
    RETOUR
FIN
 
 
OuvreFille(Fenetre_Jauge_Simple)
Fenetre_Jauge_Simple..Titre="Enviando email a "+CuentaTecnico
 
 
// https://forum.pcsoft.fr/fr-FR/pcsoft.fr.windev/209149-probleme-pour-envoyer-mails-avec-gmail/read.awp
HTTP.IgnoreErreur = httpIgnoreCertificatExpiré
EmailChangeTimeOut(10) // 10 secondes pour le time out
 
 
EmailJauge(Fenetre_Jauge_Simple.JaugeEnCours)
//Adjuntos=".\HALU.FIC;.\HPRG.FIC;.\HALU.NDX;.\HPRG.NDX"
//Ouverture d'une session SMTP
gSessionSMTP est une EmailSessionSMTP
gSessionSMTP..AdresseServeur = ServidorSMTP //"smtp.gmail.com"
gSessionSMTP..Nom = UsuarioSMTP //"info.xxxxx"
gSessionSMTP..MotDePasse = Mot_de_passe //"mdpxxxxx"
gSessionSMTP..Port = 587
gSessionSMTP..Option = EmailOptionSécuriséTLS
 
 
EmailOuvreSession(gSessionSMTP)
SI ErreurDétectée ALORS
    //PGComunes.gbError=Vrai
    Erreur("Error al abrir la sesión",EmailMsgErreur(Email.Erreur))
SINON
    //PGComunes.gbError=faux
    //Remise à zéro des variables Email
    EmailRAZ()
 
    //Expéditeur du message
    Email.Expéditeur = CuentaCliente
    Email.AdresseExpéditeur = CuentaCliente //"info.xxxxx@gmail.com"
 
    //Destinataire(s) du message
    Email.Destinataire[1] = CuentaTecnico
    Email.NbDestinataire = 1
 
    //Pièces jointes
    SI Adjuntos<>"" ALORS
        AnciennePosition est un entier
        i est un entier
        // Pour chaque produit
        POUR TOUTE POSITION PositionActuelle DE ";" DANS Adjuntos
            i=i+1
            // Ajoute le produit dans la liste ListeProduit
            Email.Attache[i] = Adjuntos[[AnciennePosition + 1 A PositionActuelle - 1]]
            // Mémorisation de la position
            AnciennePosition = PositionActuelle 
        FIN
        Email.NbAttache = i
    SINON
        Email.NbAttache = 0
    FIN
 
    //Sujet et contenu du message
    Email.Sujet = Asunto
    Email.Message = Cuerpo
    Email.HTML = ""
 
 
    //EmailEnvoieMessage(gSessionSMTP, MonMessage, Vrai)
    EmailEnvoieMessage(gSessionSMTP)
    SI ErreurDétectée ALORS
        //PGComunes.gbError=Vrai
        Erreur("Error al enviar el correo",EmailMsgErreur(Email.Erreur))
    SINON
        //PGComunes.gbError=Faux
        MaTrace("Email enviado a "+CuentaTecnico)
    FIN
 
    //Fermeture de la session SMTP
    EmailFermeSession(UsuarioSMTP)
FIN
 
Ferme(Fenetre_Jauge_Simple)

Attention, dans certain cas il faut un mot de passe différent au mot de passe du compte Gmail (voir la configuration de sécurité)

[FB4200]

Alors merci à tous ! Je me suis inspiré du code de Yusep.
Résultat : pas de problème de compilation, la génération fonctionne.
En revanche, lorsque j'essaie d'envoyer l'email avec ma fenêtre, j'obtiens un nouveau code d'erreur que voici :

Les paramètres d'appel du code 'Clic sur BTN_Envoyer' sont incorrects : on attendait entre 6 et 7 paramètres et on en a reçu 0.
Code erreur : 1079
Niveau : erreur fatale (EL_FATAL)
Dump de l'erreur du module 'wd200vm64.dll' (20.0.243.3).
Identifiant des informations détaillées (.err) : 1079
Informations de débogage :
Erreur hors execution

Je ne comprends absolument pas ce qui ne va pas et ce que je dois changer...

[Yusep]

Le code SVP

[FB4200]

Le code SVP

Voici le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
PROCEDURE Envoyeremail (Identifiant, Mot_de_passe, ServeurSMTP, Destinataire, expediteur, sujet, corps = "")
 
// Connexion Internet active ?
ResConnexion est un  booléen = InternetConnecté()
SI ResConnexion = Vrai ALORS
	//Info("Une connexion Internet est active")
	SI Ping("www.google.fr")=Faux ALORS
		Erreur("Il n'y a pas de connexion internet")
		RETOUR
	FIN
SINON
	Erreur("Il n'y a pas de connexion  Internet")
	RETOUR
FIN
 
//Ouverture d'une session SMTP
gSessionSMTP est une EmailSessionSMTP
gSessionSMTP..AdresseServeur = "nomduserveur" 
gSessionSMTP..Nom = "identifiantutilisateur"
gSessionSMTP..MotDePasse = "motdepasse"
gSessionSMTP..Port = 465
gSessionSMTP..Option = emailOptionSécuriséTLS
 
EmailOuvreSession(gSessionSMTP)
SI ErreurDétectée ALORS
	//PGComunes.gbError=Vrai
	Erreur("Erreur à l'ouverture de la session",EmailMsgErreur(Email.Erreur))
SINON
	//PGComunes.gbError=faux
	//Remise à zéro des variables Email
	EmailRAZ()
 
	//Expéditeur du message
	Email.Expéditeur = SAI_Expéditeur 
	Email.AdresseExpéditeur = SAI_Expéditeur
 
	//Destinataire(s) du message
	Email.Destinataire[1] = SAI_Dest
	Email.NbDestinataire = 1
 
	//Sujet et contenu du message
	Email.Sujet = SAI_Objet 
	Email.Message = SAI_Texte
	Email.HTML = ""
 
	//EmailEnvoieMessage(gSessionSMTP, MonMessage, Vrai)
	EmailEnvoieMessage(gSessionSMTP)
	SI ErreurDétectée ALORS
		//PGComunes.gbError=Vrai
		Erreur("Erreur d'envoi du message",EmailMsgErreur(Email.Erreur))
	SINON
		//PGComunes.gbError=Faux
		ToastAffiche("Message envoyé ")
	FIN
 
	//Fermeture de la session SMTP
	EmailFermeSession(Identifiant) 
FIN

[Voroltinquo]

L'erreur se produit lors du clic bouton, c'est le code du bouton qui nous serait nécessaire