IdentifiantMot de passe
Loading...
Mot de passe oublié ?Je m'inscris ! (gratuit)
Navigation

Inscrivez-vous gratuitement
pour pouvoir participer, suivre les réponses en temps réel, voter pour les messages, poser vos propres questions et recevoir la newsletter

Scripts/Batch Discussion :

Créer un chat entre deux ordinateurs d'un même LAN


Sujet :

Scripts/Batch

  1. #1
    Membre à l'essai
    Homme Profil pro
    autre
    Inscrit en
    mars 2022
    Messages
    17
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : France, Morbihan (Bretagne)

    Informations professionnelles :
    Activité : autre
    Secteur : High Tech - Matériel informatique

    Informations forums :
    Inscription : mars 2022
    Messages : 17
    Points : 11
    Points
    11
    Par défaut Créer un chat entre deux ordinateurs d'un même LAN
    Bonjour.

    Comme dis ci dessus je voudrais créer un chat entre deux ordis d'un même LAN (par exemple dans une entreprise où un lycée)

    pour l'instant mon code ressemble à ça :

    Code Batch : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    @echo off
    title Chat
    if exist read.bat goto reg
    :Setup
    echo @echo off >> read.bat
    echo :read>> read.bat
    echo title Messages>> read.bat
    echo type log.cdat>> read.bat
    echo type mes.cdat>> read.bat
    echo timeout /t 1 >> read.bat
    echo cls>> read.bat
    echo goto read>> read.bat
    cls
    :reg
    cls
    set /p "name= Enter your name: " 
    echo %name% Joined the chat (%time%::%date%) >> log.cdat
    cls
    start read.bat
    :mes
    set /p "message=>>"
    if %message%==exit goto fin
    echo %name%:%message%>>mes.cdat
    cls
    goto mes
     
    :fin
    del read.bat
    del log.cdat
    del mes.cdat
    exit

    Vous l'avez peut-être remarqué mais les fichiers log.cdat et mes.cdat doivent être accessible par tous les utilisateurs.

    Ma question est donc existe-il un répertoire commun au différents utilisateur d'un même lan. où est installé un système de session accessible par n'importe quel ordi connecté au réseau.

    merci d'avance

  2. #2
    Expert confirmé

    Homme Profil pro
    Responsable déploiement (SCCM, AirWatch, Intune)
    Inscrit en
    juillet 2014
    Messages
    2 915
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 43
    Localisation : France, Seine Saint Denis (Île de France)

    Informations professionnelles :
    Activité : Responsable déploiement (SCCM, AirWatch, Intune)
    Secteur : Transports

    Informations forums :
    Inscription : juillet 2014
    Messages : 2 915
    Points : 5 272
    Points
    5 272
    Par défaut
    Non, il faut configurer un empalement accessible. L'idéale pour ce type de service est un serveur de fichier.
    Mais je pense qu'il existe des outils gratuits et portable de chat.

  3. #3
    Membre à l'essai
    Homme Profil pro
    autre
    Inscrit en
    mars 2022
    Messages
    17
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : France, Morbihan (Bretagne)

    Informations professionnelles :
    Activité : autre
    Secteur : High Tech - Matériel informatique

    Informations forums :
    Inscription : mars 2022
    Messages : 17
    Points : 11
    Points
    11
    Par défaut
    Pardon mais je ne comprends pas ce que tu veux dire.

    mais sinon j'ai trouvé un moyen avec un dossier partagé.

    Par contre léger problème je ne peut mettre d'espaces dans le message car le script crash.

    Une proposition pour résoudre mon problème. Je suis tout ouïe !!

    Merci encore

  4. #4
    Expert confirmé

    Homme Profil pro
    Responsable déploiement (SCCM, AirWatch, Intune)
    Inscrit en
    juillet 2014
    Messages
    2 915
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 43
    Localisation : France, Seine Saint Denis (Île de France)

    Informations professionnelles :
    Activité : Responsable déploiement (SCCM, AirWatch, Intune)
    Secteur : Transports

    Informations forums :
    Inscription : juillet 2014
    Messages : 2 915
    Points : 5 272
    Points
    5 272
    Par défaut
    j'ai trouvé un moyen avec un dossier partagé.
    Oui, tu as configuré un emplacement accessible


    Quelques idées d'améliorations avec la correction pour ton espace qui crash

    Code batch : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    @echo off
    cls
    title Chat
     
    if not exist read.bat (
    	echo @echo off
    	echo :read
    	echo title Messages
    	echo type log.cdat 2^>nul
    	echo type mes.cdat 2^>nul
    	echo timeout /t 1 /NOBREAK ^>nul
    	echo cls
    	echo goto read
    	)> read.bat
     
    set /p "name= Enter your name : " 
    echo %name% Joined the chat (%time%::%date%)>> log.cdat
    start read.bat
     
    :mes
    cls
    set /p "message=%name% : "
    if /i "%message%"=="/exit" goto fin
    if /i "%message%"=="/clear" call :clear &goto mes
    echo %name% : %message%>>mes.cdat
    goto mes
     
    :clear
    del log.cdat 2>nul
    del mes.cdat 2>nul
    goto :eof
     
    :fin
    del read.bat
    call :clear
    exit

  5. #5
    Membre à l'essai
    Homme Profil pro
    autre
    Inscrit en
    mars 2022
    Messages
    17
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : France, Morbihan (Bretagne)

    Informations professionnelles :
    Activité : autre
    Secteur : High Tech - Matériel informatique

    Informations forums :
    Inscription : mars 2022
    Messages : 17
    Points : 11
    Points
    11
    Par défaut
    Merci ericlm128 encore une fois tu m'as aidé.

    Ça as résolu le problème mais maintenant je suis en train de créer un system pour créer plusieurs chat a la fois mais ça ne fonctionne pas et je ne comprends pas pourquoi.

    Pouvez-vous m'aider SVP ?

    code actuel
    Code Batch : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    39
    40
    41
    42
    43
    44
    45
    46
    47
    48
    49
    50
    51
    52
    53
    54
    55
    56
    57
    58
    59
    60
    61
    62
    63
    64
    65
    66
    67
    68
    69
    70
    71
    72
    73
    74
    75
    76
    77
    78
    79
    80
    81
    82
    83
    84
    85
    86
    87
    88
    89
    90
    91
    92
    93
    94
    95
    96
    97
    98
    99
    100
    101
    102
    103
    104
    105
    106
    107
    108
    109
    110
    111
    112
    113
    114
    115
    @echo off
    color 02
    title Chat
     
    if exist read.bat goto menu
    if not exist messagerie.bat (
    	echo @echo off
    	echo set /p file=^<log.txt
    	echo del log.txt
    	echo :read
    	echo title Messages
    	echo type "%file%".cdat 2^>nul
    	echo timeout /t 1 /NOBREAK ^>nul
    	echo cls
    	echo goto read
    	)> messagerie.bat
     
    :menu
    mode con cols=100 lines=28
    echo ---------------------------------------------------------------------------------------------------
    echo.
    echo.
    echo 				Créer un chat 	   {1}
    echo.
    echo 				Rejoindre un chat  {2}
    echo.
    echo                            Supprimer un chat  {3}
    echo.
    echo.
    echo ---------------------------------------------------------------------------------------------------
    set /p choice=^>
     
    if %choice%==1 goto create
    if %choice%==2 goto rejet
    if %choice%==3 goto suppr
    goto menu
     
    :rejet
    mode con cols=46 lines=13
    cls
    set /p namec=Name of chat: 
    set chem=C:\Users\%username%\%namec%.sg 
     
    if not exist %chem% goto rien
     
    set /p pass=Password: 
    set /p var=<C:\Users\%username%\%namec%.sg
    if %pass% neq %var% goto r
    goto m
     
    :r
    cls
    echo accès refusé.
    pause>nul
    goto menu
     
    :m
    echo %namec%>log.txt
    cls
    set /p name=Pseudo: 
    echo %name% a rejoint le chat (%time%::%date%)>> %namec%.cdat
    attrib %namec%.cdat +s +h
    echo .>>%namec%.cdat
    cls
    start messagerie.bat
    goto mes
     
    :create
    mode con cols=46 lines=13
    cls
    set /p namec=Name of new chat: 
    set chem=C:\Users\%username%\%namec%.sg
    set /p pass=Password of new chat: 
    echo %pass%>%chem%
    attrib %chem% +s +h
    goto m
     
    :suppr
    mode con cols=46 lines=13
    cls
    set /p pass=Password: 
    if %pass% neq aqw goto :r
     
    if %pass% equ aqw del /s C:\Users\%username%*.sg
     
    if not exist C:\Users\%username%\%namec%.sg echo action réussi.
    pause>nul
    goto menu
     
    :mes
    set /p "message=>> "
     
    if /i "%message%"=="/e" goto fin    & rem /e pour exit
    if /i "%message%"=="/d" goto chemin & rem /d pour delete
    if /i "%message%"=="/q" goto j      & rem /q pour quitter
    if not exist %chem% goto fin
    echo %name%:%message%>>%namec%.cdat
    echo . >>%namec%.cdat
    cls
    goto mes
     
    :fin
    del %namec%.cdat
    :j
    echo %name% a quitter le chat (%time%::%date%)>> %namec%.cdat
    goto menu
     
    :chemin
    del C:\Users\%username%\%namec%.sg
    goto menu 
     
    :rien
    echo Ce chat n'éxiste pas.
    pause>nul
    goto menu

    SVP

  6. #6
    Expert confirmé

    Homme Profil pro
    Responsable déploiement (SCCM, AirWatch, Intune)
    Inscrit en
    juillet 2014
    Messages
    2 915
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 43
    Localisation : France, Seine Saint Denis (Île de France)

    Informations professionnelles :
    Activité : Responsable déploiement (SCCM, AirWatch, Intune)
    Secteur : Transports

    Informations forums :
    Inscription : juillet 2014
    Messages : 2 915
    Points : 5 272
    Points
    5 272
    Par défaut
    Je regarderai, ça bloque ou ?
    A première vue je passerai le nom du fichier (chat) en paramètre au script messagerie.bat pour le récupérer dans %~1

  7. #7
    Expert confirmé

    Homme Profil pro
    Responsable déploiement (SCCM, AirWatch, Intune)
    Inscrit en
    juillet 2014
    Messages
    2 915
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 43
    Localisation : France, Seine Saint Denis (Île de France)

    Informations professionnelles :
    Activité : Responsable déploiement (SCCM, AirWatch, Intune)
    Secteur : Transports

    Informations forums :
    Inscription : juillet 2014
    Messages : 2 915
    Points : 5 272
    Points
    5 272
    Par défaut
    J'ai un petit peu de mal a comprendre comment tu veux que ça fonctionne.

    Lorsque tu crée un chat tu stock un mdp dans le profil utilisateur qui ne semble pas partagé. Donc je ne comprend pas comment quelqu'un va rejoindre le chat avec le même MDP.

    Bon de toute façon il n'y aura aucune vrai sécurité

    PS : J'ai un peu de mal avec la programmation spaghetti

  8. #8
    Expert confirmé

    Homme Profil pro
    Responsable déploiement (SCCM, AirWatch, Intune)
    Inscrit en
    juillet 2014
    Messages
    2 915
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 43
    Localisation : France, Seine Saint Denis (Île de France)

    Informations professionnelles :
    Activité : Responsable déploiement (SCCM, AirWatch, Intune)
    Secteur : Transports

    Informations forums :
    Inscription : juillet 2014
    Messages : 2 915
    Points : 5 272
    Points
    5 272
    Par défaut
    Re, du coup je te montre ma vision des choses et tu prends ce qui t’intéresse

    Code batch : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    39
    40
    41
    42
    43
    44
    45
    46
    47
    48
    49
    50
    51
    52
    53
    54
    55
    56
    57
    58
    59
    60
    61
    62
    63
    64
    65
    66
    67
    68
    69
    70
    71
    72
    73
    74
    75
    76
    77
    78
    79
    80
    81
    82
    83
    84
    85
    86
    87
    88
    89
    90
    91
    92
    93
    94
    95
    96
    97
    98
    99
    100
    101
    102
    103
    104
    105
    106
    @echo off
    color 02
     
    SETLOCAL ENABLEDELAYEDEXPANSION
     
    if not exist messagerie.bat (
    	echo @echo off
    	echo cls
    	echo :read
    	echo title Messages du chat "%%~1"
    	echo type "%%~1.cdat" 2^>nul
    	echo timeout /t 1 /NOBREAK ^>nul
    	echo cls
    	echo goto read
    	)> messagerie.bat
     
     
    :menu
    title Chat
    cls
    set namec=
    set /p "namec=Name of chat : "
     
    if not defined namec goto menu
     
    if not exist "%namec%.cdat" (
     
    	REM Create chat
    	echo.
    	echo Le chat "%namec%" n existe pas, il va etre cree
    	echo Souhaitez vous definir un mot de passe ^(vide = sans mot de passe^) ?
     
    	set choice=
    	set /p "choice=Mot de passe : "
     
    	REM Create password
    	if defined choice (
    		echo !choice!> "%namec%.pwd"
    		attrib "%namec%.pwd" +s +h
    	)
    	echo [%date% %time:~,8%] SYSTEM : Chat "%namec%" cree> "%namec%.cdat"
    	attrib "%namec%.cdat" +s +h
    ) else (
     
    	REM Authentification
    	if exist "%namec%.pwd" (
    		echo.
     
    		set choice=
    		set /p "choice=Entrer le mot de passe pour le chat %namec% : "
     
    		findstr /B /E /L /C:"!choice!" "%namec%.pwd" 1>nul 2>nul||(echo Acces refuse&pause>nul&goto menu)
    	)
    )
     
    REM PSEUDO
    echo.
    set name=
    set /p "name=Pseudo : "
     
    if not defined name goto menu
    if /i "%name%" == "SYSTEM" goto menu
     
    echo [%date% %time:~,8%] SYSTEM : "%name%" a rejoint le chat>> "%namec%.cdat"
     
     
    REM Chat mode
    mode con cols=55 lines=13
    start messagerie.bat "%namec%"
    title Chat : "%name%" sur "%namec%"
    echo Taper /? pour obtenir de l aide sur les commandes
    :chat
     
    set message=
    set /p "message=>> "
     
    if not defined message goto chat
     
    if /i "%message%" == "/?" (
    	echo /r		Reset le chat
    	echo /s		Supprime le chat
    	echo /q		Quitte. Retour au menu principal
    	echo.
    	goto chat
    )
    if /i "%message%" == "/r" (
    	attrib "%namec%.cdat" -s -h
    	echo [%date% %time:~,8%] SYSTEM : Reinitialisation du chat "%namec%" par "%name%"> "%namec%.cdat"
    	attrib "%namec%.cdat" +s +h
    	cls
    	goto chat
    )
    if /i "%message%" == "/s" (
    	taskkill /F /FI "IMAGENAME eq cmd.exe" /FI "WINDOWTITLE eq Messages du chat \"%namec%\"" 2>nul
    	del /A /Q /F "%namec%.cdat" 1>nul 2 >nul
    	del /A /Q /F "%namec%.pwd" 1>nul 2 >nul
    	cls
    	goto menu
    )
    if /i "%message%" == "/q" (
    	taskkill /F /FI "IMAGENAME eq cmd.exe" /FI "WINDOWTITLE eq Messages du chat \"%namec%\"" 2>nul
    	goto menu
    )
    echo [%date% %time:~,8%] %name% : %message%>> "%namec%.cdat"
    cls
    goto chat

  9. #9
    Membre à l'essai
    Homme Profil pro
    autre
    Inscrit en
    mars 2022
    Messages
    17
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : France, Morbihan (Bretagne)

    Informations professionnelles :
    Activité : autre
    Secteur : High Tech - Matériel informatique

    Informations forums :
    Inscription : mars 2022
    Messages : 17
    Points : 11
    Points
    11
    Par défaut
    Citation Envoyé par ericlm128 Voir le message
    J'ai un petit peu de mal a comprendre comment tu veux que ça fonctionne.

    Lorsque tu crée un chat tu stock un mdp dans le profil utilisateur qui ne semble pas partagé. Donc je ne comprend pas comment quelqu'un va rejoindre le chat avec le même MDP.
    C'était pour le tester seul sur mon ordi.

    Mais sinon merci

    Je voudrais aussi pour que le batch créer un dossier partagé de lui même au lieux d'en utiliser un existant

  10. #10
    Expert confirmé

    Homme Profil pro
    Responsable déploiement (SCCM, AirWatch, Intune)
    Inscrit en
    juillet 2014
    Messages
    2 915
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 43
    Localisation : France, Seine Saint Denis (Île de France)

    Informations professionnelles :
    Activité : Responsable déploiement (SCCM, AirWatch, Intune)
    Secteur : Transports

    Informations forums :
    Inscription : juillet 2014
    Messages : 2 915
    Points : 5 272
    Points
    5 272
    Par défaut
    Tu peux regarder ici mais je pense que ce n'est pas le rôle du script de chat
    https://stackoverflow.com/questions/...o-share-folder

  11. #11
    Membre à l'essai
    Homme Profil pro
    autre
    Inscrit en
    mars 2022
    Messages
    17
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : France, Morbihan (Bretagne)

    Informations professionnelles :
    Activité : autre
    Secteur : High Tech - Matériel informatique

    Informations forums :
    Inscription : mars 2022
    Messages : 17
    Points : 11
    Points
    11
    Par défaut
    Merci pour tout !

    ça fonctionne parfaitement

    Mais maintenant si je veux aller plus loin et et pouvoir le faire avec internet

    est-ce possible ? (toujours en batch)

    à bientot

  12. #12
    Expert confirmé

    Homme Profil pro
    Responsable déploiement (SCCM, AirWatch, Intune)
    Inscrit en
    juillet 2014
    Messages
    2 915
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 43
    Localisation : France, Seine Saint Denis (Île de France)

    Informations professionnelles :
    Activité : Responsable déploiement (SCCM, AirWatch, Intune)
    Secteur : Transports

    Informations forums :
    Inscription : juillet 2014
    Messages : 2 915
    Points : 5 272
    Points
    5 272
    Par défaut
    Eh bien il faudrait trouver un moyen de faire transiter/stocker des informations via internet en batch, sur un serveur (FTP, http...)

  13. #13
    Membre à l'essai
    Homme Profil pro
    autre
    Inscrit en
    mars 2022
    Messages
    17
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : France, Morbihan (Bretagne)

    Informations professionnelles :
    Activité : autre
    Secteur : High Tech - Matériel informatique

    Informations forums :
    Inscription : mars 2022
    Messages : 17
    Points : 11
    Points
    11
    Par défaut
    Peus-tu t'expliquer

    SVP

  14. #14
    Expert confirmé

    Homme Profil pro
    Responsable déploiement (SCCM, AirWatch, Intune)
    Inscrit en
    juillet 2014
    Messages
    2 915
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 43
    Localisation : France, Seine Saint Denis (Île de France)

    Informations professionnelles :
    Activité : Responsable déploiement (SCCM, AirWatch, Intune)
    Secteur : Transports

    Informations forums :
    Inscription : juillet 2014
    Messages : 2 915
    Points : 5 272
    Points
    5 272
    Par défaut
    C'est a dire qu'il faut chercher 🤔

+ Répondre à la discussion
Cette discussion est résolue.

Discussions similaires

  1. créer un réseau entre deux ordinateurs
    Par zan123 dans le forum Réseau
    Réponses: 3
    Dernier message: 01/08/2013, 23h48
  2. Réponses: 2
    Dernier message: 06/10/2007, 16h12
  3. Réponses: 4
    Dernier message: 11/01/2007, 17h26
  4. Formulaire: Créer une dépendance entre deux champs.
    Par mystikfury dans le forum Access
    Réponses: 3
    Dernier message: 17/05/2006, 17h49
  5. connexion entre deux ordinateurs par modem analogique
    Par devl83 dans le forum Hardware
    Réponses: 3
    Dernier message: 31/01/2006, 16h48

Partager

Partager
  • Envoyer la discussion sur Viadeo
  • Envoyer la discussion sur Twitter
  • Envoyer la discussion sur Google
  • Envoyer la discussion sur Facebook
  • Envoyer la discussion sur Digg
  • Envoyer la discussion sur Delicious
  • Envoyer la discussion sur MySpace
  • Envoyer la discussion sur Yahoo