Discussion :

[Malick]

Bonjour,

Serait-il possible de simplifier cette fonction pour faire la somme des données présentes dans les colonnes (Jour 1, Jour 2, .... Jour 31) ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Table.AddColumn(#"Colonnes renommées1", "Cumul_Temps", each List.Sum({[Jour 1],[Jour 2],[Jour 3],[Jour 4],[Jour 5],[Jour 6],[Jour 7],[Jour 8],[Jour 9],[Jour 10],[Jour 11],[Jour 12],[Jour 13],[Jour 14],[Jour 15],[Jour 16],[Jour 17],[Jour 18],[Jour 19],[Jour 20],[Jour 21],[Jour 22],[Jour 23],[Jour 24],[Jour 25],[Jour 26],[Jour 27],[Jour 28],[Jour 29],[Jour 30],[Jour 31]}))

Merci d'avance

[Raccourcix]

Bonjour

il y a peut être plus simple mais ça doit fonctionner :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

each List.Sum(Record.ToList(Record.SelectFields(_,List.Transform({1..31},each "Jour "&Text.From(_)))))

List.Transform pour définir les 31 champs
Record.SelectFields pour récupérer ces 31 champs de l'enregistrement en cours
Record.ToList pour convertir l'enregistrement en liste
et le List.Sum pour additionner le tout

Après le mieux est peut être de décroiser la table.

Stéphane

[Malick]

Bonjour,

Merci Stéphane ==> Je regarde cela et vous reviens.

[78chris]

Bonjour

En complément de l'excellente solution de Raccourcix

on peut aussi se baser sur la position des colonnes

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Table.AddColumn(#"Colonnes renommées1", "Cumul_Temps", each List.Sum(List.Range(Record.ToList(_),1,Table.ColumnCount(#"Colonnes renommées1")-1)))

1 représente ici la colonne à partir de laquelle on somme : la première étant 0, 1 est donc la 2ème, et le -1 doit compenser

Par exemple de 5ème à la fin aura 4 et -4
ou plus - x à calculer si on ne va pas jusqu'à la dernière colonne

[Raccourcix]

Bonjour

Autres possibilités si vous ne voulez pas conserver les colonnes source et avoir uniquement le total.
par défaut en utilisant la "fusion des colonnes" c'est une fonction Combiner.CombineTextByDelimiter qui est générée mais on peut la remplacer par un List.Sum

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

= Table.CombineColumns(#"Colonnes renommées1",List.Transform({1..31}, each "Jour "&Text.From(_)),List.Sum,"Cumul_Temps")

A tester mais ça peut être plus efficace qu'un traitement par Record.

Stéphane

[Malick]

Bonjour à vous,

Je confirme que vos différentes propositions fonctionnent toutes

Cela démontre encore la puissance de Power Query pour automatiser des tâches sans passer par du VBA.

encore