Discussion :

[VLP_SAS]

Hello,

Je voudrais créer une variable macro (dt_deb_m_1) qui prenne la valeur « 01/09/2020 » par calcul à partir d’une autre variable macro (dt_deb) qui vaut « 01/10/2020 » par exemple
L’idée est de pouvoir enlever/ajouter « x » mois à la variable macro initiale.
J’ai tenté le code suivant mais je n’ai pas le résultat attendu …
Qui a une idée ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
%let aaaamm = 202010; /* le paramètre en entrée */
 
%let annee = %substr(&aaaamm,1,4); 		                              /* 10 */
%let mois = %substr(&aaaamm,5,2);		                                     /* 2020 */
%let dt_deb = %sysfunc(putn(%sysfunc(mdy(&mois.,1,&annee.)),ddmmyy10.)); 	   /*01/10/2020*/
%put &dt_deb; 
 
%let dt_deb_m_1 = %sysfunc(putn(%sysfunc(intnx(month,&dt_deb,-1,s)),ddmmyy10.)); 
%put &dt_deb_m_1; /* 01/12/1959 ???? un jour de moins avant l’init des dates SAS */

[hossward]

Bonjour,
Il est souhaitable que le paramètre en entrée soit au format "01Oct2020"d.
Proposition à vérifier :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
%let dt_deb = "01Oct2020"d ; 
%let dt_deb_m_1  = %sysfunc(intnx(MONTH, &dt_deb., -1), ddmmyy10.) ;
%put &dt_deb_m_1 ;

Bon Courage
Ward

[olivier.decourt]

@ VLP_SAS, ton code ne fonctionne pas parce que dt_deb, qui vaut bien 01/10/2020, est ensuite interprété dans le INTNX comme une division : 1 divisé par 10 divisé par 2020, c'est à dire pas loin de 0. Donc du 01/01/1960 si on l'interprète ensuite comme une date SAS.
Comme le dit Hoss, avec une date initiale que SAS comprend, ça fonctionne très bien.
Autre proposition : faire l'économie de tous ces %SYSFUNC en passant par une étape Data.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
%LET dt_deb = 202010 ;
DATA _NULL_ ;
  dt_deb = INPUT("&dt_deb.01", YYMMDD8.) ;
  PUTLOG dt_deb DDMMYY10. ; /* pour vérifier */
  dt_deb_m_1 = INTNX("MONTH", dt_deb, -1, "S") ;
  PUTLOG dt_deb_m_1 DDMMYY10. ; /* vérif toujours */
  CALL SYMPUTX("dt_deb_m_1", dt_deb_m_1) ;
RUN ;

[VLP_SAS]

Tes réponses sont toujours très instructives