Discussion :

[yellowdog]

Bonjour,

J'ai le script ci-dessous qui se lance à l'ouverture de session par GPO sur un serveur RDS 2012.

Le problème est qu'il ne lance pas tous les lecteurs qu'il devrait alors qu'il n'y a pas d'erreur dans mon script.

De plus d'une ouverture de session à l'autre il monte certains lecteurs et pas d'autres.

Le disque T: ne monte jamais alors que les personnes y ont droit.

J'ai commenté le démontage des disque avant mappage car j'avais vu sur un forum que ça pouvait être l'origine du problème. Mais ça n'a rien résolu.

Avez-vous une piste sur ce comportement que je ne comprends pas ?

Anciennement ce script était en KIXTART, je l'ai traduit en VBS mais ça ne fonctionne pas !

Merci pour vos remarques.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
' ********************************************************************
' Script to MAP users disks for ALL CHACAL iX ENVIRONMENTS and merge 
' putty registry and rsa_key at logon
' ********************************************************************
Option Explicit
Dim domainName,userName,ADSPath,grouplistD,GrpName,groupName
Dim objUser,objGroup,WshNetwork,wshShell,strComputerName  
 
' *****************************************************
' GET %USERNAME% to initialize username variable
' *****************************************************
Set WshNetwork = WScript.CreateObject("WScript.Network") 
Set wshShell = CreateObject("WScript.Shell")
 
'WScript.Echo "Computer Name: " & strComputerName
 
GrpName= Array("GRPINFO","GRPCOMDPC","GRPGSBEXPORT","GRPGXF","GRPSUPCHAIN","GRPACHATS","GRPGESTION")
domainName = "mydomain.com"
userName = WshNetwork.UserName
strComputerName = WshNetwork.ComputerName
 
Select Case strComputerName
	Case "V2K12RDS14"  	'DEV
		WSHShell.Run "cmd /c \\DC01\NETLOGON\PuttyDEV.cmd"
	Case "V2K12RDS11"	'PRD
		WSHShell.Run "cmd /c \\DC01\NETLOGON\PuttyDIAPPROD.cmd"
	Case "V2K12RDS12"	'PRD
		WSHShell.Run "cmd /c \\DC01\NETLOGON\PuttyDIAPPROD.cmd"
	Case "V2K12RDS13"	'PRD
		WSHShell.Run "cmd /c \\DC01\NETLOGON\PuttyDIAPPROD.cmd"
	Case "V2K12RDS8"	'REC	
		WSHShell.Run "cmd /c \\DC01\NETLOGON\PuttyDIAP5.cmd"
	Case "V2K12RDS15"	'REC-TMP
		WSHShell.Run "cmd /c \\DC01\NETLOGON\PuttyDIAP7.cmd"
	Case Else
End Select
 
' WSHShell.Run " net Use Q: /Delete"
Wshshell.run "net use Q: \\V2K12NAS\Chacal_Data$"
 
' WSHShell.Run "net Use V: /Delete"
Wshshell.run "net use V: \\VLNXDIAP1\CHACAL_PDF"
 
For each groupName in GrpName
             If IsMember(domainName,userName,groupName) Then
				' WSHShell.Run "net Use U: /Delete"
				wshshell.run "net use U: \\NASGFX\USERS"
			Else
			End If
Next
 
If IsMember(domainName,userName,"GRPPARIS") Then
				' WSHShell.Run "net Use U: /Delete"
				wshshell.run "net use U: \\G2K16PAR01\USERS"
Else
End If				
 
If IsMember(domainName,userName,"GRPPRODDPC") Then
				' WSHShell.Run "net Use U: /Delete"
				wshshell.run "net use U: \\V2K12MTL01\USERS"
Else
End If
 
If IsMember(domainName,userName,"GRP_ESPACE_COMMERCIAL_CHANTIER") Then
				' WSHShell.Run "net Use T: /Delete"
				wshshell.run "net use T: \\NASGFX\AgencesDPCSav"
Else
End If
 
 
WScript.quit
 
' ***********************************************************************
'This function checks if the given AD user is member of the given group.
' ***********************************************************************
 
Function IsMember(domainName,userName,groupName)
   Set groupListD = CreateObject("Scripting.Dictionary")
   groupListD.CompareMode = 1
   ADSPath = domainName & "/" & userName
   Set objUser = GetObject("WinNT://" & ADSPath & ",user")
   For Each objGroup in objUser.Groups
      groupListD.Add objGroup.Name, "-"
   Next
   IsMember = CBool(groupListD.Exists(groupName))
 End Function

[yellowdog]

Après avoir analysé, il s'avère que c'est la fonction IsMember qui pose problème.

Quel script IsMemvber utilisez vous pour contrôler l'appartenance d'un utilisateur du domaine à un groupe spécifique ?

Merci pour votre retour.

[omen999]

bonjour,

si ton script ne désactive pas ailleurs la gestion des erreurs (On Error Resume Next)
le plus vraisemblable est que la valeur de la variable groupName qui est codée en dur
dans ce script ne soit pas exactement égale à objGroup.Name

de toute façon je laisserais tomber la fonction IsMember pour la remplacer par ceci :
(exemple pour les lignes 64/68)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
If  GetObject("WinNT://" & domainName & "/GRP_ESPACE_COMMERCIAL_CHANTIER,Group").IsMember("WinNT://" & domainName & "/" & userName) Then		
     wshshell.run "net use T: \\NASGFX\AgencesDPCSav"
End If

[yellowdog]

Merci pour ton retour,

J'ai essayé ton script mais il me sort une erreur sur un nom de GROUPE alors que ce groupe est bien dans l'Active Directory et qu'il n'y a pas d'erreur de syntaxe.



Sais tu d'ou vient le problème ?

[yellowdog]

En fait, le "Nom de groupe (Anterieur a Windows 2000)" du groupe Active Directory était différent du nom de groupe afficher dans l'AD.

Je l'ai renommé et ça fonctionne merci encore pour ton aide.