Discussion :

[blepy]

Bonjour,
J'essaie de mettre dans un tableau les noms d'un classeur Excel.
Ces 2 instructions fonctionnent bien :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
            Z_Nom(I) = ActiveWorkbook.Names(I).Name
            Z_Nom_Refers(I) = ActiveWorkbook.Names(I).RefersTo

A cela je voudrais récupérer la "valeur" et l'"Etendue" pour chacun des noms, nous voyons ces 2 informations quand nous faisons dans Excel le menu "Formules/Gestionnaire de noms".

Merci de m'aiguiller
Bertrand

[Philippe Tulliez]

Bonjour,
Voici un échantillon d'une fonction qui renvoie une table (la propriété visible n'est pas traitée dans cet exemple) des noms présents dans le classeur actif

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Function NameManagerList() As Variant
  ' Philippe Tulliez (https://magicoffice.be)
  Dim n As Name, r As Long, Pos As Byte
  Dim tbl()
  Dim rng As Range
  ReDim tbl(1 To ActiveWorkbook.Names.Count + 1, 1 To 5)
  For Each n In ActiveWorkbook.Names
      r = r + 1: Pos = InStr(n.Name, "!")
      On Error Resume Next
      Set rng = n.RefersToRange
      On Error GoTo 0
      tbl(r, 1) = Mid(n.Name, Pos + 1)
      tbl(r, 2) = n.Value
      tbl(r, 3) = IIf(rng Is Nothing, "'" & n.RefersToLocal, n.RefersToLocal)
      tbl(r, 5) = n.Comment
      If Pos = 0 Then
         tbl(r, 4) = "Classeur"
        Else
         tbl(r, 4) = Replace(Left(n.Name, Pos - 1), "'", "")
      End If
  Next
  NameManagerList = tbl
End Function

Exemple d'une procédure qui l'invoque

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub TestNameManagerList()
  Dim tbl As Variant
  Dim Elem As Integer
  tbl = NameManagerList
  If IsArray(tbl) Then
     For Elem = LBound(tbl) To UBound(tbl)
       Debug.Print tbl(Elem, 1) ' Nom
       Debug.Print tbl(Elem, 2) ' Valeur
       Debug.Print tbl(Elem, 3) ' Référence (précédée d'une apostrophe si c'est une formule)
       Debug.Print tbl(Elem, 4) ' Etandue
       Debug.Print tbl(Elem, 5) ' Commenataire
       Debug.Print String(15, "*")
     Next
  End If
End Sub

[blepy]

Merci beaucoup à Philippe