Discussion :

[jujudeo]

Bonjour a tous,

j'aimerai supprimer un fichier .mdb dans un dossier spécifique "PGOC" dans tout mon serveur.

Je sais supprimer un fichier dans tout le serveur mais je n'arrive pas a lui dit dire qu'il doit supprimer le fichier dans un type de dossier précisément.

Voici mon départ de code :

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

 for /r %%i IN (*.mdb) do echo 0 | del "%%i"

En vous remerciant par avance.

Julien

[barnabe0057]

Bonjour,

Ceci devrait faire l'affaire :

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
@echo off
setlocal enableextensions enabledelayedexpansion
 
for /r %%A IN (*.mdb) do (
	set "chemin=%%~pA"
	set "chemin=!chemin:~0,-1!"
	set "chemin=!chemin:\=.!"
	for /f "delims=" %%E in ("!chemin!") do set "cible=%%~xE"
	if "!cible:~1!"=="PGOC" (del /p "%%~A")
)
 
echo. & pause

[ericlm128]

J'aurai fait comme ceci

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
cls
@echo off
 
for /f "tokens=*" %%a in ('dir "C:\Mon Dossier\Sous dossier\*.mdb" /A/B/S^|findstr /I /R "^.*\\PGOC\\[^\\]*\.mdb$"') do echo del /P/A/F "%%~a"
 
pause

[jujudeo]

Bonjour,

Ceci devrait faire l'affaire :

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
@echo off
setlocal enableextensions enabledelayedexpansion
 
for /r %%A IN (*.mdb) do (
	set "chemin=%%~pA"
	set "chemin=!chemin:~0,-1!"
	set "chemin=!chemin:\=.!"
	for /f "delims=" %%E in ("!chemin!") do set "cible=%%~xE"
	if "!cible:~1!"=="PGOC" (del /p "%%~A")
)
 
echo. & pause

Bonjour,

votre code est parfait, est il possible d'enlever l'option " oui ou non " a chaque suppression ? et que PGOC peut être écrit en majuscule ou minuscule ?

[barnabe0057]

Pour répondre aux 2 questions il suffit de remplacer cette ligne :

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

if "!cible:~1!"=="PGOC" (del /p "%%~A")

Par cette ligne :

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

if /i "!cible:~1!"=="PGOC" (del /q "%%~A")

[jujudeo]

C'est parfait merci beaucoup, sujet résolu !