Discussion :

[scn68100]

Bonjour,
Je crée une archive ZIP par zipAjouteRépertoire

Je la visualise ensuite par zipInfoFichier (Je met les résultats dans une table)


Je peux aussi la visualiser par zipListeFichier


Mais j'aimerai la visualiser à la manière de WinRAR, ou de l'Explorateur de Fichier


Est-ce possible ? Si oui comment faire ?
Cordialement
SC

[Voroltinquo]

Bonjour,
A vue de nez, il faut passer par une table hiérarchique en remplaçant les "/" par des TAB pour le ArbreAjoute (colonne principale)
Les autres colonnes tu devrais avoir les infos via zipInfoFichier

[scn68100]

Bonjour,
Je me demande si l'utilisation du champs Arbre ne pourrai pas convenir
Cdlt
SC

[frenchsting]

Bonjour,

Voroltinquo t'a donné la bonne solution. C'est que je ferais également.

Pas bête d'avoir pensé au champ arbre, tu peux l'utiliser mais tu ne pourras avoir que l'équivalent de ta première colonne. Si tu veux les autres infos (taille, date, etc), tu devras les concaténer à cette "première colonne".

[philouZ]

Pas bête d'avoir pensé au champ arbre, tu peux l'utiliser mais tu ne pourras avoir que l'équivalent de ta première colonne. Si tu veux les autres infos (taille, date, etc), tu devras les concaténer à cette "première colonne".

Dans ce cs pour quoi ne pas utiliser une table hiérarchique, tu conserves les colonnes et l'avantage de l'arbre...

[scn68100]

Ha, je ne connais pas la table hiérarchique, je vais regarder cela Merci

[Voroltinquo]

Une ébauche de code pour débuter :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
 
PROCÉDURE AfficherArbo(saCheminArchive est chaîne)
saListeFichier est une chaîne	//Liste des fichiers de l'archive
saCheminFichier est une chaîne	//Chemin d'un ficher de l'archive
saBranche est chaîne			//Nom de la branche en cours
saNoeud est une chaîne			//Nom du nœud de la branche en cours
nNoNoeud est entier				//Ligne du nœud saNoeud
saFeuille est une chaîne		//Nom de la feuille
nLigneFeuille est entier		//Ligne de la feuille
saInfo est chaîne				//Info sur le fichier
 
 
SI zipOuvre(zipMonArchive,saCheminArchive)=0 ALORS
	saListeFichier=zipListeFichier(zipMonArchive)
	POUR TOUTE CHAÎNE saCheminFichier DE saListeFichier SÉPARÉE PAR RC
		saNoeud=""
		saFeuille=ExtraitChaîne(saCheminFichier,1,"\",DepuisFin)
		saInfo=zipInfoFichier(zipMonArchive,saCheminFichier)
		POUR TOUTE CHAÎNE saBranche DE saCheminFichier SÉPARÉE PAR "\"
			nNoNoeud=TableCherche(COL_Nom,saNoeud,rechercheDéfaut)	//On cherche le nœud et on récupère son no de ligne
			SI TableCherche(COL_Nom,saBranche,rechercheDéfaut)=-1 ALORS	//La branche n'existe pas encore, on peut l'ajouter
				SI saBranche<>saFeuille ALORS
					TableAjouteFils(TABLEH_Zip,nNoNoeud,saBranche,"","","Répertoire")
				SINON
					//On ajoute les infos du fichier
					nLigneFeuille=TableAjouteFils(TABLEH_Zip,nNoNoeud,saBranche,ExtraitChaîne(saInfo,2,TAB),ExtraitChaîne(saInfo,3,TAB),"fichier")						
					//On cache l'image de répertoire pour la feuille
					TABLEH_Zip[nLigneFeuille]..ImageDéroulée=Null
					TABLEH_Zip[nLigneFeuille]..ImageEnroulée=Null
				FIN
 
			FIN
			saNoeud=saBranche	//La branche devient nœud
		FIN
	FIN
FIN

[scn68100]

Bonjour,
Merci, je vais essayer d'exploiter ...
Cordialement
SC

[scn68100]

Un grand merci, c'est exactement ce que je voulais ...
Il reste à peaufiner, mais l'essentiel est fait


Mais du coup je constate vraiment que j'ai encore bien des lacunes en Windev !!! Je n'aurait jamais trouvé cela moi-même !!!

Cordialement
SC

[Voroltinquo]

Il reste à peaufiner

2 petites astuces au passage :
Le type associé à une extension est contenu dans la BDR. C'est du brut dans la plupart des cas, du style exefile, icofile. Mas parfois, c'est un peu plus détaillé.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
saTypeFichier=RegistreLit(ChaîneConstruit("HKEY_CLASSES_ROOT\%1",saExtension),"")

On peut parfois avoir le type général (e.g. Image, Audio) en lisant la valeur (si elle existe) de PerceivedType

Pour avoir un récapitulatif des tailles d'un répertoire, la procédure suivante devrait faire l'affaire.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
 
PROCÉDURE ModifierTailleParent(nNoEnfant est entier,nNoFeuille est entier)
nNoParent est un entier
 
nNoParent=TableRécupèreParent(TABLEH_Zip,nNoEnfant)
SI nNoParent=0 ALORS	//On est à la racine
	RETOUR
SINON	//On ajoute la taille de la feuille et on répercute cela au niveau du parent de niveau n+1
	COL_Compressé[nNoParent]+=COL_Compressé[nNoFeuille]
	COL_Taille[nNoParent]+=COL_Taille[nNoFeuille]
	ModifierTailleParent(nNoParent,nNoFeuille)
FIN

Lors de l'affichage d'une ligne il suffit d'appeler

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
ModifierTailleParent(IndiceEnCours,IndiceEnCours)

Mais du coup je constate vraiment que j'ai encore bien des lacunes en Windev !!!

Si ça peut te réconforter, après une quinzaine années de pratique j'en apprend encore.

[scn68100]

Bonjour,
Encore une fois merci
Cordialement
SC

[tbc92]

Mais du coup je constate vraiment que j'ai encore bien des lacunes en Windev !!! Je n'aurait jamais trouvé cela moi-même !!!

Une bonne technique, c'est de lire en diagonale l'aide.
Par exemple cette page donne la liste des types de champs qu'on peut mettre une fenêtre. Tu regardes juste les noms des champs. Si 'Table Hierarchique', ça ne te parle pas, alors tu cliques sur le lien... pour voir à quoi ça peut ressembler.

Inutile d'apprendre comment ça marche, tu mémorises juste qu'il y a un outil quelque part qui ressemble à ça.

Tu peux aussi aller dans Windev, tu crées une fenêtre vierge, et tu insères des champs au hasard, juste pour voir à quoi ils ressemblent. Si tu as une mémoire plutôt visuelle, c'est peut être mieux.

20 minutes de temps en temps, ça suffit.

[scn68100]

COL_Compressé[nNoParent]+=COL_Compressé[nNoFeuille]
COL_Taille[nNoParent]+=COL_Taille[nNoFeuille]

Bonjour,
Je n'ai fort probablement rien compris, mais COL_Compressé et COL_Taille sont deux colonnes de la table hiérarchique
Comment les renseigne-t-on ?
Cordialement
SC

[Voroltinquo]

Elle sont ajoutée lors de l'ajout de la feuille via

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
nLigneFeuille=TableAjouteFils(TABLEH_Zip,nNoNoeud,saBranche,ExtraitChaîne(saInfo,2,TAB),ExtraitChaîne(saInfo,3,TAB),"fichier")

(ligne 26 dans le code)
saInfo est le résultat de zipInfoFichier de la forme

<Chemin et nom du fichier> + TAB + <Taille originale du fichier> + TAB +
<Taille compressée du fichier> + TAB +
<Date et heure de création du fichier (AAAAMMJJHHmmSS)> + TAB +
<Date et heure de modification du fichier (AAAAMMJJHHmmSS)> + TAB +
<Date et heure d'accès du fichier (AAAAMMJJHHmmSS)> + TAB +
<Attributs du fichier> + TAB + <Mode de cryptage du fichier>

[scn68100]

Bonjour,
Merci, je suis content, car j'avais trouvé la réponse ...
Il y un bug dans l'affichage
Je vais essayer de résoudre avant de demander de l'aide
Cordialement
SC