IdentifiantMot de passe
Loading...
Mot de passe oublié ?Je m'inscris ! (gratuit)
Navigation

Inscrivez-vous gratuitement
pour pouvoir participer, suivre les réponses en temps réel, voter pour les messages, poser vos propres questions et recevoir la newsletter

Macros et VBA Excel Discussion :

Afficher mot d'une cellule s'il existe dans une colonne


Sujet :

Macros et VBA Excel

  1. #1
    re
    re est déconnecté
    Membre du Club
    Profil pro
    Inscrit en
    novembre 2005
    Messages
    111
    Détails du profil
    Informations personnelles :
    Localisation : France

    Informations forums :
    Inscription : novembre 2005
    Messages : 111
    Points : 41
    Points
    41
    Par défaut Afficher mot d'une cellule s'il existe dans une colonne
    Bonjour,
    Je voudrai svp de l'aide sur une macro pour retrouver un mot qui est dans une cellule en comparaison d'une liste de mots qui sont dans une colonne
    Exemple :
    cellule A1 "Ceci est un test"
    cellule A2 ''quel jour''
    Etc...

    Colonne C
    jour
    rien
    un
    Lorsque le scan de C trouve un mot qui est dans une cellule de la colonne A il devrait s'afficher en ligne B sur la même ligne que le mot contenu en A
    Dans l'exemple B1 = ''un''
    Que se passe t'il s'il y a 2 mots trouvé en A1 ?

    Bien sur j'ai cherché sur le net mais pas réellement trouvé la bonne macro

    Merci à vous

  2. #2
    Expert éminent sénior

    Homme Profil pro
    AAAA
    Inscrit en
    avril 2013
    Messages
    6 250
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : France, Ille et Vilaine (Bretagne)

    Informations professionnelles :
    Activité : AAAA

    Informations forums :
    Inscription : avril 2013
    Messages : 6 250
    Points : 14 673
    Points
    14 673
    Par défaut
    Citation Envoyé par re Voir le message
    Bonjour,

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    39
    40
    41
    42
    43
    44
    45
     
    Sub RechercherLesMots()
     
    Dim AireDonnees As Range, AireListe As Range
    Dim I As Long, J As Long, DerniereLigne As Long
    Dim K As Integer
    Dim TabMots As Variant
    Dim MonDico As Scripting.Dictionary
     
        With Sheets("Feuil1")
     
             .Columns("B").ClearContents
     
             DerniereLigne = .Cells(.Rows.Count, "A").End(xlUp).Row
             Set AireDonnees = .Range(.Cells(1, "A"), .Cells(DerniereLigne, "A"))
     
             DerniereLigne = .Cells(.Rows.Count, "C").End(xlUp).Row
             Set AireListe = .Range(.Cells(1, "C"), .Cells(DerniereLigne, "C"))
     
             For I = 1 To AireDonnees.Count
                 TabMots = Split(AireDonnees(I), " ")
                 Set MonDico = CreateObject("Scripting.Dictionary")
     
                 For K = LBound(TabMots) To UBound(TabMots)
                     For J = 1 To AireListe.Count
                       If AireListe(J) = TabMots(K) Then
                           If Not MonDico.Exists(TabMots(K)) Then
                               MonDico.Add (TabMots(K)), TabMots(K)
                               AireDonnees(I).Offset(0, 1) = AireDonnees(I).Offset(0, 1) & TabMots(K) & " "
                            End If
     
                       End If
     
                     Next J
                 Next K
                 Set MonDico = Nothing
             Next I
     
     
     
      End With
     
      Set AireDonnees = Nothing: Set AireListe = Nothing
     
    End Sub

  3. #3
    re
    re est déconnecté
    Membre du Club
    Profil pro
    Inscrit en
    novembre 2005
    Messages
    111
    Détails du profil
    Informations personnelles :
    Localisation : France

    Informations forums :
    Inscription : novembre 2005
    Messages : 111
    Points : 41
    Points
    41
    Par défaut
    Bonjour Eric,
    Merci beaucoup ça marche parfaitement, je l'ai modestement adaptée pour aller chercher les feuilles.
    Petite précision il faut activer ''Microsoft Scripting Runtime''

    Comment afficher un deuxième mot qui serait dans la BDD dans la même cellule, (colonne C dans l'exemple : Quel jour), ce mot ''Quel jour'' fait parti d'un ensemble de mot de la cellule de la colonne A

    Bonne journée

  4. #4
    re
    re est déconnecté
    Membre du Club
    Profil pro
    Inscrit en
    novembre 2005
    Messages
    111
    Détails du profil
    Informations personnelles :
    Localisation : France

    Informations forums :
    Inscription : novembre 2005
    Messages : 111
    Points : 41
    Points
    41
    Par défaut
    Bonjour,
    Le code me convient parfaitement
    Mais comment supprimer l'espace à la fin du mot ?
    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    AireDonnees(I).Offset(0, 1) = AireDonnees(I).Offset(0, 1) & TabMots(K) & " "
    S'il y a deux mots en supprimant l'espace entre " " aura pour effet de coller les 2 mots (DeuxMots) au lieu de Deux Mots
    je n'ai pas su intégrer =supprespace(A1) par exemple (pas sur que ce soit la bonne méthode)

    Merci

  5. #5
    Expert éminent sénior

    Homme Profil pro
    AAAA
    Inscrit en
    avril 2013
    Messages
    6 250
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : France, Ille et Vilaine (Bretagne)

    Informations professionnelles :
    Activité : AAAA

    Informations forums :
    Inscription : avril 2013
    Messages : 6 250
    Points : 14 673
    Points
    14 673
    Par défaut
    Citation Envoyé par re Voir le message
    A tester, voir en ligne 36.

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    39
    40
    41
    42
    43
    44
    45
    46
     
    Sub RechercherLesMots()
     
    Dim AireDonnees As Range, AireListe As Range
    Dim I As Long, J As Long, DerniereLigne As Long
    Dim K As Integer
    Dim TabMots As Variant
    Dim MonDico As Scripting.Dictionary
     
        With Sheets("Feuil1")
     
             .Columns("B").ClearContents
     
             DerniereLigne = .Cells(.Rows.Count, "A").End(xlUp).Row
             Set AireDonnees = .Range(.Cells(1, "A"), .Cells(DerniereLigne, "A"))
     
             DerniereLigne = .Cells(.Rows.Count, "C").End(xlUp).Row
             Set AireListe = .Range(.Cells(1, "C"), .Cells(DerniereLigne, "C"))
     
             For I = 1 To AireDonnees.Count
                 TabMots = Split(AireDonnees(I), " ")
                 Set MonDico = CreateObject("Scripting.Dictionary")
     
                 For K = LBound(TabMots) To UBound(TabMots)
                     For J = 1 To AireListe.Count
                       If AireListe(J) = TabMots(K) Then
                           If Not MonDico.Exists(TabMots(K)) Then
                               MonDico.Add (TabMots(K)), TabMots(K)
                               AireDonnees(I).Offset(0, 1) = AireDonnees(I).Offset(0, 1) & TabMots(K) & " "
                            End If
     
                       End If
     
                     Next J
                 Next K
                 AireDonnees(I).Offset(0, 1) = Trim(AireDonnees(I).Offset(0, 1))
                 Set MonDico = Nothing
             Next I
     
     
     
      End With
     
      Set AireDonnees = Nothing: Set AireListe = Nothing
     
    End Sub

  6. #6
    re
    re est déconnecté
    Membre du Club
    Profil pro
    Inscrit en
    novembre 2005
    Messages
    111
    Détails du profil
    Informations personnelles :
    Localisation : France

    Informations forums :
    Inscription : novembre 2005
    Messages : 111
    Points : 41
    Points
    41
    Par défaut
    Bonjour
    pardon pour ma réponse tardive.
    Merci, ça fonctionne

  7. #7
    re
    re est déconnecté
    Membre du Club
    Profil pro
    Inscrit en
    novembre 2005
    Messages
    111
    Détails du profil
    Informations personnelles :
    Localisation : France

    Informations forums :
    Inscription : novembre 2005
    Messages : 111
    Points : 41
    Points
    41
    Par défaut
    Bonjour,
    Votre code fonctionne parfaitement pour un mot mais s'il y a une occurrence ça me pose un petit souci pour identifier qui est qui ,-)
    Exemple sur 2 cellules

    A1 = Commission cotisation à une offre => extraire ''Commission offre'' => l’identification serait ''Multimédia"
    A2 = Commission virement SEPA => extraire ''Commission SEPA'' => l’identification serait ''Banque"

    L'identification est rentrée manuellement dans une autre colonne pour chaque nouveau mot, elle est copiée dans une BDD et récupérée automatiquement si besoin lors d'un nouvel import

    Est-il possible dans ce même code d'imposer certains mots qui sont dans la même cellule ?
    Le résultat devrait être Commission offre et Commission SEPA et pas seulement la même réponse ''Commission'' pour les deux cas, l'ordre des mots est bien souvent 'aléatoire''

    les données du fichier CSV que je dois extraite sont parfois incompréhensibles un court exemple : REF/9982851745 Motif AZBT / AAA Commission cotisation LIB//161718881/I offre xxxx333 (et encore j'ai filtré)

    J'espère que mes explications sont claires...

    Merci

  8. #8
    Expert éminent sénior

    Homme Profil pro
    AAAA
    Inscrit en
    avril 2013
    Messages
    6 250
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : France, Ille et Vilaine (Bretagne)

    Informations professionnelles :
    Activité : AAAA

    Informations forums :
    Inscription : avril 2013
    Messages : 6 250
    Points : 14 673
    Points
    14 673
    Par défaut
    Citation Envoyé par re Voir le message
    Il faudrait spliter la liste des mots clés dans la liste (liste des mots clés sur une même ligne) et ajouter une boucle à l'intérieur de la boucle J pour identifier les différents mots.

  9. #9
    Responsable
    Office & Excel


    Homme Profil pro
    Formateur et développeur chez EXCELLEZ.net
    Inscrit en
    novembre 2003
    Messages
    17 698
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 54
    Localisation : Belgique

    Informations professionnelles :
    Activité : Formateur et développeur chez EXCELLEZ.net
    Secteur : Enseignement

    Informations forums :
    Inscription : novembre 2003
    Messages : 17 698
    Points : 51 145
    Points
    51 145
    Billets dans le blog
    93
    Par défaut
    Salut.

    Je ne suis pas certain d'avoir tout compris, mais si tu veux extraire des mots-clés présents dans une liste, tu pourrais peut-être te tourner vers les expressions rationnelles. Ici, pour simplifier le motif, la chaine et les mots-clé sont repris en minuscules

    Nom : 2021-05-13_205220.png
Affichages : 113
Taille : 11,3 Ko


    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    Function MotsTrouves(Phrase As String, Motscles As Range) As String
      Dim RegExp As Object
      Dim Matches As Object
      Dim SubMatch As Object
      Dim r As Range
      Dim Pattern As String
     
      ' Création du motif
      Set RegExp = CreateObject("VBScript.RegExp")
      For Each r In Motscles
        Pattern = Pattern & "\b" & r.Value & "\b|"
      Next
      Pattern = LCase(Left(Pattern, Len(Pattern) - 1))
      RegExp.Pattern = Pattern
     
      ' Création du tableau de résultat
      RegExp.Global = True
      Set Matches = RegExp.Execute(LCase(Phrase))
      For Each SubMatch In Matches
        RegExp.Pattern = "\b" & SubMatch & "\b" ' On teste si le mot-clé a déjà été poussé
        If Not RegExp.test(MotsTrouves) Then MotsTrouves = MotsTrouves & SubMatch.Value & ";"
      Next SubMatch
      If MotsTrouves <> "" Then MotsTrouves = Left(MotsTrouves, Len(MotsTrouves) - 1)
     
      Set RegExp = Nothing
      Set Matches = Nothing
      Set SubMatch = Nothing
    End Function
    "Plus les hommes seront éclairés, plus ils seront libres" (Voltaire)
    ---------------
    Mes remarques et critiques sont purement techniques. Ne les prenez jamais pour des attaques personnelles...
    Pensez à utiliser les tableaux structurés. Ils vous simplifieront la vie, tant en Excel qu'en VBA ==> mon tuto
    Le VBA ne palliera jamais une mauvaise conception de classeur ou un manque de connaissances des outils natifs d'Excel...
    Ce ne sont pas des bonnes pratiques parce que ce sont les miennes, ce sont les miennes parce que ce sont des bonnes pratiques
    VBA pour Excel? Pensez D'ABORD en EXCEL avant de penser en VBA...
    ---------------

  10. #10
    re
    re est déconnecté
    Membre du Club
    Profil pro
    Inscrit en
    novembre 2005
    Messages
    111
    Détails du profil
    Informations personnelles :
    Localisation : France

    Informations forums :
    Inscription : novembre 2005
    Messages : 111
    Points : 41
    Points
    41
    Par défaut
    Bonjour Pierre et merci pour ton retour,

    Tu as parfaitement compris la demande mais bien sûr je n'arrive pas écrire la syntaxe ;-)

    Dans la fonction en B2: =MotsTrouves([@Phrase];t_MotsCherchés[Mot]), t_MotsCherchés c'est quoi ?

    Si j'ai bien compris en colonne E ça serait les mots qu'il y aurait dans la BDD ?
    Si c'est le cas le résultat de B est bien le résultat attendu et c'est ce que je recherche (peut être sans les ; mais c'est gérable )

    Bonne journée

  11. #11
    Responsable
    Office & Excel


    Homme Profil pro
    Formateur et développeur chez EXCELLEZ.net
    Inscrit en
    novembre 2003
    Messages
    17 698
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 54
    Localisation : Belgique

    Informations professionnelles :
    Activité : Formateur et développeur chez EXCELLEZ.net
    Secteur : Enseignement

    Informations forums :
    Inscription : novembre 2003
    Messages : 17 698
    Points : 51 145
    Points
    51 145
    Billets dans le blog
    93
    Par défaut
    Le tableau des mots à trouver s'appelle t_MotsCherchés. C'est un tableau structuré (voir mon tuto sur les tableaux structurés si tu ne connais pas trop). Tu pourrais avoir une plage classique, mais je trouve plus intéressant de travailler avec des tableaux structurés.

    Nom : 2021-05-15_203824.png
Affichages : 92
Taille : 122,9 Ko


    Pour le séparateur, ça se passe dans la fonction perso à placer dans un module standard du classeur. Ici, je l'ai adaptée pour que tu puisses choisir le séparateur qui te convient, qui peut tenir sur un seul caractère comme sur plusieurs. sur l'illustration qui suit, j'ai mis " | " comme séparateur à 3 caractères. Comme "mots à rechercher", tu pourrais aussi choisir une locution de plusieurs mots si tu le souhaites.

    Nom : 2021-05-15_204434.png
Affichages : 102
Taille : 113,6 Ko


    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    <a href="https://fauconnier.developpez.com/tutoriels/tableaux-structures/" target="_blank">mon tuto sur les tableaux structurés</a>
    "Plus les hommes seront éclairés, plus ils seront libres" (Voltaire)
    ---------------
    Mes remarques et critiques sont purement techniques. Ne les prenez jamais pour des attaques personnelles...
    Pensez à utiliser les tableaux structurés. Ils vous simplifieront la vie, tant en Excel qu'en VBA ==> mon tuto
    Le VBA ne palliera jamais une mauvaise conception de classeur ou un manque de connaissances des outils natifs d'Excel...
    Ce ne sont pas des bonnes pratiques parce que ce sont les miennes, ce sont les miennes parce que ce sont des bonnes pratiques
    VBA pour Excel? Pensez D'ABORD en EXCEL avant de penser en VBA...
    ---------------

  12. #12
    re
    re est déconnecté
    Membre du Club
    Profil pro
    Inscrit en
    novembre 2005
    Messages
    111
    Détails du profil
    Informations personnelles :
    Localisation : France

    Informations forums :
    Inscription : novembre 2005
    Messages : 111
    Points : 41
    Points
    41
    Par défaut
    Bonjour Pierre
    Merci beaucoup, tes explications sont claires, effectivement j'avais nommé le tableau ''Mot'' au lieux de de ''t_Motscherchés''

    Pour le séparateur, je n'ai pas trop compris, si rentre ta formule =MotsTrouves([@Phrase];t_MotsCherchés[Mot];" |"), ça met #Valeur! .
    Pour modifier le séparateur il faut que je modifie cette ligne
    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    If Not RegExp.test(MotsTrouves) Then MotsTrouves = MotsTrouves & SubMatch.Value & " |"
    avec cette formule =MotsTrouves([@Phrase];t_MotsCherchés[Mot]).
    Je n'ai donc pas le choix pour choisir le séparateur dans la formule, ce n'est pas important mais c'est pour comprendre

    Autre phénomène dans l'exemple ci-dessous, ça créé un espace en début avec le séparateur
    Nom : Capture.JPG
Affichages : 78
Taille : 20,1 Ko
    Si j'utilise un espace en lieu et place d'un séparateur, ça fonctionne avec cette formule =SUPPRESPACE(MotsTrouves([@Phrase];t_MotsCherchés[Mot])).
    Encore une fois je peux me contenter d'un espace pour les séparateurs

    Bonne journée

  13. #13
    re
    re est déconnecté
    Membre du Club
    Profil pro
    Inscrit en
    novembre 2005
    Messages
    111
    Détails du profil
    Informations personnelles :
    Localisation : France

    Informations forums :
    Inscription : novembre 2005
    Messages : 111
    Points : 41
    Points
    41
    Par défaut
    Bonjour
    Comment modifier ce dernier programme pour que s'il y a un mot répété dans une cellule de la colonne A un seul est affiché dans une cellule en colonne B ?
    Merci beaucoup

  14. #14
    Responsable
    Office & Excel


    Homme Profil pro
    Formateur et développeur chez EXCELLEZ.net
    Inscrit en
    novembre 2003
    Messages
    17 698
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 54
    Localisation : Belgique

    Informations professionnelles :
    Activité : Formateur et développeur chez EXCELLEZ.net
    Secteur : Enseignement

    Informations forums :
    Inscription : novembre 2003
    Messages : 17 698
    Points : 51 145
    Points
    51 145
    Billets dans le blog
    93
    Par défaut
    La solution que j'ai donnée le 15/05 ne répète pas le mot s'il se trouve plusieurs fois comme illustré dans la copie d'écran, sauf erreur de ma part
    "Plus les hommes seront éclairés, plus ils seront libres" (Voltaire)
    ---------------
    Mes remarques et critiques sont purement techniques. Ne les prenez jamais pour des attaques personnelles...
    Pensez à utiliser les tableaux structurés. Ils vous simplifieront la vie, tant en Excel qu'en VBA ==> mon tuto
    Le VBA ne palliera jamais une mauvaise conception de classeur ou un manque de connaissances des outils natifs d'Excel...
    Ce ne sont pas des bonnes pratiques parce que ce sont les miennes, ce sont les miennes parce que ce sont des bonnes pratiques
    VBA pour Excel? Pensez D'ABORD en EXCEL avant de penser en VBA...
    ---------------

  15. #15
    re
    re est déconnecté
    Membre du Club
    Profil pro
    Inscrit en
    novembre 2005
    Messages
    111
    Détails du profil
    Informations personnelles :
    Localisation : France

    Informations forums :
    Inscription : novembre 2005
    Messages : 111
    Points : 41
    Points
    41
    Par défaut
    Bonjour,
    Effectivement sans modification ça marche
    Plus sérieusement j'ai cru bon pour afficher en majuscule d'ajouter UCase :

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    If Not RegExp.Test(MotsTrouves) Then MotsTrouves = UCase(MotsTrouves & SubMatch.Value & " ")
    Ca affiche bien en majuscule mais il y a répétition du mots si ce mot est plusieurs fois dans la cellule.
    Peux-tu me donner la bonne syntaxe ?

    Merci

  16. #16
    Responsable
    Office & Excel


    Homme Profil pro
    Formateur et développeur chez EXCELLEZ.net
    Inscrit en
    novembre 2003
    Messages
    17 698
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 54
    Localisation : Belgique

    Informations professionnelles :
    Activité : Formateur et développeur chez EXCELLEZ.net
    Secteur : Enseignement

    Informations forums :
    Inscription : novembre 2003
    Messages : 17 698
    Points : 51 145
    Points
    51 145
    Billets dans le blog
    93
    Par défaut
    C'est normal car à la ligne qui teste si le mot est déjà repris, on le passe en minuscule alors qu'on l'a poussé en majuscule.
    Voici une solution au problème. Les modifs sont au niveau des <===

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    Function MotsTrouves(Phrase As String, Motscles As Range) As String
      Dim RegExp As Object
      Dim Matches As Object
      Dim SubMatch As Object
      Dim r As Range
      Dim Pattern As String
     
      Set RegExp = CreateObject("VBScript.RegExp")
      For Each r In Motscles
        Pattern = Pattern & "\b" & r.Value & "\b|"
      Next
      Pattern = LCase(Left(Pattern, Len(Pattern) - 1))
      RegExp.Pattern = Pattern
     
      RegExp.Global = True
      Set Matches = RegExp.Execute(Phrase)
      For Each SubMatch In Matches
        RegExp.Pattern = "\b" & UCase(SubMatch) & "\b" ' <=== On passe en majuscules
        If Not RegExp.test(MotsTrouves) Then MotsTrouves = MotsTrouves & UCase(SubMatch.Value) & ";" ' <=== On passe en majuscules
      Next SubMatch
      If MotsTrouves <> "" Then MotsTrouves = Left(MotsTrouves, Len(MotsTrouves) - 1)
     
      Set RegExp = Nothing
      Set Matches = Nothing
      Set SubMatch = Nothing
    End Function
    "Plus les hommes seront éclairés, plus ils seront libres" (Voltaire)
    ---------------
    Mes remarques et critiques sont purement techniques. Ne les prenez jamais pour des attaques personnelles...
    Pensez à utiliser les tableaux structurés. Ils vous simplifieront la vie, tant en Excel qu'en VBA ==> mon tuto
    Le VBA ne palliera jamais une mauvaise conception de classeur ou un manque de connaissances des outils natifs d'Excel...
    Ce ne sont pas des bonnes pratiques parce que ce sont les miennes, ce sont les miennes parce que ce sont des bonnes pratiques
    VBA pour Excel? Pensez D'ABORD en EXCEL avant de penser en VBA...
    ---------------

  17. #17
    re
    re est déconnecté
    Membre du Club
    Profil pro
    Inscrit en
    novembre 2005
    Messages
    111
    Détails du profil
    Informations personnelles :
    Localisation : France

    Informations forums :
    Inscription : novembre 2005
    Messages : 111
    Points : 41
    Points
    41
    Par défaut
    Bonjour,
    C'est réactif,
    C'est top
    Ca fonctionne parfaitement

    Merci
    Bonne journée

Discussions similaires

  1. Réponses: 2
    Dernier message: 22/03/2017, 15h38
  2. [IDE] Afficher hint sur une colonne Tlistview
    Par Pascale38 dans le forum C++Builder
    Réponses: 2
    Dernier message: 18/11/2011, 11h04
  3. Chercher un mot d'une colonne dans une autre colonne
    Par agur29 dans le forum Réplications
    Réponses: 6
    Dernier message: 17/12/2008, 16h52
  4. Comment afficher ou Maskquer une Colonne dans Listview
    Par r.mehdi dans le forum VB 6 et antérieur
    Réponses: 1
    Dernier message: 07/06/2008, 10h44
  5. [VBA-E] Copier le mot d'une colonne
    Par sebneb dans le forum Macros et VBA Excel
    Réponses: 14
    Dernier message: 13/02/2007, 17h23

Partager

Partager
  • Envoyer la discussion sur Viadeo
  • Envoyer la discussion sur Twitter
  • Envoyer la discussion sur Google
  • Envoyer la discussion sur Facebook
  • Envoyer la discussion sur Digg
  • Envoyer la discussion sur Delicious
  • Envoyer la discussion sur MySpace
  • Envoyer la discussion sur Yahoo