Discussion :

[anasecu]

re

Mais la, si je clic direct sur imprimer 'sans recherche" j'ai ça :

Évidemment il n'y à rien dans la liste

la fenêtre d'aperçu s'ouvre mais tout est bloqué, aucune action (entrée ou echap, pas possibilité de fermer la fenêtre)

Là je ne sais pas ce que tu as comme version excel mais comme je n'imprime quasiment jamais je me contente de l'aperçu et je n'ai jamais eu de blocage.
Essaies comme ceci, cela devrait corriger tes soucis.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Private Sub CommandButton5_Click() 'impression
Dim tbl As Variant
    If ListBox1.ListCount > 0 Then
        tbl = ListBox1.List
        Workbooks.Add                 'création d'un nouveau classeur temporaire
        Range("A1").Resize(UBound(tbl), UBound(tbl, 2)).Value = tbl
        ActiveSheet.UsedRange.Columns.AutoFit
        ActiveSheet.PageSetup.PrintArea = ActiveSheet.UsedRange.Cells.Address
        ActiveSheet.PageSetup.Orientation = xlLandscape
     '   ActiveWorkbook.PrintPreview  'visualiser
        ActiveWorkbook.PrintOut       'impression
        ActiveWorkbook.Close False    'suppression du classeur temporaire
    Else
        MsgBox "Rien à imprimer ! :)"
    End If
End Sub

[Fabweb]

Ca fonctionne nickel,
un grand merci pour votre patience et votre gentillesse

Fabrice

[Fabweb]

Encore une dernière question....svp

mon bouton "imprimer ne fonctionne pas avec le bouton < à10% ?????????

voici mon code pour le bouton "imprimer"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Private Sub Btn_Imprimer_Click() 'impression
Dim tbl As Variant
    If ListBox1.ListCount > 0 Then
        tbl = ListBox1.List
        Workbooks.Add                 'création d'un nouveau classeur temporaire
        Range("A1").Resize(UBound(tbl), UBound(tbl, 2)).Value = tbl
        ActiveSheet.UsedRange.Columns.AutoFit
        ActiveSheet.PageSetup.PrintArea = ActiveSheet.UsedRange.Cells.Address
        ActiveSheet.PageSetup.Orientation = xlLandscape
     '   ActiveWorkbook.PrintPreview  'visualiser
        ActiveWorkbook.PrintOut       'impression
        ActiveWorkbook.Close False    'suppression du classeur temporaire
    Else
        MsgBox "Rien à imprimer ! :)"
    End If
End Sub

j'ai une erreur d’exécution 1004
Erreur définie par l'application ou par l'objet

Et si je clique sur débogage cette ligne est surlignée en jaune: Range("A1").Resize(UBound(tbl), UBound(tbl, 2)).Value = tbl

Que dois je modifier svp?
Fabrice

[anasecu]

Bonsoir Fabweb

Que dois je modifier svp?

Comme ceci peut-être si plusieurs classeurs ouverts :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveWorkbook.ActiveSheet.Range("A1").Resize(UBound(tbl), UBound(tbl, 2)).Value = tbl

[Pierre Fauconnier]

Salut

Voila ça fonctionne, j'ai du enlever 2 colonnes car impossible de faire fonctionner si > 9 colonnes???[...]

[...]
Les listbox sont limitées en colonne effectivement et il faut choisir[...]

Si on appuie le listbox sur une plage de données, on fait sauter cette limite




On peut également la faire sauter en affectant un array à la propriété List, puis on passe les AddItem et List(x,y)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Private Sub UserForm_Initialize()
  Dim t(0, 19)
  Dim i As Long, j As Long
 
  ListBox1.List = t
  ListBox1.Clear
  For i = 0 To 10
    ListBox1.AddItem ""
    For j = 0 To 19
      ListBox1.List(i, j) = i & ":" & j
    Next j
  Next i
End Sub

[Fabweb]

Merci Pierre pour la limitation Listbox, j'essaierai rapidement.

La je suis plus bloqué avec mon bouton "imprimer" lors que j'ai sélectionné "Moyenne générale inférieure à 10%"
Alors que bizarrement cela fonctionne dans tous les autres cas???

Fabrice

[Pierre Fauconnier]

Je suppose que

• tu n'as qu'une ligne dans ta listbox pour Moyenne < 10%;
• tu n'a pas Option Base 1 en entête de ton module, ce qui veut dire que tbl commence à l'indice 0 tant pour les lignes que pour les colonnes.

Dès lors, il faudrait utiliser Range("a1").Resize(UBound(tbl) + 1, UBound(tbl, 2) + 1).Value = tbl car si tu n'as qu'une ligne dans ton listbox, tu vas essayer de "resizer" la plage à Ubound(tbl) qui vaut 0 et forcément, ça ne va pas passer car tu ne peux pas redimensionner une plage à 0 lignes.

Ca me fait dire qu'il serait bien possible que dans les cas où "ça fonctionnait", tu loupais la dernière ligne et la dernière colonne qui n'étaient pas transférées dans la feuille avant l'impression.

[...]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveWorkbook.ActiveSheet.Range("A1").Resize(UBound(tbl), UBound(tbl, 2)).Value = tbl

ActiveWorkbook.ActiveSheet. ne sert à rien sur le plan technique. Range("a1") "non parentalisé" pointera toujours vers la feuille active, et la feuille active (ActiveSheet non parentalisé) sera forcément toujours dans le classeur actif, quelque soit le classeur qui contient le code en train d'être exécuté.

[Fabweb]

Merci Pierre,
Effectivement, pour l'instant je n'avais qu'1 seul résultat < 10%

J'ai mis votre code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range("a1").Resize(UBound(tbl) + 1, UBound(tbl, 2) + 1).Value = tbl

Et ça fonctionne
Merci Beaucoup
Amicalement
Fabrice