Discussion :

[duppie20]

Bonjour,

Dans un formulaire word ayant un certain nombre de contrôle (champ texte, numérique, liste déroulante, date ou case à cocher), je souhaite faire en VBA-Word une boucle de 1 à N pour récupérer tous les noms de contrôle et leur valeur pour ensuite pousser le tout dans un fichier CSV. Selon moi le plus simple sera de faire la boucle 2 fois pour écrire en premier la ligne d'entête et à la 2e passe la ligne de data. Par la suite ce fichier CSV sera poussé dans une BD Access ou vers un fichier Excel qui recevra tout par la magie du nuage.
En VBA access, je suis bien alaise, un peu moins en VBA excel mais en VBA word, jamais. J'ai tenté quelques essais mais je plafonne (rapidement) sans succès. Les contrôles dont je parle sont ceux word 2016 et + avec les braquettes devant et après la zone à saisir (ce ne sont pas ceux issus d'ActiveX ni ceux des zones de champ des versions antérieures de word).

Ma première question: comment récupérer ces objets. Si j'arrive à afficher un msgbox avec le nom et le contenu d'un seul champs je serai déjà bien heureux car par la suite je ferai mes essais de boucle pour conclure avec l'envoi dans un fichier CSV.

merci pour vos suggestions.

[Gado2600]

Bonjour Duppie,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Les contrôles dont je parle sont ceux word 2016 et + avec les braquettes devant et après la zone à saisir

Tu parles des signets ?

Regardes du côté "bookmarks" via ce lien :
https://docs.microsoft.com/fr-fr/off...6)%26rd%3Dtrue

Par contre, prends en compte qu'un bookmark (signet, si c'est bien ce que tu as décrit) est facilement effaçable dans un Word.

Cordialement,

[duppie20]

Après quelques recherches ce sont des “content controls”. Je cherches comment les retrouver via du code VBA pour les exploiter.

[Invité]

Après quelques recherches ce sont des “content controls”. Je cherches comment les retrouver via du code VBA pour les exploiter.

Bonjour,

A tester :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
 
Option Explicit
 
Public MatriceControles() As Variant
Public IndexMatrice As Integer
 
Sub TestListerLesContentControls()
 
    ListerLesContentControls ActiveDocument
    LireLaMatriceControles
 
End Sub
 
Sub ListerLesContentControls(ByVal WordDoc As Document)
 
Dim I As Integer
 
    IndexMatrice = 0
 
    With WordDoc
         For I = 1 To .ContentControls.Count
             With .ContentControls(I)
                  'Debug.Print "Titre : " & .Title & ", type : " & .Type & ", contenu : " & .Range.Text
                  ReDim Preserve MatriceControles(2, IndexMatrice)
                  MatriceControles(0, IndexMatrice) = .Title
                  MatriceControles(1, IndexMatrice) = .Type
                  MatriceControles(2, IndexMatrice) = .Range.Text
                  IndexMatrice = IndexMatrice + 1
            End With
        Next I
   End With
 
End Sub
 
 
Sub LireLaMatriceControles()
 
    For IndexMatrice = LBound(MatriceControles, 2) To UBound(MatriceControles, 2)
        Debug.Print "Titre : " & MatriceControles(0, IndexMatrice) & ", type : " & MatriceControles(1, IndexMatrice) & ", contenu : " & MatriceControles(2, IndexMatrice)
    Next IndexMatrice
 
End Sub

[duppie20]

Merci infiniment

C'est exactement ce que je cherchais.
Peut-être toutefois, je remarque que le type de content control n'est pas toujours facile à choisir

Dans le cadre d'un formulaire où la protection à la saisie est activé, ça ne fait pas trop de différence entre texte enrichi versus texte brut.
Pour les autres type c'est un peu la même chose entre zone le liste déroulante versus liste déroulante.
Il n'y a pas de type numérique (je vais me résigner à inscrire des chiffres en alpha et les convertir plus tard...)

pour la partie qui vise à transférer le contenu vers un fichier CSV ou EXCEL, je devrais y parvenir sans trop de peine.

Bref, j'ai découvert les types suivants :

type
0- texte enrichi
1- texte brut
2- image
3- zone liste déroulante
4- liste déroulante
5- ne semble pas exister
6- calendrier
7- ne semble pas exister
8- case à cocher --> le data oui/non (ou peut être -1/0) ne s'affiche pas (ça indique seulement "?") --> je vais introduire une liste avec oui/non codé en -1 et 0. ;-)
9- text répétitif

[Invité]

Pour les cases à cocher, modifiez le code comme ci-dessous :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
 
Sub ListerLesContentControls(ByVal WordDoc As Document)
 
Dim I As Integer
 
    IndexMatrice = 0
 
    With WordDoc
         For I = 1 To .ContentControls.Count
             With .ContentControls(I)
                  'Debug.Print "Titre : " & .Title & ", type : " & .Type & ", contenu : " & .Range.Text
                  ReDim Preserve MatriceControles(2, IndexMatrice)
                  MatriceControles(0, IndexMatrice) = .Title
                  MatriceControles(1, IndexMatrice) = .Type
                  Select Case .Type
                         Case 8
                              MatriceControles(2, IndexMatrice) = .Checked
                         Case Else
                              MatriceControles(2, IndexMatrice) = .Range.Text
 
                  End Select
                  IndexMatrice = IndexMatrice + 1
            End With
        Next I
   End With
 
End Sub

[duppie20]

Génial

Merci