Discussion :

[bthomas53]

Pour l'un de nos clients, nous recevons chaque semaine un data sharing d’intersport avec les ventes et les stocks.

Pour chaque fichier j’ai créé une colonne date pour les différencier et les ai ajoutés dans une feuille commune pour les intégrer à Power BI.

Le problème que j’ai c’est que dans mon fichier principal les ventes et stocks sont donnés depuis le début de l’année.

Connaitriez vous un moyen de créer une formule automatique pour faire les différences de chaque modèle dans chaque magasin à la semaine.

Par exemple sur un magasin X en Semaine 12 j'ai 3 vente depuis le début de l'année, en semaine 13 j'ai 5 vente depuis le début de l'année (in fine 2 ventes ont été réalisé en semaine 13).

J'aimerai afficher ces ventes à la semaine et je vous sollicite donc pour savoir si quelqu'un avait une solution

Merci d'avance,

[Tippa]

Bonjour,

Sans en savoir plus sur votre modèle de données (avez-vous une table de dates ? Sous quelle forme sont les dates ou numéro de semaine ?) difficile de répondre précisément.

Je vous mets en pièce jointe un cas assez similaire au votre (fichier Excel et pbix) avec de la consommation de gaz cumulative et pour calculer la conso par période.

Vus y trouverez des mesures écrites pour fonctionner avec les filtres du rapport.

J'espère que cela peut vous aider, sinon il faudra nous en dire plus.

Bonne fin de semaine

PS : Si vous avez besoin d'une table de dates et que vous ne savez pas comment faire vous pouvez vous referez à ce post :
https://www.developpez.net/forums/d2...m-num-sem-iso/

[danixdb]

Bonjour bthomas53, Tippa, Le Forum,

Une requête en power query répond aussi à la demande (j'y ai ajouté une colonne Date calculée par rapport au numéro de semaine de l'année), peut-être utile dans le cas de futurs calculs se basant sur le Time Intelligence, mais comme le dit Tippa, là il faut une table de dates).
Je suis parti d'un fichier par semaine mis dans le même dossier, la semaine étant inscrite dans une colonne dans chaque fichier (on peut la déduire du nom de l'onglet ou du nom du fichier en fonction de la sauvegarde au moment de la réception des fichiers du client)

Structure des fichiers.


Requête Power Query.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
 
let
    Source = Folder.Files("C:\Users\DanixDB\OneDrive\Documents\bthomas53"),
    #"FiltreLignesXLS?" = Table.SelectRows(Source, each Text.Contains([Extension], ".xls")),
    AjoutColonneObjetsExcel = Table.AddColumn(#"FiltreLignesXLS?", "ObjetsExcel", each Excel.Workbook([Content],true)),
    DevelopperObjetsExcel = Table.ExpandTableColumn(AjoutColonneObjetsExcel, "ObjetsExcel", {"Name", "Data"}, {"Name.1", "Data"}),
    FitreTableauVentes = Table.SelectRows(DevelopperObjetsExcel, each ([Name.1] = "tabVentes")),
    DevelopperColonneData = Table.ExpandTableColumn(FitreTableauVentes, "Data", {"Magasins", "Modèles", "Semaine", "Ventes"}, {"Magasins", "Modèles", "Semaine", "Ventes"}),
    SuppressionAutresCols = Table.SelectColumns(DevelopperColonneData,{"Magasins", "Modèles", "Semaine", "Ventes"}),
    AjoutColonneDateParRapportASemaine = Table.AddColumn(SuppressionAutresCols, "DateSemaine", each fxgetStartDateFromWeekinYear([Semaine])),
    ModificationTypesData = Table.TransformColumnTypes(AjoutColonneDateParRapportASemaine,{{"DateSemaine", type date}, {"Ventes", type number}}),
    LignesTriées = Table.Sort(ModificationTypesData,{{"Magasins", Order.Ascending}, {"Modèles", Order.Ascending}, {"Semaine", Order.Ascending}}),
    IndexBase1 = Table.AddIndexColumn(LignesTriées, "Index", 1, 1, Int64.Type),
    IndexBase0 = Table.AddIndexColumn(IndexBase1, "Index.1", 0, 1, Int64.Type),
    FusionRequetes = Table.NestedJoin(IndexBase0, {"Index.1"}, IndexBase0, {"Index"}, "Index ajouté1", JoinKind.LeftOuter),
    DevelopperFusionRequete = Table.ExpandTableColumn(FusionRequetes, "Index ajouté1", {"Magasins", "Modèles", "Ventes"}, {"Magasins.1", "Modèles.1", "Ventes.1"}),
    RenomerColonneVentesSemPrecedente = Table.RenameColumns(DevelopperFusionRequete,{{"Ventes.1", "VentesSemPrecedente"}}),
    AjoutColonnecalculVenteSemaine = Table.AddColumn(RenomerColonneVentesSemPrecedente, "VenteDeLaSemaine", each if [Magasins]=[Magasins.1] and [Modèles]=[Modèles.1] then [Ventes]-[VentesSemPrecedente] else [Ventes]),
    SuppressionAutresColonnes = Table.SelectColumns(AjoutColonnecalculVenteSemaine,{"VenteDeLaSemaine", "Magasins", "Modèles", "Semaine", "DateSemaine"}),
    PermutationColonnes = Table.ReorderColumns(SuppressionAutresColonnes,{"Magasins", "Modèles", "Semaine", "DateSemaine", "VenteDeLaSemaine"}),
    ModificationTypeColonnes = Table.TransformColumnTypes(PermutationColonnes,{{"VenteDeLaSemaine", type number}})
in
    ModificationTypeColonnes

Mesure dans Power BI

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
_VenteSemaine = sum(bthomas53[VenteDeLaSemaine])

Résultat dans un visuel Power BI.


Espérant avoir répondu à la demande ou tout au moins t'avoir donné des pistes d'investigation. Je pense qu'on peut aussi le faire grâce à des mesures DAX.
Cordialement
DanixDB