Discussion :

[modus57]

Bonjour,

Pour boucler sur une plage de cellules et obtenir une liste d'éléments sans doublons, pas de soucis.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Dim Cell As Range
    Dim Un As Collection
    Dim i As Long
    Set Un = New Collection
 
    Range("zone_sélection_années").ClearContents
    On Error Resume Next
    'Boucle sur la plage de cellule
    For Each Cell In Range("Tableau1[DATES]").SpecialCells(xlCellTypeVisible)
        If Cell <> "" Then Un.Add Year(Cell), CStr(Year(Cell))
    Next Cell
 
    i = 0
    On Error GoTo 0
    'Boucle sur les éléments de la collection.
    For i = 1 To Un.Count
        ' transférer  les éléments de la collection vers une plage de feuille
        Cells(2, 1 + i) = Un.Item(i) 'début liste en ligne A2 à ... 
        i = i + 1
    Next i   
    Set Un = Nothing

Pour transférer dans la feuille ça ne fonctionne pas bien.

J'ai dû commettre une erreur, mais je ne trouve pas d’où ça vient.

Merci d'avance pour votre aide.

[Philippe Tulliez]

Bonjour,
Pour exporter les éléments uniques présents dans une colonne de façon simple, vous avez soit l'utilisation de PowerQuery soit utiliser la méthode AdvancedFilter de l'objet Range

Exemple avec AdvancedFilter

Exportation des éléments uniques présents dans la colonne nommée First Name du tableau structuré nommé T_DataGenerator vers la cellule A1 de la feuille dont le CodeName est shtTarget

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub T()
 Dim oRng As Range
 Set oRng = Range("T_DataGenerator").ListObject.ListColumns("First Name").Range
 oRng.AdvancedFilter Action:=xlFilterCopy, Unique:=True, CopyToRange:=shtTarget.Range("A1")
 Set oRng = Nothing
End Sub

Pour en savoir plus sur la propriété CodeName d'une feuille, lire éventuellement mon billet titré VBA Excel - Comment s’affranchir de la modification du nom de la feuille en utilisant son CodeName

[Pierre Fauconnier]

Salut.


Je plussoie Philippe sur l'utilisation de Power Query qui permet de rester dans un xlsx et qui offre un dédoublonnage plus souple que le filtre avancé tout en demandant moins de mise en place dès lors qu'on n'extrait pas toutes les colonnes ou pas dans même ordre que celui du tableau initial⁽¹⁾.

En VBA et sur base des tableaux structurés t_Source et t_Cible, j'utilise la suppression des doublons, plus souple que le filtre avancé pour dédoublonner. De plus, la plage d'arrivée d'un filtre avancé n'est pas un tableau structuré. C'est parfois bien, parfois pas

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub Test()
  If Not Range("t_Cible").ListObject.DataBodyRange Is Nothing Then Range("t_Cible").ListObject.DataBodyRange.Delete ' Vidange de la cible
  Range("t_Cible").Resize(Range("t_Source").Rows.Count).Value = Range("t_Source").Value
  Range("t_cible").RemoveDuplicates 1, Header:=xlYes
End Sub

A adapter si tu dois dédoublonner sur plusieurs colonnes.


⁽¹⁾ Perso, je ne conseille plus jamais l'usage du filtre avancé, outil devenu selon moi obsolète.

[78chris]

Bonjour à tous

Salut.

Je plussoie Philippe sur l'utilisation de Power Query qui permet de rester dans un xlsx et qui offre un dédoublonnage plus souple que le filtre avancé tout en demandant moins de mise en place dès lors qu'on n'extrait pas toutes les colonnes ou pas dans même ordre que celui du tableau initial

Un filtre avancé permet aussi de choisir les colonnes dans l'ordre voulu donc le critère discriminant pour le choix est davantage de se passer de VBA

[Pierre Fauconnier]

Salut Chris,

Power Query permet aussi le choix et l'ordre des colonnes, et est plus souple que le filtre avancé pour la gestion des doublons ainsi que pour la mise à jour de l'extraction (un simple clic droit suffit)⁽¹⁾. L'extraction sur une autre feuille (ce qui sera le cas dans 99% des cas) est également plus simple à gérer en Power Query => A partir de la version 2010, je déconseille le filtre avancé qui pour moi est devenu obsolète.


⁽¹⁾ Je sais que tu le sais, hein C'est pour les lecteurs de la discussion que je précise cela.

[modus57]

Bonsoir,

Merci pour vos réponse mais je n'arrive pas au résultat que je souhaite.

Ce que je cherche à faire c'est une liste sans doublons des lignes visibles de la colonne "DATES" du tableau structuré "Tableau1".

Comme je le dis dans mon post, boucler sur une plage de cellules et obtenir une liste d'éléments sans doublons, pas de soucis.

Ça pèche dans la boucle

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For i = 1 To Un.Count

pour transférer la liste dans la même feuille dans les cellule A2 B2 C2 … en fonction du nombre de valeurs uniques de cette liste.

[Philippe Tulliez]

Bonjour,

Ce que je cherche à faire c'est une liste sans doublons des lignes visibles de la colonne "DATES" du tableau structuré "Tableau1".

Prenons le problème autrement.
Comment obtient-on ces lignes visibles ?
En effectuant un filtre, soit une ou plusieurs conditions donc le but est d'exporter les éléments uniques suivant conditions
Problème que l'on peux résoudre avec PowerQuery OU avec la méthode AdvancedFilter

[Pierre Fauconnier]

Si tu tiens vraiment à le faire par VBA plutôt que par Power Query, tu peux utiliser ceci, avec les deux tableaux sur des feuilles différentes

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub Test()
  Dim r
  Dim i As Long
  Dim c As Range
 
  i = 1
  If Not Range("tableau2").ListObject.DataBodyRange Is Nothing Then Range("tableau2").ListObject.DataBodyRange.Delete
  ReDim r(1 To Range("tableau1").SpecialCells(xlCellTypeVisible).Count, 1 To 1)
  For Each c In Range("tableau1").SpecialCells(xlCellTypeVisible)
    r(i, 1) = c.Value
    i = i + 1
  Next
  Range("tableau2").Resize(i - 1).Value = r
  Range("tableau2").ListObject.DataBodyRange.RemoveDuplicates 1, xlYes
End Sub

Perso, je m'orienterais plutôt vers power query en transférant les conditions du filtre dans power query

[modus57]

Bonsoir M. FAUCONNIER,

Je suis navré de répondre tardivement pour vous dire que votre solution de deux tableaux sur des feuilles différentes me convient parfaitement et fonctionne tip top.

Encore une fois merci.

[Pierre Fauconnier]

J'en suis ravi

Bonne weekend!