membre qui masque un autre membre

**nanog** · 28/01/2021, 21h51

Hello toutes et tous,
j'aimerai mettre dans un caddie des produits, je tente de coder ça en objet.

Pour cela des le clique sur bouton caddie d'un produit (et après renseigné la qté), je souhaite mettre les infos dans un tableau, qui serai restitué dans une table (d'une autre page, "caddie").

J'utilise des membres de 4 classes : produit (idproduit, titreproduit,..), photoproduit (cheminphoto), lignefacture (qté), caddie qui hérite des 3 autres.

J'ai créé un tableau de type classe Caddie dans ma classe.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
Caddie est une Classe
    hérite de MLigneFacture
    hérite de MPhotoProduit
    hérite de MProduit
 
    tabCaddie est un tableau de Caddie
FIN

Le code qui met les membres dans le tableau caddie :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
 
clCaddie est un Caddie              
 
clCaddie.m_nIDProduit = ATT_IDProduit
clCaddie.m_nQuantite = ATT_Quantité
clCaddie.m_sTitreProduit = ATT_TitreProduit
clCaddie.m_sCheminPhoto = ATT_PhotoProduit
 
clCaddie.tabCaddie.Ajoute(clCaddie)

Et ca me fait un Warning au niveau du Constructeur MProduit: Le membre 'm_nIDProduit' de la classe 'MProduit' masque le membre 'm_nIDProduit' de la classe de base 'MPhotoProduit'
En effet , j'ai bien un IDProduit dans MPhotoProduit.. mais je pige pas l'erreur

Merci pour votre aide

**tbc92** · 28/01/2021, 23h15

Ma première remarque, c'est que je ne vois pas trop pourquoi MphotoProduit n'est pas intégré dans Mproduit.
Peut-être que tu prévois plusieurs photos pour chaque produit, et ça pourrait expliquer cela ... mais dans ce cas, ça génère d'autres incohérences dans ton raisonnement.

Mais ceci est un détail. En toute logique, tu as un idProduit dans Mproduit, dans mPhotoProduit, et dans MLigne facture.
Donc même ensupprimant le fichier photo, le problème subsiste.

Pour moi (pas un pro de la POO), il ne devrait pas y avoir d'héritage dans ta classe Caddie.

Pour moi, un Caddie, c'est un tableau de plusieurs LigneFacture.
Plus éventuellement des informations 'annexes' (la date, le lieu,... )

L'autre problème que je vois, c'est que tu déclares Caddie comme une classe, et dans cette classe, tu as un tableau de Caddie !!!
Par acquis de conscience, je viens de regarder la doc en diagonale, et je confirme : ça me paraît très louche.

**nanog** · 28/01/2021, 23h30

Merci TBC,
oui le tableau je vais le changer, c'était juste un essai. Il faut en effet, un tableau de MProduit ou autre mais pas de Caddie.

J'aurai voulu savoir comment tu t'y aurais pris, avec l'objectif d'avoir un tableau d'une classe pour faire afficher les résultats dans une table.

Merci.

**Voroltinquo** · 29/01/2021, 03h00

Bonjour,
1-Avec un diagramme UML tu t'en sortirais mieux.
2-A priori, la classe photo est incluse dans la classe produit, elle même incluse dans LigneFacture, qui est incluse dans Caddie. Je ne vois pas la notion d'héritage. L'héritage, c'est lorsque tu as (par exemple) un client et en vendeur qui ont des membres en commun (e.g. Nom et prénom) Il y a alors une classe individu (avec pour membres nom, prénom) et client et vendeur héritent de Individu.
3-Il est préférable de passer les paramètre d'une instance par le constructeur
4-On n'accède jamais directement aux membres d'une classe, ils sont privés. Il faut passer par des getter (récupération) et des setter (affectation). En WLangage, la propriété fait 2 en 1

En ce qui concerne ta question, pour afficher le contenu d'un tableau d'instances dans un champ table, il suffit de choisir Alimenté par une variable dans la description.

**mous97** · 29/01/2021, 10h14

Ta logique n'est juste pas bonne, revoit ta modélisation des données avant tout, ici tu n'a pas à faire d'héritage mais plutôt une déclaration de ces classes en tant qu'objet comme membre de la classe Caddie

**nanog** · 29/01/2021, 15h32

Merci à tous,
mention spéciale à Mous qui m'a donné la solution : pour ma problématique, un simple affectation des membres dans caddie et le tour est joué : j'avais zappé ça !

Désolé j'ai pas pensé à vous afficher mon modèle qui est très simple car c'est un projet test pour manipuler la POO. Voir ci-dessous.

Voroltinquo, merci pour les notions d'héritage, je suis pas encore au clair là-dessus, et oui on n’accède jamais aux membres des classes car normalement ils sont en privés.
Par contre quand tu dis que "3-Il est préférable de passer les paramètre d'une instance par le constructeur" ça se fait par défaut via les propriétés ?

Auriez vous des exemples de prog en objets ? Car windev est un peu à la ramasse avec leurs exemples la plupart sont en procédurale.

Encore merci pour votre temps et patience

Nom : MLD.png
Affichages : 94
Taille : 22,6 Ko

**mous97** · 29/01/2021, 16h08

Je t'en prie, dans d'autres langages de programmation (mention spécial au C# Entity Framework et ado) la modélisation de ton analyse est gérée automatiquement, mais bon sache que lorsque dans ton analyse tu tombes sur des relations avec foreign key, la modélisation en POO c'est de déclaré un objet de cette classe dans la classe correspondante, et dans le cas d'une relation 1-n (Ligne produit par exemple) c'est un tableau de LigneProduit que tu as dans commandes, et dans LigneProduit tu peux déclaré un objet Commande avec une relation faible (<faible>) sinon tu tombes dans une relation cyclique, c'est un peu ambiguë je te l'accorde mais ça vient seul avec l'expérience
Hésite jamais si tu as des questions.

**Voroltinquo** · 29/01/2021, 16h30

Dans un premier temps, tu ne nous fournit pas un diagramme de classe mais un MLD.
En ce qui concerne le propriété, il faut les programmer.

Un petit exemple, la classe CVecteur.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
 
CVecteur est une Classe
	PRIVÉ
		m_xX est un numérique = 0 //Abscisse
		m_xY est un numérique = 0 //Ordonnée
		m_xRho est un numérique = 0 //Module
		m_xThéta est un numérique = 0 //Phase
	FIN
//Utilisé pour différencier les 2 types de coordonnées
ETypeCoord est une Enumération
	Rectangulaire
	Polaire
FIN

Comme on ne doit pas accéder directement aux membres ils sont déclarés privés, il faut créer des propriété.
Le fonction trigonométrique utilisées sont des surchargées afin de travailler normalement (i.e. en Rad). PI a été définit dans cette collection de procédure (ou le composant qui en découle)
Propriétés:
Getter :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
PROCÉDURE PUBLIQUE p_xX() : numérique
 
RENVOYER m_xX

Setter :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 
PROCÉDURE PUBLIQUE p_xX(xValeur est un numérique)
 
:m_xX=xValeur
//Le fait de changer l'abscisse modifie le modue et la phase
:m_xRho=:CalculerModule(xValeur,:m_xY)
:m_xThéta=:CalculerPhase(xValeur,:m_xY)

etc...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
FONCTION PRIVÉE CalculerModule(xAbs est numérique,xOrd est numérique):numérique
 
RENVOYER Racine((Puissance(xAbs,2)+Puissance(xOrd,2)),2)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
 
FONCTION PRIVÉE CalculerPhase(xAbs est un numérique,xOrd est un numérique):numérique
 
SELON xAbs
	CAS 0
		SELON xOrd
			CAS >0
				RENVOYER PI/2
			CAS 0
				RENVOYER 0
			CAS <0
				RENVOYER 3*PI/2
		FIN
	CAS >0
		SELON xOrd
			CAS >=0
				RENVOYER ArcTang(xOrd/xAbs)
			CAS <0
				RENVOYER ArcTang(xOrd/xAbs)+2*PI
		FIN
	CAS <0
		RENVOYER ArcTang(xOrd/xAbs)+PI
FIN

Il nous manque le constructeur :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
 
PROCÉDURE Constructeur(xParam1 est un numérique=0,xParam2 est numérique=0,eType est ETypeCoord=Rectangulaire)
SELON eType
	CAS Rectangulaire
		:m_xX=xParam1
		:m_xY=xParam2
		:m_xRho=:CalculerModule(xParam1,xParam2)
		:m_xThéta=:CalculerPhase(xParam1,xParam2)
	CAS Polaire
		:m_xX=xParam1*Cosinus(xParam2)		
		:m_xY=xParam1*Sinus(xParam2)
		:m_xRho=xParam1
		:m_xThéta=xParam2
FIN

On peut faire des opération sur les vecteur entre autre l'addition.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
FONCTION Ajouter(clVecteur2 est CVecteur):CVecteur
clVectRes est CVecteur
 
clVectRes:p_xX=:p_xX+clVecteur2:p_xX
clVectRes:p_xX=:p_xY+clVecteur2:p_xY
 
RENVOYER clVectRes

Utilisation :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
 
clV1 est CVecteur
clV2 est CVecteur
clVRes est CVecteur
 
clV1=allouer un CVecteur(50,PI/4,CVecteur.Polaire) //Utilisation du constructeur
TracerVecteur(clV1,BleuFoncé)
clV2:p_xRho=107
clV2:p_xThéta=0.79
clVRes=clV1:Ajouter(clV2)
TracerVecteur(clVRes,VertFoncé)
dLigne(IMG_Vecteur,clV1:p_xX,clV1:p_xY,clVRes:p_xX,clVRes:p_xY,RougeFoncé)

Avec

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
PROCÉDURE TracerVecteur(clVecteur est CVecteur,nCouleur est entier)
dLigne(IMG_Vecteur,0,0,clVecteur:p_xX,clVecteur:p_xY,nCouleur)

**mous97** · 30/01/2021, 10h41

Personnellement je laisse mes membres public et je déclares des propriétés sur les membres soumis à des règles métiers, je trouve ça trop lourd de déclarer des Getter/Setter pour tous ses membres mêmes alors que 80% n'ont n'en pas besoin

**padbrain** · 31/01/2021, 10h59

Envoyé par mous97

Personnellement je laisse mes membres public et je déclares des propriétés sur les membres soumis à des règles métiers, je trouve ça trop lourd de déclarer des Getter/Setter pour tous ses membres mêmes alors que 80% n'ont n'en pas besoin

Raison de plus pour ne pas les exposer en mettant leur visibilité en public.

**mous97** · 01/02/2021, 10h00

Envoyé par padbrain

Raison de plus pour ne pas les exposer en mettant leur visibilité en public.

En public les membres sont accessibles pour les liaisons et les affectations, pas besoin de getter/setter qui n'ont aucune règles métiers dedans frérot

**padbrain** · 01/02/2021, 11h36

Chacun fait bien comme il veut

**mous97** · 01/02/2021, 12h35

Envoyé par padbrain

Chacun fait bien comme il veut

"4-On n'accède jamais directement aux membres d'une classe, ils sont privés. Il faut passer par des getter (récupération) et des setter "
Pas d'après cette règle

membre qui masque un autre membre [WD23]

WinDev

Discussions similaires

Partager

Partager