Discussion :

[JYL74]

Bonjour,
Je ne connais pas grand chose en Regex.
J'ai cette pattern ((\d{2} ){4})\d{2} qui me permet de récupérer des n° de téléphone formattés dans une chaine et qui fonctionne bien. Potentiellement, elle me retourne 0 à 3 matches; je voudrais ne prendre que les 2 premiers matches. Est-ce possible directement dans la Regex ou dois-je le faire comme actuellement en traitant mon tableau de matches ?
Merci de votre aide.

[jurassic pork]

Hello,
peux-tu nous mettre ton code complet avec un exemple de données d'entrée et ce que tu veux en sortie (bien sûr pas avec de vrais numéros de téléphone).
Ami calmant, J.P

[mat955]

Bonjour,

Quand tu travailles avec les Regex, tu as la méthode Execute qui te renvoie une collection avec toutes les occurrences qui vérifient ton Pattern.
Il te suffit donc de prendre les 2 premiers éléments de la collection.

Si tu veux un peu de documentation, il existe ce tutoriel de Charles A. qui explique les bases des Regex en VBA, ça devrait t'aider

[JYL74]

Merci à tous les deux d'avoir regardé mon problème
@jurassic-pork
cas le plus complet, certaines fois je n'ai pas de n° , pas de texte, un seul n° etc.
chaine ="01 22 33 44 55 (standard)|06 45 45 45 45 (mobile)|01 22 33 44 66 (maintenance)"
avec la regex "((\d{2} ){4})\d{2}" me ramène bien les 3 n°, ce que je voudrais, c'est limiter le nombre de résultats à 2 maximum (les 2 premiers)
@mat955
C'est ce que je fais, dans le tableau vba qui collecte les matches, je ne prends que les 2 premiers et ça marche, je voudrais juste savoir si c'était réalisable directement dans la regex

[jurassic pork]

Comme tu peux avoir de 0 à 3 correspondances ça va être difficile de faire une expression régulière qui s'adapte à tous les cas. Qu'est-ce qui ne te plaît pas de le faire dans le traitement des résultats ? et tu ne nous as toujours pas montré ton code complet

[mat955]

Je rejoins jurassic pork, les Regex ne sont faites que pour vérifier qu'une chaîne de caractère vérifie un pattern.
Le plus simple est ensuite d'utiliser la collection pour ne garder que les 2 premiers résultats.

[JYL74]

Merci de vos réponses.
Rien ne me déplait dans le traitement des résultats pour limiter le nombre de retour à 2, c'est ce que je fais et ça marche bien.
Comme je ne maitrise pas les regex c'était juste pour savoir si c'était possible.

modèle code : https://www.ablebits.com/office-addi...strings-excel/
Ci dessous un extrait du code, modèle ci dessus, modifié, qui reçoit en paramètres
text : la chaine à scanner
pattern : le motif
instance_num : le n° de l'instance à retourner, 0 si toutes
occur_max : le nombre de matches à utiliser (dans l'exemple, 2)
concat_string : une chaine de concaténation pour joindre les résultats dans un chaine unique

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
    Set matches = regex.Execute(text)
    'si correspondance trouvée
    If matches.count > 0 Then
        'si on retient toutes les instances
        If (instance_num = 0) Then
            'si un nombre maxi d'occurrences est précisé, on prend la valeur minimum
            If occur_max <> 0 Then
                lLimite = IIf(matches.count < occur_max, matches.count, occur_max)
            'sinon on prend tous les résultats
            Else
                lLimite = matches.count
            'finsi un nombre maxi d'occurences est précisé
            End If
            'on dimensionne un tableau selon la taille limite 
            ReDim text_matches(lLimite - 1)
            'on remplit le tableau
            For matches_index = 0 To lLimite - 1
                text_matches(matches_index) = matches.Item(matches_index)
            Next matches_index
            'à la complétion du tableau, on concatène les postes, si nécessaire, on insère un séparateur
            If lLimite > 1 And concat_string <> "" Then
                RegExpExtract = Join(text_matches, concat_string)
            Else
                RegExpExtract = text_matches
            End If
        'sinon on retourne l'instance choisie
        Else
            RegExpExtract = matches.Item(instance_num - 1)
        'Finsi on retient toutes les instances
        End If
    'finsi correspondance trouvée
    End If

[omen999]

bonjour,

Comme je ne maitrise pas les regex c'était juste pour savoir si c'était possible.

oui
démonstration :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Dim res(1)
text="header : 01 22 33 44 55 (standard)|06 45 45 45 45 (mobile)|01 22 33 44 66 (maintenance)"
Set regex = CreateObject("VBScript.RegExp")
regex.pattern = "((\d{2} ){4})\d{2}"
regex.MultiLine = True
For n = 0 to 1
	Set matches = regex.Execute(text)
	res(n) = matches(0)
	text = Mid(text,matches(0).FirstIndex + matches(0).Length)
Next
MsgBox res(0) & " -- " & res(1)

par défaut, la propriété Global de l'objet RegExp est False, ce qui signifie que la fonction Execute ne renvoie que la première occurrence qui vérifie le pattern.
donc pour obtenir la deuxième occurrence, il suffit de reboucler en prenant soin d'appliquer la fonction Execute sur le texte raccourci (pour éviter de recapturer la première...)

ps : en complément du premier article donné en lien, en voici un autre pour approfondir le sujet et t'aider à t'endormir

[jurassic pork]

Hello,

oui
démonstration :

sauf que la solution proposée ne fonctionne pas si il n'y a pas ou seulement un n° de téléphone dans le texte.
Voici un code qui devrait fonctionner dans tous les cas :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub NumsTel()
Dim res(1)
Dim Text As String, i As Integer, j As Integer
Dim regex As Object, matches As Object
Dim Match
Text = "header : 01 22 33 44 55 (standard)|06 45 45 45 45 (mobile)|01 22 33 44 66 (maintenance)"
Set regex = CreateObject("VBScript.RegExp")
regex.Pattern = "((\d{2} ){4})\d{2}"
regex.Global = True
Set matches = regex.Execute(Text)
res(0) = "": res(1) = ""
If matches.Count > 2 Then j = 1 Else j = matches.Count - 1
For i = 0 To j
  res(i) = matches(i)
Next
Debug.Print res(0), res(1) 'res(0) = N° standard si disponible, res(1) = N° mobile si disponible
Set matches = Nothing
Set regex = Nothing
End Sub

Ami calmant, J.P

[JYL74]

Merci à tous.
Le sujet est résolu en ce qui me concerne.
Je retiens que les regex ne permettent pas nativement de limiter le nombre maximum de réponses souhaité et qu'il convient de le faire dans le code encapsulant regex.

[Promethee25]

Bonjour,

Je dirais que c'est possible en te débrouillant pour que l'expression régulière récupère à la fois le 1er résultat et le 2nd résultat (si ce dernier existe) et en conservant reg.Global à False et reg.Multiline à False aussi (j'ai supposé que tes numéros pouvaient apparaître sur des lignes différentes):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

^[\s\S]*?((?:\d{2} ){4}\d{2})(?:\D[\s\S]*?((?:\d{2} ){4}\d{2}))?

PS: J'ai modifié un peu tes parenthèses pour qu'elles capturent strictement les numéros de téléphone complet, ce qui me semble plus efficace.
Chaque SubMatch comprend un numéro de téléphone.