Discussion :

[khroujou]

Bonjour à tous,
J'ai deux feuilles avec :
Feuille1

Colonne A	colonne B
Lettre	cotation
a	1
à	1
b	2
c	3
ç	3
etc...

Je veux avoir en feuille 2, colonne b la cotation automatique des mots ou phrases saisis dans la colonne A selon la cotation des lettres dans la feuille1 :

Feuille2

Mot	cotation
bac	6
ça	4
Ca ba	7

J'espère que c'est clair.

Merci pour votre aide.

[78chris]

Bonjour

Avec le premier tableau sous forme de tableau structuré nommé Cotation et le second sous forme de tableau structuré nommé Textes

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((RECHERCHEV(STXT([@Texte];LIGNE(INDIRECT(1&":"&NBCAR([@Texte])));1);Cotation;2;0))*1)

[TOFatJOB]

bonjour,

sauf erreur, cette formule ne ramène que la valeur du premier caractère de la chaine. J'ai essayé en validation matricielle, même chose.

[Pierre Fauconnier]

Salut.

La formule de Chris fonctionne très bien. Tu dois avoir un problème de retranscription. Peux-tu donner celle que tu utilises?

[78chris]

Bonjour à tous

Fonctionne sur 365 mais effectivement pas sur 2010 et donc sans doute 2016

Code excel :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((SOMME.SI.ENS(Cotation[cotation];Cotation[Lettre];STXT([@Mot];LIGNE(INDIRECT(1&":"&NBCAR([@Mot])));1)))*1)

Je peux aussi fournir une solution POwerQuery

[Pierre Fauconnier]

Salut Chris,

Tu veux dire que la formule de ton premier message ne fonctionne pas en 2010?

Perso, j'ai déjà eu des soucis avec INDIRECT et RECHERCHEV en matricielle. J'aime encore bien DECALER, sur la même idée:

Code excel :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD(INDEX(Cotation[Cotation];EQUIV(STXT([@Texte];LIGNE(DECALER($A$1;0;0;NBCAR([@Texte])));1);Cotation[Lettre];0))*1)

[TOFatJOB]

re,

effectivement, seule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((SOMME.SI.ENS(Cotation[cotation];Cotation[Lettre];STXT([@Mot];LIGNE(INDIRECT(1&":"&NBCAR([@Mot])));1)))*1)

fonctionne sous XL-2016

[Pierre Dumas]

Bonsoir

Je confirme que la première formule de 78chris ainsi que celle de Pierre ne fonctionnent pas en 2019.
Seule la dernière de 78chris donne le bon résultat.

Belle fin de journée

Pierre Dumas

[78chris]

Bonjour à tous

Merci de vos essais

J'avais déjà remarqué que 365 fait du matriciel par défaut mais pas encore qu'il traite des cas différemment des versions antérieures

Cela va devenir compliqué les échanges de classeurs...

[Pierre Fauconnier]

J'ai eu un souci aussi avec des matricielles développées sur 365 repassées en 2013. J'ai dû passer par une fonction perso, mais comme le dit Chris, ça va être galère car ni la formule de Chris ni la mienne n'utilisaient des spécificités 365

Et en plus, SOMMEPROD n'est même pas une matricielle, en ce sens qu'elle n'est pas validée en matricielle.

[TonyNiort79]

Bonjour à tous,
la demande pour moi était très compliquée voire impossible à réaliser quand j'ai lu cette discussion,
Puis, une réponse, si rapide ? non, pas possible,

j'avais tenté l'expérience pour commencer à me familiariser avec les tableaux structurés et voir ce que cela donnait,
et comme l'a signalé TOFatJOB cela ne fonctionnait pas (j'ai aussi la version 2010),
mais n'y connaissant rien, je pensais m'être trompé dans la construction du tableau pourtant bien expliqué par Pierre ici,
puis j'ai repris le post 6 de Chris et,
Chapeau, c'est vraiment réalisable avec une seule ligne.

[khroujou]

Merci à tous pour vos réponses et à 78chris pour la solution qui marche à merveille.