IdentifiantMot de passe
Loading...
Mot de passe oublié ?Je m'inscris ! (gratuit)
Navigation

Inscrivez-vous gratuitement
pour pouvoir participer, suivre les réponses en temps réel, voter pour les messages, poser vos propres questions et recevoir la newsletter

  1. #1
    Membre régulier Avatar de goninph
    Homme Profil pro
    Inscrit en
    octobre 2013
    Messages
    438
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : Suisse

    Informations forums :
    Inscription : octobre 2013
    Messages : 438
    Points : 124
    Points
    124
    Par défaut Créer un rendez-vous OUTLOOK dans un agenda autre que le miens
    Bonjour

    Est-il possible de créer un rendez-vous dans un autre agenda que le mien.

    Ci-dessous une macro qui créer un rendez-vous dans mon agenda, j'aimerai faire la même chose dans l'agenda "Transport"

    Merci pour votre aide
    Philippe

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    Sub Agenda_RDVC()
    Dim Destinataire_A As Variant
    Dim Destinataire_CC As Variant
    Dim Objet_mail As Variant
    Dim messagerie As Object
    Dim Email As Object
    Dim Message As Variant
        Destinataire_A = f.Cells(Ligne_Data_LOOK, 18)
        Destinataire_CC = ""
        'Objet du mail
        Objet_mail = "RDVC avec " & f.Cells(Ligne_Data_LOOK, 13) & " " & f.Cells(Ligne_Data_LOOK, 14) & " " & f.Cells(Ligne_Data_LOOK, 15) & " - " & f.Cells(Ligne_Data_LOOK, 12)
        If MsgBox("Créer un rendez-vous dans mon agenda ?", vbYesNo + vbQuestion, "Rendez-vous") = vbYes Then
            'Corps du mail
            Message = f.Cells(Ligne_Data_LOOK, 5) & "." & f.Cells(Ligne_Data_LOOK, 6) & " - " & f.Cells(Ligne_Data_LOOK, 8)
            'Création du mail avec Outlook
            Set messagerie = CreateObject("Outlook.Application")
            Set Email = messagerie.CreateItem(1) '0=Mail, 1=RDV, 2=Contact, 3=Tache, 6=Objet outlook
            With Email
                .MeetingStatus = olMeeting
                .Subject = Objet_mail
                .body = Message 'Note du rendez-vous
                .RequiredAttendees = Destinataire_A ' participants obligatoires à la réunion
                .OptionalAttendees = Destinataire_CC 'participants optionnels à la réunion
                .Categories = ""
                .ReminderSet = True 'Activer le rappel
                .ReminderMinutesBeforeStart = 60 'Durée du rappel en minutes
                .Start = Now
                .Duration = 60
                .Location = f.Cells(Ligne_Data_LOOK, 9) & " " & f.Cells(Ligne_Data_LOOK, 10) & " " & f.Cells(Ligne_Data_LOOK, 11)
                .Display 'Ouvre l'invitation avant de l'envoyer
            End With
            Call SetInterligne(Email) 'Appel la fonction qui évite le double retour à la ligne lors de l'appui sur la touche ENTER
            Set Email = Nothing
            Set messagerie = Nothing
            Unload USF_Details_Commande
            Unload Me
        End If
    End Sub

  2. #2
    Expert éminent
    Avatar de Oliv-
    Homme Profil pro
    solution provider
    Inscrit en
    mars 2006
    Messages
    4 081
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 50
    Localisation : France, Nord (Nord Pas de Calais)

    Informations professionnelles :
    Activité : solution provider

    Informations forums :
    Inscription : mars 2006
    Messages : 4 081
    Points : 7 033
    Points
    7 033
    Billets dans le blog
    20
    Par défaut
    Bonsoir,
    Voici un exemple, Lors'il s'agit du calendrier par défaut de la BAL visée.
    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
     
    Sub Creation_rdv_autre_calendrier()
        Dim myNameSpace As Outlook.NameSpace
        Dim myRecipient As Outlook.Recipient
        Dim CalendarFolder As Outlook.Folder
     
        Set myNameSpace = Application.GetNamespace("MAPI")
        Set myRecipient = myNameSpace.CreateRecipient("BAL_DU_CALDENDRIER")
        myRecipient.Resolve
        If myRecipient.Resolved Then
     
            Set CalendarFolder = _
            myNameSpace.GetSharedDefaultFolder _
                                 (myRecipient, olFolderCalendar)
     
            Dim myItem As Object
            Dim myRequiredAttendee, myOptionalAttendee, myResourceAttendee As Outlook.Recipient
     
            Set myItem = CalendarFolder.Items.add
            myItem.MeetingStatus = olNonMeeting
            myItem.Subject = "Strategy Meeting"
            myItem.Location = "Conf Rm All Stars"
            myItem.Start = #6/15/2018 1:30:00 PM#
            myItem.Duration = 90
     
            'pour l'afficher
            'myItem.Display
            myItem.Save
     
        Else
            MsgBox "erreur"
        End If
    End Sub

  3. #3
    Membre régulier Avatar de goninph
    Homme Profil pro
    Inscrit en
    octobre 2013
    Messages
    438
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : Suisse

    Informations forums :
    Inscription : octobre 2013
    Messages : 438
    Points : 124
    Points
    124
    Par défaut
    Bonjour Oliv,

    A quoi peut ressembler myNameSpace.CreateRecipient("BAL_DU_CALDENDRIER")

    Merci

  4. #4
    Membre régulier Avatar de goninph
    Homme Profil pro
    Inscrit en
    octobre 2013
    Messages
    438
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : Suisse

    Informations forums :
    Inscription : octobre 2013
    Messages : 438
    Points : 124
    Points
    124
    Par défaut
    Bonsoir,

    Pour créer un rendez-vous dans mon agenda, j'utilise cette macro.

    Comment l'adapter pour quelle ajoute un rendez-vous dans un autre agenda que le mien ?

    Merci A+
    Philippe


    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    39
    Sub Agenda_RDVC()
    Dim Destinataire_A As Variant
    Dim Destinataire_CC As Variant
    Dim Objet_mail As Variant
    Dim messagerie As Object
    Dim Email As Object
    Dim Message As Variant
        Destinataire_A = f.Cells(Ligne_Data_LOOK, 18)
        Destinataire_CC = ""
        'Objet du mail
        Objet_mail = "RDVC avec " & f.Cells(Ligne_Data_LOOK, 13) & " " & f.Cells(Ligne_Data_LOOK, 14) & " " & f.Cells(Ligne_Data_LOOK, 15) & " - " & f.Cells(Ligne_Data_LOOK, 12)
        If MsgBox("Créer un rendez-vous dans mon agenda ?", vbYesNo + vbQuestion, "Rendez-vous") = vbYes Then
            'Corps du mail
            Message = f.Cells(Ligne_Data_LOOK, 5) & "." & f.Cells(Ligne_Data_LOOK, 6) & " - " & f.Cells(Ligne_Data_LOOK, 8)
            'Création du mail avec Outlook
            Set messagerie = CreateObject("Outlook.Application")
            Set Email = messagerie.CreateItem(1) '0=Mail, 1=RDV, 2=Contact, 3=Tache, 6=Objet outlook
            With Email
    '            .MeetingStatus = olMeeting
                .Subject = Objet_mail
                .body = Message 'Note du rendez-vous
                .RequiredAttendees = Destinataire_A ' participants obligatoires à la réunion
                .OptionalAttendees = Destinataire_CC 'participants optionnels à la réunion
                .Categories = ""
                .ReminderSet = True 'Activer le rappel
                .ReminderMinutesBeforeStart = 60 'Durée du rappel en minutes
                .Start = Now
                .Duration = 60
                .Location = f.Cells(Ligne_Data_LOOK, 9) & " " & f.Cells(Ligne_Data_LOOK, 10) & " " & f.Cells(Ligne_Data_LOOK, 11)
    '            .Attachments.Add (Srep & Nom_du_PDF_Partenaires)
                .display 'Ouvre l'invitation avant de l'envoyer
            End With
            Call SetInterligne(Email) 'Appel la fonction qui évite le double retour à la ligne lors de l'appui sur la touche ENTER
            Set Email = Nothing
            Set messagerie = Nothing
            Unload USF_Details_Commande
            Unload Me
        End If
    End Sub

  5. #5
    Membre régulier Avatar de goninph
    Homme Profil pro
    Inscrit en
    octobre 2013
    Messages
    438
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : Suisse

    Informations forums :
    Inscription : octobre 2013
    Messages : 438
    Points : 124
    Points
    124
    Par défaut
    Bonjour,

    Voilà, ça fonctionne nickel

    J'ai saisis l'adresse mail complète du calendrier, car je n'ai pas tout compris comment s'effectuait la sélection du bon calendrier.
    Dans mon exemple le calendrier s'appel Camion grue, si je saisis cam ou camio ou grue, la macro trouve l'agenda, mais je n'ai pas d'autre agenda ayant la même série de caractères, ce qui pourrait être problématique, je suppose ....

    Si vous avez des infos merci d'avance.

    Bonne fêtes
    Philippe

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    39
    40
    41
    42
    43
    44
    45
    46
    47
    48
    49
    50
    51
    52
    53
    54
    55
    56
    57
    58
    59
    60
    61
    62
    63
    64
    Sub Ordre_Transport_Camion()
    Dim objApp As Outlook.Application
    Dim objNS As Outlook.Namespace
    Dim objFolder As Outlook.MAPIFolder
    Dim objDummy As Outlook.MailItem
    Dim objRecip As Outlook.Recipient
    Dim Email As Outlook.AppointmentItem
    Dim strMsg As String
    Dim strName As String
    Dim Destinataire_A As Variant
    Dim Destinataire_CC As Variant
    Dim Objet_mail As Variant
    Dim Message As Variant
    On Error Resume Next
        If MsgBox("Créer un ordre de transport pour Alvaro ?", vbYesNo + vbQuestion, "Rendez-vous") = vbYes Then
            Destinataire_A = ""
            Destinataire_CC = ""
            'Objet du mail
            Objet_mail = "Livraison et grutage pour " & Application.UserName
            'Corps du mail
            Message = USF_Details_Commande.TextBox_Adresse_client & vbLf & vbLf & vbLf & "Meilleures salutations" & vbLf & Application.UserName
            'Adresse mail du calendrier
            strName = "camion.grue@zurbuchensa.ch"
            'Création du rendez-vous
            Set objApp = CreateObject("Outlook.Application")
            Set objNS = objApp.GetNamespace("MAPI")
            Set objDummy = objApp.CreateItem(olMailItem)
            Set objRecip = objDummy.Recipients.Add(strName)
            objRecip.Resolve
            If objRecip.Resolved Then
                On Error Resume Next
                Set objFolder = objNS.GetSharedDefaultFolder(objRecip, olFolderCalendar)
                If Not objFolder Is Nothing Then
                    Set Email = objFolder.Items.Add
                    If Not Email Is Nothing Then
                        With Email
                            .Subject = Objet_mail
                            .Body = Message
                            .RequiredAttendees = Destinataire_A ' participants obligatoires à la réunion
                            .OptionalAttendees = Destinataire_CC 'participants optionnels à la réunion
                            .Categories = ""
                            .ReminderSet = True 'Activer le rappel
                            .ReminderMinutesBeforeStart = 60 'Durée du rappel en minutes
                            .Start = DateValue(Date) & " " & TimeValue("8:00:00")
                            .Duration = 120
                            .Location = f.Cells(Ligne_Data_LOOK, 9) & " " & f.Cells(Ligne_Data_LOOK, 10) & " " & f.Cells(Ligne_Data_LOOK, 11)
                            .Display 'Ouvre l'invitation avant de l'envoyer
                        End With
                        Call SetInterligne(Email) 'Appel la fonction qui évite le double retour à la ligne lors de l'appui sur la touche ENTER
                        Unload USF_Details_Commande
                        Unload Me
                    End If
                End If
            Else
                MsgBox "N'a pas trouvé l'agenda " & vbCrLf & vbCrLf & strName, vbExclamation, "! Oups ! Action interrompue"
            End If
        End If
        Set objApp = Nothing
        Set objNS = Nothing
        Set objFolder = Nothing
        Set objDummy = Nothing
        Set objRecip = Nothing
        Set Email = Nothing
    End Sub

  6. #6
    Membre régulier Avatar de goninph
    Homme Profil pro
    Inscrit en
    octobre 2013
    Messages
    438
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : Suisse

    Informations forums :
    Inscription : octobre 2013
    Messages : 438
    Points : 124
    Points
    124
    Par défaut
    Bonjour,

    J'ai un gros problème

    Sur mon PC MSO365 64bits tout fonctionne à merveille, mais mes collègues avec Office2013 n'ont pas la même librairie d'objet pour Outlook.

    J'ai Microsoft 16.0 Object Library

    Mes collègues ont Microsoft 15.0 Object Library

    Comment faire pour que la macro fonctionne sur tous les PC

    Est-il possible de se passer de cette library ? En parcourant le forum j'ai lu que l'on pouvait utiliser LATE BINDING, mais cela résoudrait-il mon problème ?

    Merci pour votre aide et joyeux noël

    Philippe

  7. #7
    Membre régulier Avatar de goninph
    Homme Profil pro
    Inscrit en
    octobre 2013
    Messages
    438
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : Suisse

    Informations forums :
    Inscription : octobre 2013
    Messages : 438
    Points : 124
    Points
    124
    Par défaut
    YES, YES et re-YES, j'ai résolu mon problème et ça fonctionne nickel, OUF !

    J'ai corrigé la macro pour ne plus avoir besoin de la library Outlook

    Si l'un d'entre vous pourrait vérifier ...

    Joyeux noël

    Merci et meilleures salutations
    Philippe

    Note : quelle vacherie ces librairies, j'avais déjà eu un problème similaire dans le passé avec "Calendar" qui n'existe plus sur MSO365, mais que j'avais également pu contourner après des heures de recherche

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    39
    40
    41
    42
    43
    44
    45
    46
    47
    48
    49
    50
    51
    52
    53
    54
    55
    56
    Sub Ordre_Transport_Camion()
    Dim Email As Object
    Dim objNS As Object
    Dim Messagerie As Object
    Dim objRecip As Object
    Dim objDummy As Object
    Dim objFolder As Object
    Dim Nom_Calendrier As String
    Dim Objet_mail As Variant
    Dim Message As Variant
        If MsgBox("Créer un ordre de transport pour Alvaro ?", vbYesNo + vbQuestion, "Rendez-vous") = vbYes Then
            Nom_Calendrier = "camion.grue@zurbuchensa.ch"
            Set Messagerie = CreateObject("Outlook.Application")
            Set objNS = Messagerie.GetNamespace("MAPI")
            Set objDummy = Messagerie.CreateItem(1)
            On Error Resume Next 'permet de passer à la ligne suivante pour traiter l'erreur si le calendrier n'est pas trouvé
            Set objRecip = objDummy.Recipients.Add(Nom_Calendrier)
            objRecip.Resolve
            If objRecip.Resolved Then
                Set objFolder = objNS.GetSharedDefaultFolder(objRecip, 9) '9 = valeur du dossier calendrier
                Set Email = objFolder.Items.Add
                'Si le calendrier et trouvé mais en lecture seule (pas de modification possible)
                If Not Email Is Nothing Then
                    objFolder.display 'Ouvre le calendrier partagé qui s'affichera une fois le rendez-vous enregistré
                    'Objet du mail
                    Objet_mail = "Livraison et grutage pour " & Application.UserName
                    'Corps du mail
                    Message = "Poseur : " & vbLf & vbLf & vbLf & USF_Details_Commande.TextBox_Adresse_client & vbLf & vbLf & vbLf & "Meilleures salutations" & vbLf & Application.UserName
                    'Création du rendez-vous
                    With Email
                        .Subject = Objet_mail
                        .Body = Message
                        .RequiredAttendees = "" ' participants obligatoires à la réunion
                        .OptionalAttendees = "" 'participants optionnels à la réunion
                        .Categories = ""
                        .ReminderSet = True 'Activer le rappel
                        .ReminderMinutesBeforeStart = 60 'Durée du rappel en minutes
                        .Start = DateValue(Date + 1) & " " & TimeValue("8:00:00")
                        .Duration = 120
                        .Location = f.Cells(Ligne_Data_LOOK, 9) & " " & f.Cells(Ligne_Data_LOOK, 10) & " " & f.Cells(Ligne_Data_LOOK, 11)
                        .display 'Afficher le rendez-vous pour modification
                    End With
                Else
                    MsgBox "L'agenda : " & Nom_Calendrier & vbCrLf & vbCrLf & " n'est pas accessible pour la modification.", vbExclamation, "! Oups ! Action interrompue"
                End If
            Else
                MsgBox "L'agenda : " & Nom_Calendrier & vbCrLf & vbCrLf & " n'existe pas.", vbExclamation, "! Oups ! Action interrompue"
            End If
        End If
        Set Email = Nothing
        Set objNS = Nothing
        Set Messagerie = Nothing
        Set objRecip = Nothing
        Set objDummy = Nothing
        Set objFolder = Nothing
    End Sub

  8. #8
    Expert éminent
    Avatar de Oliv-
    Homme Profil pro
    solution provider
    Inscrit en
    mars 2006
    Messages
    4 081
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 50
    Localisation : France, Nord (Nord Pas de Calais)

    Informations professionnelles :
    Activité : solution provider

    Informations forums :
    Inscription : mars 2006
    Messages : 4 081
    Points : 7 033
    Points
    7 033
    Billets dans le blog
    20
    Par défaut
    Sallut

    comme cela

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    39
    40
    41
    42
    43
    44
    45
    46
    47
    48
    49
    50
    51
    52
    53
    54
    55
    56
    57
    58
    59
    60
    61
    62
    Sub Ordre_Transport_Camion()
        Dim Email As Object
        Dim objNS As Object
        Dim Messagerie As Object
        Dim objRecip As Object
        Dim objDummy As Object
        Dim objFolder As Object
        Dim Nom_Calendrier As String
        Dim Objet_mail As Variant
        Dim Message As Variant
        If MsgBox("Créer un ordre de transport pour Alvaro ?", vbYesNo + vbQuestion, "Rendez-vous") = vbYes Then
            Nom_Calendrier = "camion.grue@zurbuchensa.ch"
            Set Messagerie = CreateObject("Outlook.Application")
            Set objNS = Messagerie.GetNamespace("MAPI")
     
     
            'Set objDummy = Messagerie.CreateItem(1)
            'On Error Resume Next    'permet de passer à la ligne suivante pour traiter l'erreur si le calendrier n'est pas trouvé
            'Set objRecip = objDummy.Recipients.Add(Nom_Calendrier)
     
            On Error Resume Next    'permet de passer à la ligne suivante pour traiter l'erreur si le calendrier n'est pas trouvé
            Set objRecip = objNS.CreateRecipient(Nom_Calendrier)
     
            objRecip.Resolve
            If objRecip.Resolved Then
                Set objFolder = objNS.GetSharedDefaultFolder(objRecip, 9)    '9 = valeur du dossier calendrier
                Set Email = objFolder.Items.Add
                'Si le calendrier et trouvé mais en lecture seule (pas de modification possible)
                If Not Email Is Nothing Then
                    objFolder.display    'Ouvre le calendrier partagé qui s'affichera une fois le rendez-vous enregistré
                    'Objet du mail
                    Objet_mail = "Livraison et grutage pour " & Application.UserName
                    'Corps du mail
                    Message = "Poseur : " & vbLf & vbLf & vbLf & USF_Details_Commande.TextBox_Adresse_client & vbLf & vbLf & vbLf & "Meilleures salutations" & vbLf & Application.UserName
                    'Création du rendez-vous
                    With Email
                        .Subject = Objet_mail
                        .Body = Message
                        .RequiredAttendees = ""    ' participants obligatoires à la réunion
                        .OptionalAttendees = ""    'participants optionnels à la réunion
                        .Categories = ""
                        .ReminderSet = True    'Activer le rappel
                        .ReminderMinutesBeforeStart = 60    'Durée du rappel en minutes
                        .Start = DateValue(Date + 1) & " " & TimeValue("8:00:00")
                        .Duration = 120
                        .Location = f.Cells(Ligne_Data_LOOK, 9) & " " & f.Cells(Ligne_Data_LOOK, 10) & " " & f.Cells(Ligne_Data_LOOK, 11)
                        .display    'Afficher le rendez-vous pour modification
                    End With
                Else
                    MsgBox "L'agenda : " & Nom_Calendrier & vbCrLf & vbCrLf & " n'est pas accessible pour la modification.", vbExclamation, "! Oups ! Action interrompue"
                End If
            Else
                MsgBox "L'agenda : " & Nom_Calendrier & vbCrLf & vbCrLf & " n'existe pas.", vbExclamation, "! Oups ! Action interrompue"
            End If
        End If
        Set Email = Nothing
        Set objNS = Nothing
        Set Messagerie = Nothing
        Set objRecip = Nothing
        Set objDummy = Nothing
        Set objFolder = Nothing
    End Sub

  9. #9
    Membre régulier Avatar de goninph
    Homme Profil pro
    Inscrit en
    octobre 2013
    Messages
    438
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : Suisse

    Informations forums :
    Inscription : octobre 2013
    Messages : 438
    Points : 124
    Points
    124
    Par défaut
    Merci Oliv,

    J'ai une question, pourquoi la macro créée des calendriers partagés alors qu'ils sont déjà existants dans mes calendriers ?

    Merci et bonne journée
    Philippe

    Nom : 2020-12-29_11-28-33.png
Affichages : 16
Taille : 33,1 Ko

+ Répondre à la discussion
Cette discussion est résolue.

Discussions similaires

  1. [AC-2010] Créer un rendez-vous Outlook depuis access
    Par bvalenza dans le forum Access
    Réponses: 3
    Dernier message: 18/12/2017, 11h53
  2. [XL-2016] Creer un rendez vous outlook dans un calendrier partagé
    Par psychoblade dans le forum Excel
    Réponses: 0
    Dernier message: 29/01/2017, 09h14
  3. Import de rendez-vous Outlook dans Access
    Par pascal@falcy.ch dans le forum VBA Access
    Réponses: 17
    Dernier message: 30/01/2015, 10h21
  4. Réponses: 0
    Dernier message: 29/12/2011, 09h53
  5. lier rendez vous outlook dans formulaire access
    Par TAUPE007 dans le forum Access
    Réponses: 0
    Dernier message: 11/05/2008, 13h56

Partager

Partager
  • Envoyer la discussion sur Viadeo
  • Envoyer la discussion sur Twitter
  • Envoyer la discussion sur Google
  • Envoyer la discussion sur Facebook
  • Envoyer la discussion sur Digg
  • Envoyer la discussion sur Delicious
  • Envoyer la discussion sur MySpace
  • Envoyer la discussion sur Yahoo