Discussion :

[boudoula]

Bonjour à tous,

j'essaie d 'ouvrir un fichier XLSM via une macro sous VBA.
Mon problème est que lorsque le fichier s'ouvre la macro veux lancer la macro du fichier ouvert alors que ce n'est pas mon souhait ( la macro ne se trouve pas dans workbooks open mais dans un module VBA)
et j'ai ce souci avec les 2 commandes suivantes:

• Workbooks.Open Filename:= x
• Set test = Application.Workbooks.Open(X)

merci d'avance pour vos conseils

cordialement

[Guy7700]

Bonjour,

J'ai trouvé ce bout de code sur le net :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub ouvrir_sans_macro()
Application.EnableEvents = False
Workbooks.Open "Répertoire\Nom du fichier"
Application.EnableEvents = True
End Sub

Je ne l'ai pas testé, j'espère que ça fera ce que tu recherches. Tiens-nous au courant.

Bien cordialement,

[boudoula]

merci pour l'aide mais ça ne fonctionne pas j'ai toujours la macro sur le fichier à ouvrir qui se lance

autant pour moi ça ne fonctionne pas en pas à pas mais ça fonctionne lorsque je lance la macro en autonome.

merci beaucoup

[Patrice740]

Bonjour,

Comme ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Dim mas As MsoAutomationSecurity
 
  mas = Application.AutomationSecurity
  Application.AutomationSecurity = msoAutomationSecurityForceDisable
  Set wbk = Workbooks.Open(nom)
  Application.AutomationSecurity = mas

[Pierre Fauconnier]

Salut.

Perso, j'ajouterais une gestion d'erreur aux codes proposés pour éviter les problèmes si l'ouverture se passe mal. Je préfère le code de Patrice car avec le Application.EnableEvents = True en fin de parcours, on remet peut-être une propriété à True au mauvais moment.

• Un code ne devrait jamais modifier durablement une propriété d'application s'il n'est pas explicitement prévu pour.
• Il faut toujours prévoir une gestion d'erreur lorsque l'on modifie les propriétés de l'application pour être certain de sortir proprement en remettant tout en ordre avant.
• Il faut toujours prévoir une gestion d'erreur lorsque l'on manipule des fichiers, notamment lorsque l'on essaie d'ouvrir un classeur.

Sur le modèle du code de Patrice, on pourrait passer par un On Error Goto Catch à la place du Resume Next en fonction de l'architecture du code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub TestOpen()
  Dim mas As MsoAutomationSecurity
 
  On Error Resume Next
  mas = Application.AutomationSecurity
  Application.AutomationSecurity = msoAutomationSecurityForceDisable
  Set wbk = Workbooks.Open(nom)
  If Err = 0 Then
    '...
    '...
  End If
  Application.AutomationSecurity = mas
End Sub

Perso, j'aime bien une fonction qui renvoie le workbook et qui encapsule ces notions. De cette manière, on utilise du code que l'on peut tester isolément du reste. [Edit] Merci Patrice pour la correction de la coquille

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Function GetWorkbook(Filename, Optional ActivateWb As Boolean, Optional DisableEvents As Boolean) As Workbook
  Dim AppEnableEvents As Boolean
  Dim wb As Workbook
 
  Set wb = ActiveWorkbook
  On Error GoTo Catch
  AppEnableEvents = Application.EnableEvents
  Application.EnableEvents = Not DisableEvents
  Set GetWorkbook = Workbooks.Open(Filename)
  If Not ActivateWb Then wb.Activate
 
Catch:
  Set wb = Nothing
  Application.EnableEvents = AppEnableEvents
End Function
 
Sub TestOpen()
  Dim wb As Workbook
 
  Set wb = GetWorkbook("c:\data\temp\testopen.xlsm", True)
  If Not wb Is Nothing Then
    MsgBox "Fichier ouvert"
  Else
    MsgBox "Problème à l'ouverture"
  End If
End Sub