Discussion :

[alexhsh]

Bonjour,
Pour des raisons pratiques, je souhaiterai convertir un grand nombre de fichiers msg en html, on parle de 5000 elements tout de même
Ces mails donc au formats msg se trouve dans un répertoire TEST MAIL
D'où le code VBA suivant que j'exécute depuis Outlook,
Le problème survient à la ligne Set Cemail = ActiveInspector.CurrentItem

J'aimerai aussi fermer le mail ouvert avant de passer au suivant sinon ma RAM risque de ne pas apprécier !
est ce que quelqu'un aurait une idée ? ou même une autre suggestion comme une impression en pdf par exemple?
Merci d'avance à tous et bonne journée

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Private Sub ConvertMsgToHTML()
Dim Fich As String, Texte As String
Dim MonApplication As Object
Dim Cemail As Outlook.MailItem
 
 
Const Chemin = "C:\TEST MAIL\"    'on indique le répertoire où se trouve les mails à convertir
Fich = Dir(Chemin & "*.msg")            'on détermine les fichiers à trouver
 
Do While Fich <> ""                     'on boucle
 
    Set MonApplication = CreateObject("Shell.Application")
    MonApplication.Open (Chemin & Fich) ' on ouvre le fichier msg
 
    Texte = Fich 'on récupere le nom de fichier pour s'en servir lors du process d'enregistrement
 
    Set Cemail = ActiveInspector.CurrentItem 'on alimente la variable ce mail avec le mail précédemment ouvert
    Cemail.SaveAs "C:TEST MAIL\" & Texte & ".html", OlSaveAsType.olHTML 'on l'enregistre au format html dans le répertoire d'origine
 
    'puis on ferme et on passe au suivant
    'ici je n'ai aucune idée du code qui permettrait la fermeture du mail juste ouvert
 
    Fich = Dir
Loop 'on passe au fichier suivant
 
End Sub

[EricDgn]

Bonjour,

Il faudrait sans doute initialiser l'Inspector:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
    Dim myinspector As Outlook.Inspector 
    Set myinspector = Application.ActiveInspector
    ...
    Set Cemail = myinspector.CurrentItem
    Cemail.SaveAs chemin & Texte & ".html", OlSaveAsType.olHTML
    Cemail.Close olDiscard
    ...

Cordialement.

[alexhsh]

Bonjour EricDgn et merci de ton intervention,
ça m'a aiguillé sur d'autres discussions, j'ai continué à creuser et je suis tombé sur une ligne de code qui m'a permis de réaliser ce que je cherchai sur mes 5000 mails,
A toute fin utile et afin d'aider la communauté, je laisse à dispo le code ci-dessous, à noter que le code ne tient pas compte ici des pièces jointes.
Merci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Private Sub ConvertMsgToHTML()
   Dim Chemin As String, Fich As String
    Dim objOL As Object
 
    Set objOL = CreateObject("Outlook.Application")
    Dim Msg As Object
 
    'Définit le répertoire contenant les fichiers
    Chemin = "C:\TEST MAIL\"
 
    'Boucle sur tous les fichiers xls du répertoire.
    Fich = Dir(Chemin & "*.msg")
 
    Do While Len(Fich) > 0 'on boucle sur les fichiers
 
        Set Msg = objOL.Session.OpenSharedItem(Chemin & "\" & Fich) 'on initialise notre objet(mail) avec la fonction OpenSharedItem
        ' on peut maintenant utiliser les éléments de l'email msg
        Msg.SaveAs "C:\TEST MAIL\" & Fich & ".html", OlSaveAsType.olHTML 'on l'enregistre au format html dans le répertoire d'origine
 
        Set Msg = Nothing 'on remet à 0 notre objet
 
        'lors du processus de conversion du msg en html, un répertoire est créé, ici on le vide et on le supprime
        Kill ("C:\TEST MAIL\" & Fich & "_fichiers\*.*")
 
        RmDir "C:\TEST MAIL\" & Fich & "_fichiers"
 
        Fich = Dir() 'msg suivant
    Loop
 
End Sub