Discussion :

[DéesseClem]

Bonjour,

Je voudrais créer un tableau avec l'année en cours, allant de la date du jour à 1 an auparavant. Du coup j'ai fait ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub AnneeEnCours()
 
    Dim F As Worksheet
    Set F = Worksheets("AnneeEnCours")
 
    Dim lig As Integer
    Dim nbJour As Integer
    Dim dateJour As Date
 
    nbJour = 365
    dateJour = Now()
 
    F.Cells(2, 1) = dateJour
 
    For lig = 3 To nbJour
        F.Cells(lig, 1) = dateJour - lig + 2
    Next   
End Sub

Ca marche mais comment faire pour récupérer l'année en cours + tous les jours du premier mois.
Exemple nous sommes le 26 novembre 2020, si j'exécute mon code, j'aurais du 26/11/2019 au 26/11/2020
Je voudrais avoir du 01/11/2019 au 26/11/2020

J'espère que c'est assez claire, sinon n'hésitez pas à me poser des questions.

Clémence

[Philippe Tulliez]

Bonjour,
Voici un code qui génère une suite de date commençant le 1er jour du même mois qu'aujourd'hui de l'année dernière, jusqu'à ce jour
La cellule de départ est la cellule B1 de la feuille nommée Feuil1 du classeur où se trouve le code VBA et l'écriture se fait en colonne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub T()
  Dim StartRange As Range
  Set StartRange = ThisWorkbook.Worksheets("Feuil1").Range("B1")
  With StartRange
  .Value = DateSerial(Year(Date) - 1, Month(Date), 1)
  .DataSeries Rowcol:=xlColumns, Type:=xlChronological, Date:=xlDay, Step:=1, Stop:=DateSerial(Year(Date), Month(Date), Day(Date))
  End With
  Set StartRange = Nothing
End Sub

[BENNASR]

bonjour à tous
bonjour Philippe Tulliez : (+1) de ma part, seulement je crois que la demandeur cherches un ordre décroissant...si tu permets peut on ajouter l'ordre dans ton code?

version bricoleur et débutant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub AnneeEnCours()
    Dim F As Worksheet
    Set F = Worksheets("AnneeEnCours")
    Dim lig As Integer
    Dim nbJour As Integer
    Dim dateJour As Date
    dateJour = Date
    mois = Month(Date)
    année = Year(Date) - 1
    date_mois_année_ancienne = DateSerial(année, mois, 1)
    nb_jours = dateJour - date_mois_année_ancienne
    F.Cells(2, 1) = dateJour
    For lig = 3 To nb_jours + 2
        F.Cells(lig, 1) = F.Cells(lig - 1, 1) - 1
    Next
End Sub

[BENNASR]

j'ai trouvé philippe
j'enregistre cette procédure que je ne connais pas ...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub T()
  Dim StartRange As Range
  Set StartRange = ThisWorkbook.Worksheets("AnneeEnCours").Range("B2")
  With StartRange
  .Value = Date
  .DataSeries Rowcol:=xlColumns, Type:=xlChronological, Date:=xlDay, Step:=-1, Stop:=DateSerial(Year(Date) - 1, Month(Date), 1)
  End With
  Set StartRange = Nothing
End Sub

[Philippe Tulliez]

Bonjour Bennasr,
Merci pour ton appréciation

seulement je crois que la demandeur cherches un ordre décroissant...si tu permets peut on ajouter l'ordre dans ton code?

Si je lis bien la demande c'est "Je voudrais avoir du 01/11/2019 au 26/11/2020" et c'est ce que fait la procédure que j'ai proposée et qui est basée sur une fonctionnalité native d'excel qui est la recopie en série
Si maintenant, il faut partir du 26/11/2020 vers le 1/11/2019, il suffit d'inverser les données de la cellule de départ avec l'argument Stop et remplacer la valeur constante 1 de l'argument Step par -1

[DéesseClem]

Merci beaucoup ! Ca marche parfaitement, après niveau ordre au final c'est pas très important je peux toujours le trier avec le tableau.