Discussion :

[Pat973-13]

Bonjour,

Je souhaiterais faire une boucle sur quelques TextBox_AfterUpdate()
Txt1_AfterUpdate(), Txt2_AfterUpdate(), Txt3_AfterUpdate()...etc...
Exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub txt1_AfterUpdate()
    If IsNumeric(Me.txt1.Value) Then
     Me.txt1.Value = Format(Me.txt1.Value, "# ##0.00 €")
    End If
End Sub

Je n'arrive pas à le faire en boucle, si quelqu'un pouvait me donner un exemple ou un lien.
Merci par avance.

[a_diard]

sauf erreur de ma part

le AfterUpdate se déclenche quand une donnée est modifié dans le textbox

Je ne pense pas que tu modifie plusieurs textbox en même temps

je ne comprends pas ta demande de boucle...

l'option la plus probable est que je n'ai rien compris à ton besoin....

[Pat973-13]

Bonjour et merci a_diard de bien vouloir me répondre,
Je me suis mal exprimé, désolé.
J'ai dans un UserForm 30 lignes et 3 colonnes de textbox.
je n'interviens que dans les 2 premières colonnes et la 3ème fait les calculs, c'est la 2ème qui me pose "problème".

ex : 25.32 x 12.38€ = 313.46€
lorsque je saisie 12.38 dans la 2ème, la troisième affiche 313.46€ et la 2ème passe au format 12.38€

J'ai donc dans mon programme 30fois txt_afterupdate pour la 2eme colonne et je souhaitais simplifier ca avec une boucle.
Je ne peux pas le faire avec txt_Change() car après chaque saisie dans cette colonne la 3ème fait le calcul (au format monétaire )et la 2ème doit être au format monétaire aussi.
Certaines lignes du UserForm peuvent être vides, et je peux entrer des valeurs plusieurs lignes plus bas.
Les données sont transférées après dans un fichier, et peuvent être récupérées ultérieurement dans le UserForm.

Je ne sais pas si je me suis mieux exprimé cette fois.......

[Philippe Tulliez]

Bonjour,
30 lignes et 3 colonnes, cela fait donc 90 TextBox ?
Il faut impérativement passer par un module de classe

Quelques tutoriels sur la question

• Création et utilisation de classes personnalisées en VB 6.0 et VBA (partie 1)
• Access : Modules de classes
• Office et les modules de classes
• Excel VBA: Modélisation des échanges entre table de données et userform
• Débat - Polymorphisme avec VBA: implémentation d'interface

[Pierre Fauconnier]

Salut.

Une façon simple de procéder, mais qui requiert de manipuler chaque évènement AfterUpdate des textbox, est de déporter le traitement dans une procédure appelée par chaque évènement AfterUpdate des textbox concernés.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Private Sub TextBox1_AfterUpdate()
  TextBoxAfterUpdate TextBox1
End Sub
 
Private Sub TextBox2_AfterUpdate()
  TextBoxAfterUpdate TextBox2
End Sub
 
Private Sub TextBox3_AfterUpdate()
 TextBoxAfterUpdate TextBox3
End Sub
 
Private Sub TextBoxAfterUpdate(tbo As MSForms.TextBox)
  MsgBox tbo.Name & " modifié"
End Sub

[Pat973-13]

Bonjour et merci messieurs TULLIEZ et FAUCONNIER,
Je vais me pencher sur les tutos de Mr Philippe TULLIEZ, car je pense partir sur le module de classe.
La méthode de Mr Pierre FAUCONNIER est plus simple, mais ne simplifie pas énormément ma programmation actuelle (1 ligne seulement par TextBox).
Dès que j'ai ma solution, je reviendrais vers vous pour vous tenir au courant, j'attends donc avant d'appuyer sur résolu.

Encore merci

[Pierre Fauconnier]

Plus simple, je ne sais pas, car ce qui est simple pour certains peut ne pas l'être pour d'autres. En l'absence d'une grille de critères commune, il est malaisé de parler de "plus simple".

Créer une classe qui gère les évènements pour plusieurs contrôles se réalise de la manière suivante:

Créer un module de classe et y saisir le code suivant. On voit que l'objet reçoit un msforms.textbox et l'attribue à une variable du module de classe, Private ou Public. La classe peut alors gérer certains évènements des textbox, comme ici Change.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Option Explicit
 
Private WithEvents mTbo As MSForms.TextBox
 
Sub Init(Value As MSForms.TextBox)
  Set mTbo = Value
End Sub
 
Private Sub mTbo_Change()
  MsgBox mTbo.Name & " est modifié"
End Sub

A l'initialisation du userform, on boucle sur les contrôles et on ajoute à une collection du userform les contrôles TextBox.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Option Explicit
 
Private tbos As Collection
 
Private Sub UserForm_Initialize()
  Dim c As MSForms.Control
  Dim MyTbo As cTbo
 
  Set tbos = New Collection
  For Each c In Me.Controls
    If TypeName(c) = "TextBox" Then
      Set MyTbo = New cTbo
      MyTbo.Init c
      tbos.Add MyTbo
    End If
  Next
End Sub

Le problème est que les évènements d'un msforms.textbox ne sont pas tous repris dans les évènements d'une variable msforms.textbox. Il en manque 4, dont celui qui t'intéresse: BeforeUpdate, AfterUpdate, Enter, Exit.



Au delà de cet aspect technique, je me pose toujours la question de savoir pourquoi on réinvente Excel avec 90 textbox qui, si j'ai bien compris le problème posé, ressemblent peu ou prou à une plage de cellules de 30 lignes et 3 colonnes. Pourquoi refaire en programmation ce pour quoi Excel est fait? Ne serait-il pas plus simple d'utiliser ce qui existe?