Discussion :

[LB12345]

Bonjour,

Pour un besoin pratique dans un tableau assez complexe, je souhaiterais pouvoir sommer des valeurs sur une plage selon des critères qui se situent aussi dans la même plage. Le critère se situe toujours au rang N+1 de la plage par rapport à la valeur qui lui est associée. L'exemple sera plus parlant :

EXEMPLE.xlsx

L'idéal serait de pouvoir utiliser des formules Excel et non une macro, pour pouvoir par la suite ajouter des données ("Postes" dans l'exemple joint et que les sommes les prennent bien en compte).

Par avance, merci de vos solutions !

[Pierre Fauconnier]

Salut

Ce n'est pas la meilleure organisation de données qui soit, car tu mélanges les données et leur exploitation/présentation/analyse... (Un des 7 péchés capitaux d'Excel).

Cela étant:
Formule en P3 à recopier vers le bas:

Code formule :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD(SI(ESTNUM(DECALER(B3;0;0;1;COLONNE()-3));DECALER(B3;0;0;1;COLONNE()-3))*(DECALER(DECALER(B3;0;0;1;COLONNE()-3);0;1)="P"))

Formule en Q3 à recopier vers le bas:

Code formule :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD(SI(ESTNUM(DECALER(B3;0;0;1;COLONNE()-4));DECALER(B3;0;0;1;COLONNE()-4))*(DECALER(DECALER(B3;0;0;1;COLONNE()-4);0;1)="A"))

Tu pourras insérer les colonnes 2 par 2 avant la colonne P, DECALER permettant de recalculer la plage de travail

[ARTURO83]

Bonjour,

Autres propositions:
la plus simple si le nombre de poste est figé

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(C3="P";B3;0)+SI(E3="P";D3;0)+SI(G3="P";F3;0)+SI(I3="P";H3;0)+SI(K3="P";J3;0)+SI(M3="P";L3;0)+SI(O3="P";N3;0)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(C3="A";B3;0)+SI(E3="A";D3;0)+SI(G3="A";F3;0)+SI(I3="A";H3;0)+SI(K3="A";J3;0)+SI(M3="A";L3;0)+SI(O3="A";N3;0)

autre solution, plus courte:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME.SI(C3:O3;"P";B3:N3)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME.SI(C3:O3;"A";B3:N3)

Cdlt

[Menhir]

Tout simplement en décalant la zone à sommer de la zone de critère.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME.SI($C3:$O3;"P";$B3:$N3)

[Pierre Fauconnier]

[...]
L'idéal serait de pouvoir utiliser des formules Excel et non une macro, pour pouvoir par la suite ajouter des données ("Postes" dans l'exemple joint et que les sommes les prennent bien en compte).[...]

Cela dit, plus simple que la mienne mais qui tient compte de l'ajout des postes, du moment que tu ajoutes bien deux colonnes par poste:

Pour P:

Code formule :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME.SI.ENS(DECALER(B3;0;0;1;COLONNE()-3);DECALER(C3;0;0;1;COLONNE()-3);"P")

Pour Q:

Code formule :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME.SI.ENS(DECALER(B3;0;0;1;COLONNE()-4);DECALER(C3;0;0;1;COLONNE()-4);"A")

Attention que ces formules tiennent compte du fait que ton premier poste est en B. Si tu insères des colonnes avant la colonne B, tu devras modifier ta formule.

[LB12345]

MERCI A TOUS !
C'est parfait.

(Je suis bien conscient que cela aurait été plus propre de ne pas mélanger données et critères sur une même plage mais dans le tableau que j'exploite ce n'était vraiment pas possible.)