Discussion :

[DaddyTousucre]

Bonjour à tous,
J'ai une macro qui crée des zones de texte, que je souhaite mettre en forme directement dans le code mais je n'y arrive pas ><
J'ai constament une erreur quand le code s'exécute et je ne comprends pas d'où ça vient ...
Je m'arrache les cheveux là dessus, pouvez-vous m'aider ?
Le code qui ne fonctionne pas est le suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Set boxepaisseur = Sheets(Onglet).Shapes.AddTextbox(msoTextOrientationHorizontal, _
                    ActiveCell.Offset(0, 4).Value + (Fac3 * EpMoy) * (Fac3 * 1.5), _
                    ActiveCell.Offset(0, 5).Value + (Fac4 * EpMoy) * (Fac4 * 1.5), _
                    10, 20)
                    With boxepaisseur.TextFrame
                        .Characters.Text = EpMoy & " µm"
                        .AutoSize = True
                    End With
                    With boxepaisseur.ShapeRange
                        .Fill.ForeColor.RGB = RGB(255, 255, 255)
                        .Line.Weight = 1.25
                        .Line.ForeColor.RGB = RGB(188, 68, 207)
                    End With
                    With boxepaisseur.Font
                        .Bold = True
                        .ColorIndex = 7
                        .Size = 14
                    End With

Ca coince au 2ème With
Merci par avance pour votre aide.
Bonne journée à tous

[Menhir]

Supprime .ShapeRange.

[DaddyTousucre]

Merci le 2ème With passe mais maintenant ça bloque au dernier ><

[pijaku]

Bonjour,

J'ai modifié certaines couleurs.

Essaye ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
    Set boxepaisseur = Sheets(Onglet).Shapes.AddTextbox(msoTextOrientationHorizontal, _
    ActiveCell.Offset(0, 4).Value + (Fac3 * EpMoy) * (Fac3 * 1.5), _
    ActiveCell.Offset(0, 5).Value + (Fac4 * EpMoy) * (Fac4 * 1.5), _
    10, 20)
    With boxepaisseur
        With .TextFrame
            .Characters.Text = EpMoy & " µm"
            .AutoSize = True
        End With
        With .TextFrame2.TextRange.Font
            .Bold = True
            .Fill.ForeColor.RGB = RGB(255, 0, 0)
            .Size = 14
        End With
        With .Fill
            .ForeColor.RGB = RGB(0, 255, 255)
        End With
        With .Line
            .Weight = 1.25
            .ForeColor.RGB = RGB(188, 68, 207)
        End With
    End With

[DaddyTousucre]

Merci à vous deux, en combinant vos réponses j'ai le code suivant qui tourne nickel :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Set boxepaisseur = Sheets(Onglet).Shapes.AddTextbox(msoTextOrientationHorizontal, _
                    ActiveCell.Offset(0, 4).Value + (Fac3 * EpMoy) * (Fac3 * 1.5), _
                    ActiveCell.Offset(0, 5).Value + (Fac4 * EpMoy) * (Fac4 * 1.5), _
                    10, 20)
                    With boxepaisseur.TextFrame
                        .Characters.Text = EpMoy & " µm"
                        .AutoSize = True
                    End With
                    With boxepaisseur
                        .Fill.ForeColor.RGB = RGB(255, 255, 255)
                        .Line.Weight = 1.25
                        .Line.ForeColor.RGB = RGB(188, 68, 207)
                    End With
                    With boxepaisseur.TextFrame2.TextRange.Font
                    .Bold = True
                    .Fill.ForeColor.RGB = RGB(255, 0, 0)
                    .Size = 14
                    End With

Vous avez sauvé pas mal de mes cheveux merci beaucoup !