Discussion :

[plasto590807]

Bonjour,

Comment agrandir le Name d'un UserForm ? Rendre plus gros ? changer de police ?

Merci.

[Philippe Tulliez]

Bonjour,

Comment agrandir le Name d'un UserForm ? Rendre plus gros ? changer de police ?

J'avoue ne pas comprendre

• "Comment agrandi le Name d'un UserForm". On peut modifier le nom (propriété Name) d'un UserForm et bien entendu il y a un maximum de caractères autorisé et cela on ne peut pas le modifier
• "Rendre plus gros ?". Tu veux sans doute dire modifier sa largeur (Width), sa hauteur (Height) ?
  Oui, c'est possible

et oui, on peut modifier la police de caractères : C'est la propriété Font du groupe Police de la fenêtre des propriétés

Le tout est possible soit directement dans la fenêtre des propriétés (F4) soit par VBA à l'initialisation par exemple

Petit exemple en VBA où l'on modifie les propriétés Name, Italic et Size du UserForm lorsque l'on clique dessus

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Private Sub UserForm_Click()
 With Me.Label1.Font
 .Name = "Cambria"
 .Size = 15
 .Italic = True
 End With
End Sub

[Patrice740]

Bonjour,

Comment agrandir le Name d'un UserForm ? Rendre plus gros ? changer de police ?

Si tu parles de la barre de titre de l'userform, on ne peut pas agir sur la police.
Mais on peut, ne pas l'afficher, et recréer une pseudo barre de titre avec des labels.

Par exemple : usfSansBarreDeTitre.xlsm

Le code pour Excel 32 bits (avec 3 labels) :

Code VBA :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
Option Explicit
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long) As Long
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Function DrawMenuBar Lib "user32" (ByVal hwnd As Long) As Long
Private Sub UserForm_Initialize()
Dim hwnd As Long
Dim style
  ' Supprimer la barre de titre
  hwnd = FindWindow(vbNullString, Me.Caption)
  style = GetWindowLong(hwnd, -16) And Not &HC00000 'supression de la barre de titre...
  SetWindowLong hwnd, -16, style
  DrawMenuBar hwnd
  ' Recréer une pseudo-barre avec 3 labels
  With Me.lblTitreTexte       'Nom de l'userform
    .BackColor = &H80000002
    .Width = Me.Width
    .Left = 0
    .Top = 3
    .Caption = " " & Me.Name
    .Font.Name = "Tahoma"
    .Font.Size = 24
    .AutoSize = True
    .ZOrder 0
  End With
  With Me.lblTitreFond        'Couleur de fond
    .AutoSize = False
    .BackColor = &H80000002
    .Height = Me.lblTitreTexte.Height + 6
    .Width = Me.Width
    .Left = 0
    .Top = 0
    .Caption = ""
    .ZOrder 1
  End With
  With Me.lblCroix            'Croix de fermeture
    .AutoSize = False
    .BackColor = &H80000002
    .ForeColor = &H0
    .Height = Me.lblTitreTexte.Height
    .Width = .Height * 1.5
    .Left = Me.Width - Me.lblCroix.Width - 6
    .Top = Me.lblTitreTexte.Top
    .SpecialEffect = 6
    .Caption = "X"
    .Font.Name = "Tahoma"
    .Font.Size = 21
    .ZOrder 0
  End With
End Sub
Private Sub lblCroix_MouseMove(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
  With Me.lblCroix
    .BackColor = &HFF
    .ForeColor = &HFFFFFF
  End With
End Sub
Private Sub lblTitreFond_MouseMove(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
  With Me.lblCroix
    .BackColor = &H80000002
    .ForeColor = &H0
  End With
End Sub
Private Sub UserForm_MouseMove(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
  With Me.lblCroix
    .BackColor = &H80000002
    .ForeColor = &H0
  End With
End Sub
Private Sub lblCroix_Click()
  Unload Me
End Sub
Private Sub CommandButton1_Click()
  Unload Me
End Sub