Discussion :

[manusib]

Bonjour à tous,

j'ai une formule assez compliquée à mettre en œuvre. voilà mon fichier excel en copie écran :



J'aimerai pouvoir faire la somme des cellules de la colonne F selon plusieurs critères :

si les cellules de la colonne G sont égales à "MTI" ou "P1CONSO" ou "P1ABT" et si la date des cellules de la colonne G sont comprises entre 01/01/2017 et 31/12/2017.

Je tourne en rond, j'ai essayé avec la fonction

Code formule :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME.SI.ENS('2014'!F:F;'2014'!G:G;"P1CONSO")+SOMME.SI.ENS('2014'!F:F;'2014'!G:G;"MTI")+SOMME.SI.ENS('2014'!F:F;'2014'!G:G;"P1ABT")

mais je n'arrive pas à intégrer la fonction DATE dans cette fonction...

Avec tous remerciements

[Menhir]

J'aimerai pouvoir faire la somme des cellules de la colonne F selon plusieurs critères :
si les cellules de la colonne G sont égales à "MTI" ou "P1CONSO" ou "P1ABT" et si la date des cellules de la colonne G sont comprises entre 01/01/2017 et 31/12/2017.

Je tourne en rond, j'ai essayé avec la fonction

Code formule :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME.SI.ENS('2014'!F:F;'2014'!G:G;"P1CONSO")+SOMME.SI.ENS('2014'!F:F;'2014'!G:G;"MTI")+SOMME.SI.ENS('2014'!F:F;'2014'!G:G;"P1ABT")

Quand on veut intégrer dans une fonction SOMME.SI.ENS() une période (durée limitée par deux dates), il faut utiliser deux critères : un pour indiquer "supérieur à la date de départ" et un autre pour indiquer "inférieur à la date de fin".
Exemple si les dates sont en colonne A :

Code formule :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME.SI.ENS('2014'!F:F;'2014'!G:G;"P1CONSO";'2014'!A:A;">=01/01/2017";'2014'!A:A;"<01/01/2018")

[manusib]

Désolé, ça ne fonctionne pas, j'ai simplifié pour essayer de résoudre le problème en mettant ceci :

Code formule :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME.SI.ENS(F:F;G:G;"P1CONSO";A:A;">=01/01/2017")

ça me renvoie 0 alors que si j'enlève la comparaison sur la date, ça fonctionne.

J'ai formaté la colonne en date jj/mm/aaaa, mais ça ne fonctionne pas.

Ne faudrait-il pas une conversion de la date en nombre ?

[papouclo]

Bonjour,
Attention les dates ne sont pas en colonne A mais en colonne D.
Cordialement
Claude

[manusib]

oui j'ai fait attention à cela, c'est parce que quand je poste avec la colonne D ça me convertit en smiley voilà pourquoi j'ai pris exemple sur la colonne A (A:A pas de smiley mais D smiley)

[Menhir]

Essaye ça :

Code formule :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME.SI.ENS('2014'!F:F;'2014'!G:G;"P1CONSO";'2014'!A:A;">="&DATE(2017;1;1);'2014'!A:A;"<"&DATE(2018;1;1))

En remplaçant bien sûr A:A par la colonne où se trouvent tes dates.

[manusib]

et bien non, pas bon, toujours 0...

[Menhir]

Chez moi ça fonctionne.
Ca veut sans doute dire que tes dates n'en sont pas vraiment.

[Patrice740]

Bonjour,

D'après la photo, les dates ne sont pas des dates : ce sont des textes !
Il faut les convertir en nombre :
- sélectionne un cellule vide / copier
- sélectionne les dates / collage spécial : cocher valeur et addition

[manusib]

Merci super, ça fonctionne, en effet les dates n'étaient pas en nombre mais en texte...

ce qui donne :

Code formule :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME.SI.ENS('[Fact_chauf.xlsx]2017'!$F:$F;'[Fact_chauf.xlsx]2017'!$G:$G;"P1CONSO";'[Fact_chauf.xlsx]2017'!$D:$D;">="&DATE(2017;1;1);'[Fact_chauf.xlsx]2017'!$D:$D;"<"&DATE(2018;1;1))

ceci fonctionne !

En revanche, lorsque j'intègre la plage colonne G avec un critère supplémentaire "P1ABT", ça ne fonctionne plus.......

Code formule :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME.SI.ENS('[Fact_chauf.xlsx]2017'!$F:$F;'[Fact_chauf.xlsx]2017'!$G:$G;"P1CONSO";'[Fact_chauf.xlsx]2017'!$G:$G;"P1ABT";'[Fact_chauf.xlsx]2017'!$D:$D;">="&DATE(2017;1;1);'[Fact_chauf.xlsx]2017'!$D:$D;"<"&DATE(2018;1;1))

Pourquoi ?

évidemment je peux ajouter un deuxième SOMME.SI.ENS, là ça fonctionne :

Code formule :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME.SI.ENS('[Fact_chauf.xlsx]2017'!$F:$F;'[Fact_chauf.xlsx]2017'!$G:$G;"P1CONSO";'[Fact_chauf.xlsx]2017'!$D:$D;">="&DATE(2017;1;1);'[Fact_chauf.xlsx]2017'!$D:$D;"<"&DATE(2018;1;1)) + SOMME.SI.ENS('[Fact_chauf.xlsx]2017'!$F:$F;'[Fact_chauf.xlsx]2017'!$G:$G;"P1ABT";'[Fact_chauf.xlsx]2017'!$D:$D;">="&DATE(2017;1;1);'[Fact_chauf.xlsx]2017'!$D:$D;"<"&DATE(2018;1;1))

Un éclairage ?

[ARTURO83]

Bonsoir,

La fonction SOMME.SI.ENS est une fonction qui fait la somme si la condition 1 ET la condition2 ET la condition 3 etc sont réunies, alors que dans votre cas , il y a des conditions ET et OU , il vous faut donc créer une SOMME pour chaque cas OU à traiter.
en plus des propositions précédentes en voici 2 autres avec des formes d'écritures différentes

Code formule :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
=SOMME.SI.ENS('2014'!F:F;'2014'!G:G;"MTI";'2014'!D:D;">=01/01/17";'2014'!D:D;"<=21/12/17")+
SOMME.SI.ENS('2014'!F:F;'2014'!G:G;"P1CONSO";'2014'!D:D;">=01/01/17";'2014'!D:D;"<=21/12/17")+
SOMME.SI.ENS('2014'!F:F;'2014'!G:G;"P1ABT";'2014'!D:D;">=01/01/17";'2014'!D:D;"<=21/12/17")

Code formule :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
=SOMMEPROD(('2014'!$G$2:$G$1000="MTI")*('2014'!$D$2:$D$1000>=DATE(2017;1;1))*('2014'!$D$2:$D$1000<=DATE(2017;12;31));('2014'!$F$2:$F$1000))+
SOMMEPROD(('2014'!$G$2:$G$1000="P1CONSO")*('2014'!$D$2:$D$1000>=DATE(2017;1;1))*('2014'!$D$2:$D$1000<=DATE(2017;12;31));('2014'!$F$2:$F$1000))+
SOMMEPROD(('2014'!$G$2:$G$1000="P1ABT")*('2014'!$D$2:$D$1000>=DATE(2017;1;1))*('2014'!$D$2:$D$1000<=DATE(2017;12;31));('2014'!$F$2:$F$1000))

Dans le 2ème cas, l'emploi de sommeprod nécessite de mettre des limites définies, ici la plage de la ligne 2 à 1000

Cdlt

[manusib]

Un grand merci pour votre efficacité, promptitude et professionnalisme.