Discussion :

[Icamstudent]

Bonjour à tous je rencontre un problème sur mon projet.
J'ai une feuille avec toutes les données de mes commandes, un peu comme une base de donnée.
J'ai crée une seconde feuille avec seulement les colonnes qui m’intéresse de la première feuille.

Je voudrais copier les données des colonnes en questions. Pour le moment j'ai fait ça:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub CopieDonnées()
'Numéro od
    Feuil2.Range("L2:L94").Copy
    Feuil10.Range("A2").PasteSpecial xlPasteValues
 
'Date Int
'Dday
'Raison Social
'Date od
'Date Cadence
'Cout TT
'Qte
 
End Sub

Et le problème, c'est que je voudrais que ce soit dynamique en fonction du nombre de ligne. Par exemple si j'ai 40 lignes aujourd'hui, je copie les 40. Mais si le lendemain j'en est 60 bah je veux prendre les 60 lignes, pas seulement 40.
Je ne trouve pas comment faire, car sur les tutos que j'ai vu c'est toujours une plage avec plusieurs colonnes.
Pouvez vous m'aider ? Merci d'avance

[Pierre Dumas]

Bonjour

Il n'est rien dit dans l'énoncé sur pourquoi il faut prendre 40 ou 60 lignes. Est-ce un filtre, est-ce une mise à jour de données, un désir changeant, ... ?

Ne connaissant pas la réponse, je vous propose une solution, hyper basique, où le code vous demande jusqu'à quelle ligne copier :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub CopieDonnées()
    lig = InputBox("combien ?")
    Feuil2.Range("L2:L" & lig & ",K2:K" & lig & ",I2:I" & lig).Copy
    Feuil10.Range("A2").PasteSpecial xlPasteValues
End Sub

Tant qu'à faire, on copie tous les éléments en une seule fois, pour tout coller en une seule fois.

Sinon, il me semble beaucoup plus efficace de mettre en place un filtre avancé. C'est une fonctionnalité native d'Excel (présente depuis au moins le siècle dernier) et qui répond pile à votre besoin. La première fois n'est peut-être pas simple à mettre en place, mais pour la deuxième, il suffit de lancer le filtre et de cliquer sur OK.
Je vous laisse consulter le tutoriel de Philippe Tulliez.

Bonne fin de journée

Pierre Dumas

[Icamstudent]

C'est vrai que ce n'est pas clair. En faite chaque jour la base de donnée change en fonction du nombre de commandes, donc nombre de ligne. Par exemple la bdd actuelle comprends 94 lignes mais demain il peu en avoir 100 et apres 90 etc..

Et je veux copier toutes ces ligne dans ma seconde feuille.

[Menhir]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
    Feuil2.Range("L1").EntireColumn.Copy
    Feuil10.Range("A1").PasteSpecial xlPasteValues

Même chose pour les autres colonnes.

[Icamstudent]

Merci pour cette réponse mais ça n'est pas exactement ce que je cherche. Cela modifie le titre de colonne dans la feuille de destination.
De plus cette fonction prends toute la colonne hors sous cette base de donnée il y'a des commentaires que je ne veux pas copier.

Il n'est pas possible de compter le nombre de ligne rempli pour arriver jusqu’à la dernier ligne avant la séparation avec les commentaire, pour avoir le nombre d'enregistrement exact à chaque fois ?

[Pierre Dumas]

[...]
De plus cette fonction prends toute la colonne hors sous cette base de donnée il y'a des commentaires que je ne veux pas copier.

Ça, on ne pouvait pas le deviner. Ce n'était écrit ou affiché nul part

Il n'est pas possible de compter le nombre de ligne rempli pour arriver jusqu’à la dernier ligne avant la séparation avec les commentaire, pour avoir le nombre d'enregistrement exact à chaque fois ?

Bien sûr que si c'est possible
Mais, là aussi, il faut en dire plus afin que l'on n'élabore pas des solutions en partant dans des directions qui ne sont pas les bonnes.
"compter le nombre de ligne rempli" : oui, mais dans quelle colonne ? Et c'est rempli avec quoi ?
"avant la séparation avec les commentaire" : oui, mais comment sait-on que c'est la séparation ?

Il faut le maximum d'information afin de proposer l'aide la plus pertinente possible et la plus rapide.

Bonne fin de journée

Pierre Dumas

[Icamstudent]

Pour le commentaire c'est ma faute je m'en suis rendu compte après avoir poste le premier message.

Chaque colonne à le même nombre de ligne. Et les colonne qui m'intéresse (Numéro od / Date Int / Raison Social / Dday / Date od / Date cadence /Cout TT / Qté). 1 ligne un enregistrement. C'est rempli avec des dates, des codes, des donnée numérique. Tout les colonne ne sont pas toute cote à cote, et elles ne sont pas dans le même ordre dans la feuille de destination.

Dans le code que j'ai fait, j'arrive bien à copier tout les information. Mais le nombre de ligne est fixé ( Range(A2:A95) ), il n'est pas dynamique ou variable comme vous préféré, pour prendre en compte le nombre de ligne d'enregistrement exacte.

La séparation avec les commentaire se fait avec une ligne vide entre les 2.

Et merci de prendre du temps pour m'aider

[MarcelG]

Bonjour à vous, Bonjour au Forum,

Pour ma part, je ne trouve pas opportun de placer des commentaires après une base de données.

Je me méfie comme de la peste de la propriété CurrentRegion.

Si, malgré tout, les commentaires doivent subsister, et s'ils forment un bloc sans ligne vide, alors peut être éventuellement l'utilisation de 3 xlUp

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Option Explicit
 
Sub tablo()
 
Dim derlign As Long
 
With Worksheets(1)
        derlign = .Cells(.Rows.Count, 1).End(xlUp).End(xlUp).End(xlUp).Row
End With
 
End Sub

Malgré tout, je ne suis pas fan.

Mais si l'une des dernières cellules de la base reporte une constante (exemple "tra"), alors la recherche de cette dernière ligne pourrait s'effectuer par la combinaison des paramètres SerachOrder et SeachDirection de la méthode Find
Autrement dit, on part de la dernière ligne de la feuille.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Option Explicit
 
Sub tablo2()
 
Dim derlign As Long
 
With Worksheets(1)
        derlign = .Range("A1:A" & .Rows.Count).Find(what:="tra", searchdirection:=xlPrevious, searchorder:=xlByRows, LookIn:=xlValues).Row
End With
 
End Sub

Pour ce qui concerne la gestion des colonnes, j'opterais pour l'utilisation d'une variable tableau.
Ceci avec cette précaution nécessaire quant aux dates.
Celles-ci doivent impérativement être reportées sous format de chaînes de caractères en utilisant la fonction Format.
Dans le cas contraire, le reversement de la variable tableau pour ce champ risquerait fort de s''effectuer sous format américain (inversion jour et mois).

[Icamstudent]

C'est très intéressant merci
Je n'arrive pas à l'ajouter correctement à mon code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Option Explicit
 
Sub CopieDonnées()
 
Dim derlign As Long
 
With Worksheets(2)
        derlign = .Cells(.Rows.Count, 1).End(xlUp).End(xlUp).End(xlUp).Row
End With
 
 
 
'Numéro od
    Feuil2.Range("L2 & derlign").Copy
    Feuil10.Range("A2").PasteSpecial xlPasteValues
'Date Int
    'Feuil2.Range("J2:J95").Copy
    'Feuil10.Range("B2").PasteSpecial xlPasteValuesAndNumberFormats
'Dday
   ' Feuil2.Range("K2:K95").Copy
   ' Feuil10.Range("C2").PasteSpecial xlPasteValuesAndNumberFormats
'Raison Social
    'Feuil2.Range("I2:I95").Copy
    'Feuil10.Range("D2").PasteSpecial xlPasteValues
'Date od
    'Feuil2.Range("M2:M95").Copy
    'Feuil10.Range("E2").PasteSpecial xlPasteValuesAndNumberFormats
'Date Cadence
    'Feuil2.Range("AC2:AC95").Copy
    'Feuil10.Range("F2").PasteSpecial xlPasteValuesAndNumberFormats
'Cout TT
    'Feuil2.Range("AH2:AH95").Copy
    'Feuil10.Range("G2").PasteSpecial xlPasteValuesAndNumberFormats
'Qte
    'Feuil2.Range("AI2:AI95").Copy
    'Feuil10.Range("H2").PasteSpecial xlPasteValuesAndNumberFormats
 
    Application.CutCopyMode = False
 
End Sub

[MarcelG]

Salut,

Je n'arrive pas à l'ajouter correctement à mon code

C'est à dire? Message d'erreur à quelle ligne?

Par ailleurs, si je me réfère à ce que tu as reporté en libellé, et si tu tiens au collage spécial, mieux vaut à mon avis boucler sur un Array contenant les numéros de colonne

[Icamstudent]

Erreur 1004

Un array c'est à dire ?

[MarcelG]

Pourrais-tu être plus explicite, s'il te plaît.
Je t'ai demandé sur quelle ligne portait l'erreur.
Autrement dit, quelle ligne est mise en surbrillance (généralement jaune) par le débugger lorsque celle-ci survient?

Un Array est un tableau à 1 dimension, déclaré généralement, et exceptionnellement de mon point de vue, en Variant.
Tu trouveras plusieurs illustrations avec un minimum de recherche.

[Icamstudent]

Quand je lance le VBA j'ai juste un message d'erreur 1004 mais aucune ligne ne se met en surbrillance.

d'accord je vais essayer avec cette fonction.
Je suis novice donc ce qui pour vous est simple, ne l'est pas pour moi. Et j'ai du mal à tout comprendre et assimiler

[MarcelG]

Quand je lance le VBA j'ai juste un message d'erreur 1004 mais aucune ligne ne se met en surbrillance.

Jamais vu

Lorsque le message d'erreur survient, active le bouton "Débogage" sur le pop-up.

Tu peux reporter une capture d'écran de ce qui apparaît ensuite.

Je suis novice donc ce qui pour vous est simple, ne l'est pas pour moi. Et j'ai du mal à tout comprendre et assimiler

Aucun problème. Nous sommes, pour beaucoup, passés par ce stade.

[Icamstudent]

Voila j'ai surement du faire une erreur bête dans l'ajout de derlign

[MarcelG]

Bizarre, je ne m'attendais pas à voir une erreur 1004 sans débogage.


Par ailleurs, et par précaution, procède au préalable à l'affichage de la fenêtre des variables locales.
Menu "Affichage" de l'éditeur VBE.
Cette fenêtre t'indiquera la valeur de la variable "derlign"

Puis effectue une exécution d ton code pas à pas.
Pour ce faire
Clic sur le nom de la procédure puis touche F8.
Le message d'erreur doit survenir après une ligne de ton code.

Enfin, le code proposé est sans doute à adapter (nom de la feuille, numéro de colonne…).

[Icamstudent]

J'ai afficher la valeur de derlign c'est égale à 0. Une fois passe le End elle prends la valeur 1

Et le message erreur arrive la :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
'Numéro od
    Feuil2.Range("L2 & derlign").Copy
    Feuil10.Range("A2").PasteSpecial xlPasteValues

J'ai adapter le numéro de dans le Workbook(2) c'est le numéro de la feuille de la base de donnée.
Mais le numéro de colonne je sais pas ou le mettre.

Je commence à désespéré un peu lol

[MarcelG]

Salut,

Il te faut comprendre ce que tu écris.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Range("L2 & derlign").

ne veut rien dire.

Cette écriture sous-entendrait en effet qu'un nom de cellule(s) "L2 & derlign" soit créé.

L'argument d'un objet Range peut être une chaîne de caractères, elle-même résultat d'une concaténation.
Mais dans ce cas, il te faut coder

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range("L2:L" & derlign)

Cela étant, comme un certain nombre de post ont été édités pour cette discussion, retourne un fichier simplifié.
Je te proposerai volontiers une piste, à condition que tu cherches à comprendre chaque ligne du code proposé (i.e. sans un pur copier/coller, à terme infructueux)

[Icamstudent]

Voici le fichier simplifier: Copie donnée.xls
J'ai enlever tout les formule de la bdd pour de garder que les valeur.

Concernant les commentaires je vais voir avec notre client si ils sont indispensable.

Pour rappel, j'aimerais copier tout les enregistrements compris dans les colonnes, en fonction du nombre de commande de chaque jour.

Et oui je vais chercher à comprendre la proposition que tu vas faire, car je veux apprendre. Et comme c'est sur un problème concret pour moi ce sera formateur.
Encore merci

[MarcelG]

Salut,

Voici, Voilou.

Pour la recherche de la dernière ligne, je me suis basé sur les 2 occurrences "O" et "N" reportées en colonne AK

Comme références, au niveau des colonnes, j'ai considéré les commentaires figurant dans ton code

A savoir:
La colonne 12 (L) est copiée vers la colonne 1 (A)
La colonne 10 (J) est copiée vers la colonne 2 (B)
etc...

D'où, en respectant cet ordre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

tablo_col = Array(12, 10, 11, 9, 13, 29, 34, 35)

Soit

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
Option Explicit
 
Public Sub copie_colonnes_MarcelG()
 
Dim wks_origine As Worksheet
Dim wks_destin As Worksheet
 
With ThisWorkbook
        Set wks_origine = .Worksheets("OD_PRIORITY")
        Set wks_destin = .Worksheets("Donnees_access")
End With
 
Dim dernl1 As Long, dernl2 As Long, dernl As Long
 
Dim tablo_col As Variant
Dim i As Integer
Dim col As Variant
 
tablo_col = Array(12, 10, 11, 9, 13, 29, 34, 35)
 
i = 0
 
With wks_origine
 
        dernl1 = .Range("AK2:AK" & .Rows.Count).Find(what:="N", searchdirection:=xlPrevious, searchorder:=xlByRows, LookIn:=xlValues).Row
        dernl2 = .Range("AK2:AK" & .Rows.Count).Find(what:="O", searchdirection:=xlPrevious, searchorder:=xlByRows, LookIn:=xlValues).Row
        dernl = Application.WorksheetFunction.Max(dernl1, dernl2)
 
        For Each col In tablo_col
                i = i + 1
                .Range(.Cells(2, col), .Cells(dernl, col)).Copy
                wks_destin.Cells(2, i).PasteSpecial Paste:=xlValues
        Next col
 
End With
 
Application.CutCopyMode = False
 
Set wks_destin = Nothing
Set wks_origine = Nothing
 
End Sub

A adapter (éventuellement) dans un module standard.

Comme tu sembles être débutante, j'ai opté pour ce processus.
Bien entendu, je pourrai revenir en considérant une variable tableau.
(Je ne suis pas familiarisé avec Power Query; sans doute y a-t-il une possibilité de ce côté.)

Tu essaies de comprendre ce code mot à mot (depuis Option Explicit jusqu'à End Sub).
Tu reviens pour toute question.

2 compléments
1 - La méthode Find est décrite dans cet espace
2 - Pour ton information, voire, si je peux me permettre, ta formation, tu peux t'orienter vers la source indiquée au-dessus de mon avatar (icône bleue).

A plus tard donc