Discussion :

[Avril_05]

Bonjour à tous,

Je ne parviens pas à faire en sorte que ma formule prenne en compte mes deux menus déroulants.

Voici ma formule :

=SI($C$41="Desktop";SOMME.SI.ENS('Base Global'!K:K;'Base Global'!$E:$E;"B";'Base Global'!C:C;"Desktop";'Base Global'!$B:$B;"2020";'Base Global'!$A:$A;'Campagnes'!B46);SI($C$41="Mobile";SOMME.SI.ENS('Base Global'!K:K;'Base Global'!$E:$E;"B";'Base Global'!C:C;"Mobile";'Base Global'!$B:$B;"2020";'Base Global'!$A:$A;'Campagnes'!B46);SI($C$41="Tablette";SOMME.SI.ENS('Base Global'!K:K;'Base Global'!$E:$E;"B";'Base Global'!C:C;"Tablette";'Base Global'!$B:$B;"2020";'Base Global'!$A:$A;'Campagnes'!B46);SI($C$41="All Device";SOMME.SI.ENS('Base Global'!K:K;'Base Global'!$E:$E;"B";'Base Global'!$B:$B;"2020";'Base Global'!$A:$A;'Campagnes'!B46);SI($C$43="Google Ads";SOMME.SI.ENS('Base Global'!K:K;'Base Global'!E:E;"B";'Base Global'!D:D;"Google Ads";'Base Global'!B:B;"2020";'Base Global'!A:A;'Campagnes'!B46);SI($C$43="Bing Ads";SOMME.SI.ENS('Base Global'!K:K;'Base Global'!E:E;"B";'Base Global'!D:D;"Bing Ads";'Base Global'!B:B;"2020";'Base Global'!A:A;'Campagnes'!B46);SI($C$43="All Moteur";SOMME.SI.ENS('Base Global'!K:K;'Base Global'!E:E;"B";'Base Global'!B:B;"2020";'Base Global'!A:A;'Campagnes'!B46))))))))
Les stats s'actualisent bien quand je change la cellule C41 qui correspond à mon premier menu déroulant. Par contre cela ne prend pas du tout en compte mon deuxième menu déroulant C43.

Pouvez-vous m'aider sur cette formule svp ?

Merci par avance

[ARTURO83]

Bonjour,

A première vue après avoir éclaircie la formule, il semblerait que vous vouliez faire l'addition suivant C41 et C43, mais si c'est le cas, il manquerait l'opérateur "+" entre les 2 (ici en rouge dans la formule)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
=SI($C$41="Desktop";SOMME.SI.ENS('Base Global'!K:K;'Base Global'!$E:$E;"B";'Base Global'!C:C;"Desktop";'Base Global'!$B:$B;"2020";'Base Global'!$A:$A;Campagnes!B46);
SI($C$41="Mobile";SOMME.SI.ENS('Base Global'!K:K;'Base Global'!$E:$E;"B";'Base Global'!C:C;"Mobile";'Base Global'!$B:$B;"2020";'Base Global'!$A:$A;Campagnes!B46);
SI($C$41="Tablette";SOMME.SI.ENS('Base Global'!K:K;'Base Global'!$E:$E;"B";'Base Global'!C:C;"Tablette";'Base Global'!$B:$B;"2020";'Base Global'!$A:$A;Campagnes!B46);
SI($C$41="All Device";SOMME.SI.ENS('Base Global'!K:K;'Base Global'!$E:$E;"B";'Base Global'!$B:$B;"2020";'Base Global'!$A:$A;Campagnes!B46)+
SI($C$43="Google Ads";SOMME.SI.ENS('Base Global'!K:K;'Base Global'!E:E;"B";'Base Global'!D;"Google Ads";'Base Global'!B:B;"2020";'Base Global'!A:A;Campagnes!B46);
SI($C$43="Bing Ads";SOMME.SI.ENS('Base Global'!K:K;'Base Global'!E:E;"B";'Base Global'!D;"Bing Ads";'Base Global'!B:B;"2020";'Base Global'!A:A;Campagnes!B46);
SI($C$43="All Moteur";SOMME.SI.ENS('Base Global'!K:K;'Base Global'!E:E;"B";'Base Global'!B:B;"2020";'Base Global'!A:A;Campagnes!B46))))))))

Cdlt

[Avril_05]

Merci Arturo pour votre aide.

Cela fonctionne maintenant mais uniquement si sur le filtre C41 je suis en all device. Je n'ai donc toujours pas la combinaison des deux filtres pris en compte.
Est-ce que vous avez une autre idée svp ?

Merci par avance

[ARTURO83]

Pour que je puisse faire des tests, serait-il possible d'avoir un petit bout de votre fichier (supprimez les données confidentielles)?

[Avril_05]

Voici un exemple avec de fausses données

Merci pour votre aideAvril.xlsx

[ARTURO83]

Avant d'aller plus loin, regardez ici, c'est sûr que la cellule à tester est bien C4 ce n'est pas C5 plutôt?
Pièce jointe 553306

et l'addition avec le + (en rouge dans la formule, en bout de la 4ème ligne)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
=SI($C$3="Desktop";SOMME.SI.ENS('Base Global'!J:J;'Base Global'!$E:$E;"One";'Base Global'!C:C;"Desktop";'Base Global'!$B:$B;"2020";'Base Global'!$A:$A;Campagnes!B8);
SI($C$3="Mobile";SOMME.SI.ENS('Base Global'!J:J;'Base Global'!$E:$E;"One";'Base Global'!C:C;"Mobile";'Base Global'!$B:$B;"2020";'Base Global'!$A:$A;Campagnes!B8);
SI($C$3="Tablette";SOMME.SI.ENS('Base Global'!J:J;'Base Global'!$E:$E;"One";'Base Global'!C:C;"Tablette";'Base Global'!$B:$B;"2020";'Base Global'!$A:$A;Campagnes!B8);
SI($C$3="All Device";SOMME.SI.ENS('Base Global'!J:J;'Base Global'!$E:$E;"One";'Base Global'!$B:$B;"2020";'Base Global'!$A:$A;Campagnes!B8)+
SI($C$5="Google Ads";SOMME.SI.ENS('Base Global'!J:J;'Base Global'!E:E;"One";'Base Global'!D:D;"Google Ads";'Base Global'!B:B;"2020";'Base Global'!A:A;Campagnes!B8);
SI($C$5="Bing Ads";SOMME.SI.ENS('Base Global'!J:J;'Base Global'!E:E;"One";'Base Global'!D:D;"Bing Ads";'Base Global'!B:B;"2020";'Base Global'!A:A;Campagnes!B8);
SI($C$5="All Moteur";SOMME.SI.ENS('Base Global'!J:J;'Base Global'!E:E;"One";'Base Global'!B:B;"2020";'Base Global'!A:A;Campagnes!B8))))))))

[Avril_05]

Désolée c'est bien C5

[ARTURO83]

J'ai complété mon message précédent, l'avez-vous vu?

[Avril_05]

c'est bien ça aussi pour l'addition

[Avril_05]

Vous pensez que c'est possible de le faire ?

Merci par avance

[ARTURO83]

Bonjour,

Essayez ceci, pour plus de clarté, j'ai créé 2 cellules pour Année recherchée et pour la marque
Pièce jointe 553372

la formule:

Code formule :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
=SI(ET($C$3="All Device";$C$5="All Moteur");SOMME.SI.ENS('Base Global'!J:J;'Base Global'!$E:$E;$G$5;'Base Global'!$B:$B;$G$3;'Base Global'!$A:$A;$B8);
SI(ET($C$3="All Device";$C$5<>"All Moteur");SOMME.SI.ENS('Base Global'!J:J;'Base Global'!$D:$D;$C$5;'Base Global'!$E:$E;$G$5;'Base Global'!$B:$B;$G$3;'Base Global'!$A:$A;$B8);
SI(ET($C$3<>"All Device";$C$5<>"All Moteur");SOMME.SI.ENS('Base Global'!J:J;'Base Global'!$C:$C;$C$3;'Base Global'!$D:$D;$C$5;'Base Global'!$E:$E;$G$5;'Base Global'!$B:$B;$G$3;'Base Global'!$A:$A;$B8);
SI(ET($C$3<>"All Device";$C$5="All Moteur");SOMME.SI.ENS('Base Global'!J:J;'Base Global'!$C:$C;$C$3;'Base Global'!$E:$E;$G$5;'Base Global'!$B:$B;$G$3;'Base Global'!$A:$A;$B8)))))

Cdlt

[papouclo]

Bonjour,
Je reprends pour ma proposition la présentation d'Arturo83 avec sur la feuille Campagnes le choix de l'année et de la marque respectivement en G3 et G5.
La formule proposée illustre aussi les paroles de Pierre Fauconnier dans une discussion similaire:
SOMMEPROD offre une palette beaucoup plus large que SOMME.SI.ENS et quasi infinie de critérisation.
SOMMEPROD permet ici d'écrire en C8 une formule plus courte que l'excellente formule d'Arturo83 :

Code formule :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD('Base Global'!$J:$J;('Base Global'!$A:$A=Campagnes!$B8)*('Base Global'!$B:$B=Campagnes!$G$3)*('Base Global'!$E:$E=Campagnes!$G$5)*SI(Campagnes!$C$3="All Device";1;'Base Global'!$C:$C=Campagnes!$C$3)*SI(Campagnes!$C$5="All Moteur";1;'Base Global'!$D:$D =Campagnes!$C$5))

Cordialement
Claude

[ARTURO83]

Bonjour,

Papouclo, d'accord pour l'utilisation de SOMMEPRO plutôt que SOMME.SI.ENS, mais je crois que votre formule est incomplète, de plus je viens de revérifier dans ma précédente proposition et je constate qu'il manque des éléments, donc résultats faux suivant ce qui est sélectionné en C3 et/ou C5. Je m'étonne que notre ami Avril_05 ne se soit pas manifester pour signaler ces anomalies, à moins qu'il ait fait la correction de lui-même.

Voici la formule corrigée en B3 avec SOMME.SI.ENS

Code formule :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
=SI(ET($C$3="All Device";$C$5="All Moteur");SOMME.SI.ENS('Base Global'!$J:$J;'Base Global'!$E:$E;$G$5;'Base Global'!$B:$B;$G$3;'Base Global'!$A:$A;$B8);
SI(ET($C$3="All Device";$C$5<>"All Moteur");SOMME.SI.ENS('Base Global'!$J:$J;'Base Global'!$E:$E;$G$5;'Base Global'!$B:$B;$G$3;'Base Global'!$A:$A;$B8;'Base Global'!$D:$D;$C$5);
SI(ET($C$3<>"All Device";$C$5<>"All Moteur");SOMME.SI.ENS('Base Global'!$J:$J;'Base Global'!$E:$E;$G$5;'Base Global'!$B:$B;$G$3;'Base Global'!$A:$A;$B8;'Base Global'!$C:$C;$C$3;'Base Global'!$D:$D;$C$5);
SI(ET($C$3<>"All Device";$C$5="All Moteur");SOMME.SI.ENS('Base Global'!$J:$J;'Base Global'!$E:$E;$G$5;'Base Global'!$B:$B;$G$3;'Base Global'!$A:$A;$B8;'Base Global'!$C:$C;$C$3)))))

La même avec SOMMEPROD

Code formule :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
=SI(ET($C$3="All Device";$C$5="All Moteur");SOMMEPROD(('Base Global'!$E:$E=$G$5)*('Base Global'!$B:$B=$G$3)*('Base Global'!$A:$A=$B8);('Base Global'!$J:$J));
SI(ET($C$3="All Device";$C$5<>"All Moteur");SOMMEPROD(('Base Global'!$E:$E=$G$5)*('Base Global'!$B:$B=$G$3)*('Base Global'!$A:$A=$B8)*('Base Global'!$D:$D=$C$5);('Base Global'!$J:$J));
SI(ET($C$3<>"All Device";$C$5<>"All Moteur");SOMMEPROD(('Base Global'!$E:$E=$G$5)*('Base Global'!$B:$B=$G$3)*('Base Global'!$A:$A=$B8)*('Base Global'!$C:$C=$C$3)*('Base Global'!$D:$D=$C$5);('Base Global'!$J:$J));
SI(ET($C$3<>"All Device";$C$5="All Moteur");SOMMEPROD(('Base Global'!$E:$E=$G$5)*('Base Global'!$B:$B=$G$3)*('Base Global'!$A:$A=$B8)*('Base Global'!$C:$C=$C$3);('Base Global'!$J:$J))))))

Comme il y a des éléments en commun dans les 4 parties qui constituent la formule SOMMEPROD, on peut factoriser, certes elle sera plus courte, mais je ne suis pas sûr que cela la rende plus aisée à analyser.

CDlt

[papouclo]

Bonjour Arturo83,
Pourriez vous me dire en quoi ma formule vous semble incomplète ?
Avez-vous vérifié si elle fonctionnait et donnait les mêmes résultats que votre formule (je parle de la dernière) ?
Cordialement
Claude

[ARTURO83]

Bonjour papouclo,

Avez-vous vérifié si elle fonctionnait et donnait les mêmes résultats que votre formule (je parle de la dernière) ?

Bien sûr

Pourriez vous me dire en quoi ma formule vous semble incomplète ?

Sauf erreur de ma part, Il me semble qu"elle ne traite pas tous les cas de figure.

Voici pour comparer nos résultats respectifs
Pièce jointe 554103

Cdlt

[papouclo]

RE,

Voici ce que donne chez moi la même situation sur le classeur que vous aviez envoyé à Avril_05. J'ai mis votre dernière formule en colonne C, la mienne en colonne D et une MFC de comparaison des résultats en colonne E.
Je joins le classeur.

Cordialement
Claude

[ARTURO83]

Bonsoir papouclo,

C'est donc bien une erreur de ma part, le fait d'utiliser SOMMEPROD dans votre formule m'a fait oublier (et ça ne m'est même pas venu à l'idée) que vu sa construction, il s'agissait d'une matricielle (SOMMEPROD en est déjà une en soi) et donc de valider avec CTRL +SHIFT + ENTREE.

Toutes mes excuses.

Cdlt

[danixdb]

Bonjour ARTURO83, papouclo,Avril05, Le Forum,

La formule SOMME.SI.ENS fonctionne aussi bien que la formule SOMMEPROD.
J'obtiens bien les 129 comme indiqué dans le 1er fichier mais je ne prends pas en compte l'année ni le moteur car pas représenté dans le 1er fichier, mais ce ne sont que deux critères à ajouter

Code formule :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME.SI.ENS('Base Global'!$J$2:$J$79;'Base Global'!$A$2:$A$79;Campagnes!$B8;'Base Global'!$C$2:$C$79;SI(Campagnes!$C$3="All Device";"*";Campagnes!$C$3);'Base Global'!$D$2:$D$79;SI(Campagnes!$C$5="All Moteur";"*";Campagnes!$C$5))

J'espère que cela pourra vous aider.
DanixDB


Pour compléter le message ci-dessus, voici la formule complète en pièce jointe.