Discussion :

[Miraie]

Bonjour à tous,

Me voici pris dans une situation problématique. Je dois à l'aide d'une macro construire une seule colonne à l'aide de plusieurs colonnes. Donc toutes mes colonnes peuvent avoir des valeurs dans un nombre imprévisible de ligne qui se suivent, pour un maximum de 2 lignes. en "A" ma colonne que je veux avoir toutes mes valeurs, "F,J,N et R" sont mes autres colonnes que je dois ajouter à la suite de ma colonne "A". Voici mon code.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Sub Rajoutdureste()
 
    Sheets("Tri").Select
    Range("F3:F25").Select
    Selection.Copy
    Range("A2").End (xlDown)
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
    Range("J3:J25").Select
    Selection.Copy
    Range("A2").End (xlDown)
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
    Range("N3:N25").Select
    Selection.Copy
    Range("A2").End (xlDown)
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
    Range("R3:R25").Select
    Selection.Copy
    Range("A2").End (xlDown)
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
    Range("F3:T25").Select
    Selection.ClearContents
End Sub

Quand je lance la macro, j'ai une erreur de compilation (Utilisation incorrecte de la propriété) avec .End de la ligne 6 qui est surlignié. Pourriez-vous m'aider a comprendre mon erreur?

[Invité]

Bonjour,

C'est parce que le code n'est pas complet

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Range("A2").End(xlDown).Row

Mais cette façon de faire n'est pas correcte, vous allez atteindre la dernière cellule de l'onglet. Il faut plutôt partir du bas et ajouter 1 pour atteindre la dernière cellule vide.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
Sub Rajoutdureste()
 
Dim DerniereLigne As Long
 
   With Sheets("Tri")
 
        DerniereLigne = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
        .Range("F3:F25").Copy Destination:=.Cells(DerniereLigne, 1)
 
        DerniereLigne = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
        .Range("J3:J25").Copy Destination:=.Cells(DerniereLigne, 1)
 
        DerniereLigne = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
        .Range("N3:N25").Copy Destination:=.Cells(DerniereLigne, 1)
 
        DerniereLigne = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
        .Range("R3:R25").Copy Destination:=.Cells(DerniereLigne, 1)
 
        .Range("F3:T25").ClearContents
 
  End With
 
 
End Sub

Autre possibilité en respectant votre méthode de copier-coller :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
 
 
Sub Rajoutdureste2()
 
Dim I As Integer
Dim AiresACopier As Variant
 
   AiresACopier = Array("F3:F25", "J3:J25", "N3:N25", "R3:R25")
 
   With Sheets("Tri")
        For I = LBound(AiresACopier) To UBound(AiresACopier)
            CopieZone .Range(AiresACopier(I))
        Next I
        .Range("F3:T25").ClearContents
  End With
 
 
End Sub
 
Sub CopieZone(ByVal CellulesSource As Range)
 
Dim DerniereLigne As Long
 
   With Sheets("Tri")
        DerniereLigne = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
        CellulesSource.Copy
        .Range("A" & DerniereLigne).PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
   End With
 
End Sub

[Menhir]

Juste une petite simplification de la première méthode d'Eric ( ).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub Rajoutdureste()
   With Sheets("Tri")
        .Range("F3:F25").Cut Destination:=.Cells(.Rows.Count, 1).End(xlUp).Offset(1, 0)
        .Range("J3:J25").Cut Destination:=.Cells(.Rows.Count, 1).End(xlUp).Offset(1, 0)
        .Range("N3:N25").Cut Destination:=.Cells(.Rows.Count, 1).End(xlUp).Offset(1, 0)
        .Range("R3:R25").Cut Destination:=.Cells(.Rows.Count, 1).End(xlUp).Offset(1, 0)
  End With
End Sub

Si les colonnes sources sont de dimension variable :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub Rajoutdureste()
   With Sheets("Tri")
        .Range("F3", Cells(Rows.Count, "F").End(xlUp)).Cut Destination:=.Cells(.Rows.Count, 1).End(xlUp).Offset(1, 0)
        .Range("J3", Cells(Rows.Count, "J").End(xlUp)).Cut Destination:=.Cells(.Rows.Count, 1).End(xlUp).Offset(1, 0)
        .Range("N3", Cells(Rows.Count, "N").End(xlUp)).Cut Destination:=.Cells(.Rows.Count, 1).End(xlUp).Offset(1, 0)
        .Range("R3", Cells(Rows.Count, "R").End(xlUp)).Cut Destination:=.Cells(.Rows.Count, 1).End(xlUp).Offset(1, 0)
  End With
End Sub

[Miraie]

Merci pour votre aide, vous m'avez bien aidé.

[Miraie]

Bonjour,

Tout semblais bien fonctionné jusqu'à ce que j'ai une colonne vide. Alors, plutôt que de rien recopier, la macro va chercher l'entête de la colonne en deuxième ligne et fait tout planter. Les valeurs sont numériques alors que l'entête est alphabétique. Il y aurrait-il un moyen de limiter la macro aux lignes sous la deuxième ligne ou mettre une restriction afin qu'elle utilise seulement les chiffres? Ou auriez vous une autre solution à m'apporter?

Merci d'avance pour votre aide

[Invité]

Bonjour,

Remplacez la ligne de code calculant la dernière ligne par celle-ci, mais vous aurez des cellules vides dans votre première colonne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
        DerniereLigne = .UsedRange.SpecialCells(xlCellTypeLastCell).Row + 1

Ou alors collez sur un autre onglet.

[Miraie]

Re bonjour,

En fait la deuxième technique d'Eric KERGRESSE répond très bien et corrige l'erreur a laquelle je fessais face.

Merci encore pour votre aide!

[Invité]

Elle n'est pas différente de la première...