Discussion :

[Crachover]

Bonjour,

J'ai une base de donnée avec une table [Table1], dans cette table j'ai un champ PHOTO de type Pièce jointe.

J'aimerais qu'un fichier (Pic00.jpg) s'ajoute automatiquement dans ce champ à la création d'un enregistrement...

Le fichier image se trouve dans un répertoire IMAGE qui se trouve lui même dans le répertoire de mon fichier ACCESS.

J'ai trouvé ce code, mais je n'arrive pas à l'adapter et à le lancer lors de la création de l'enregistrement...

Pouvez-vous m'aider ???

Merci d'avance

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Function AjouterFichier(strchemin As String, inteleve As Integer) As Boolean
On Error GoTo err
Dim oRst As DAO.Recordset
    ' Ouvre un Recordset sur les fichiers de l'élève passé en paramètre
    Set oRst = CurrentDb.OpenRecordset("SELECT Fichiers FROM tbl_eleve WHERE [N°]=" & inteleve)
    With oRst.Fields(0).Value
        ' Ajoute la pièce jointe
        .AddNew
        ' Lit le fichier
        .Fields("FileData").LoadFromFile strchemin
        .Update
    End With
    AjouterFichier = True
 
fin:
    Set oRst = Nothing
    Exit Function
 
err:
    ' Gestion d'erreur
    Select Case err.Number
        Case 3024:
            MsgBox "Fichier inexistant", vbCritical
        Case 3820:
            MsgBox "Une autre pièce jointe de ce nom existe déjà", vbCritical
        Case Else:
            MsgBox "Erreur inconnue", vbCritical
    End Select
    Resume fin
End Function

[hyperion13]

Bonjour
Nous serons beaucoup de contributeurs à vous conseiller de ne pas enregistrer les images dans les tables. Car le poids de votre bdd risque d'augmenter de façon vertigineuse. Mais bon chacun son truc.
Sinon ici vous avez une contribution simple à mettre en place.

[Crachover]

Bonjour,

C'est aussi mon avis au sujet des pièces jointes, mais c'est juste pour afficher une très petite photo par personne (enregistrement) :-)

Merci pour le lien , je vais regarder à ça...

Bonne journée

EDIT :

J'ai tester votre lien, cela fonctionne, mais il y a un truc assez embêtant... lorsque une image est sélectionnée, cela revient automatiquement au 1er enregistrement... :-/

J'aimerais donc pouvoir utiliser ma première idée ou trouver une solution pour ne pas revenir au 1er enregistrement... :-)


Voici le code qui revient au 1er enregistrement : Forms![frmProperties].Form.Requery

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub cmdDeleteImage_Click()
    Me.memProperyPhotoLink.Enabled = True
    Me.memProperyPhotoLink.SetFocus
    Me.memProperyPhotoLink.Locked = False
    Me.memProperyPhotoLink.Text = ""
    Me.memProperyPhotoLink.SetFocus
    Forms![frmProperties].Form.Requery
    Me.memProperyPhotoLink.Locked = True
    Me.memProperyPhotoLink.Enabled = False
End Sub

J'ai essayé de rajouter ceci juste après, mais cela ne change rien...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
On Error GoTo ErrMan
    DoCmd.GoToRecord , , acPrevious
Fin:
    Exit Sub
ErrMan:
    Resume Fin

[hyperion13]

RE,
Dans ce cas là, il faut lire la totalité de l'article ici.

[Crachover]

Merci pour le lien, mais c'est celui que j'avais trouvé... mais...

Je n'arrive pas à l'adapter...

• Nom du champ pièce jointe : PHOTO
• J'ai bien [N°]
• Nom de ma table : Table1

Maintenant je ne comprends pas la variable : inteleve...

J'ai créé un module avec

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Function AjouterFichier(strchemin As String, inteleve As Integer) As Boolean
On Error GoTo err
Dim oRst As DAO.Recordset
    ' Ouvre un Recordset sur les fichiers de l'élève passé en paramètre
    Set oRst = CurrentDb.OpenRecordset("SELECT PHOTO FROM Table1 WHERE [N°]=" & inteleve)
    With oRst.Fields(0).Value
        ' Ajoute la pièce jointe
        .AddNew
        ' Lit le fichier
        strchemin = "F:\Users\luc\Desktop\ajout fichier access vba/pic00.jpg"
        .Fields("FileData").LoadFromFile strchemin
        .Update
    End With
    AjouterFichier = True
    
fin:
    Set oRst = Nothing
    Exit Function

err:
    ' Gestion d'erreur
    Select Case err.Number
        Case 3024:
            MsgBox "Fichier inexistant", vbCritical
        Case 3820:
            MsgBox "Une autre pièce jointe de ce nom existe déjà", vbCritical
        Case Else:
            MsgBox "Erreur inconnue", vbCritical
    End Select
    Resume fin
End Function

Ps : J'y ai rajouté la ligne : strchemin = "F:\Users\luc\Desktop\ajout fichier access vba/pic00.jpg"

J'ai ensuite créé un formulaire et un bouton avec le code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub Commande7_Click()
Call AjouterFichier
End Function

Et j'ai le message suivant : Erreur de compilation, Argument non facultatif

[hyperion13]

Re,
L13 adaptez selon l'emplacement de votre dossier "IMAGE"
ajouter "Microsoft Office 1x.0 Object Library" dans References
Passez et attachez ce qui suit :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Private Sub Commande7_Click()
Dim rst As DAO.Recordset
Dim rst1 As DAO.Recordset2
Dim fld As DAO.Field2
Dim fdg As Office.FileDialog
Dim strFileName As Variant
 
Set fdg = Application.FileDialog(msoFileDialogFilePicker)
With fdg
    .Title = "Selectionnez le fichier à attacher"
    .ButtonName = "Selection Fichier"
    .AllowMultiSelect = False
    .InitialFileName = "F:\Users\luc\Desktop\...\IMAGE"
    .Filters.Add "Images", "*.bmp; *.gif; *.jpg; *.jpeg", 1
    If .Show <> 0 Then
        Me.Dirty = False
    Set rst = Me.RecordsetClone
    With rst
        .Bookmark = Me.Bookmark
        .Edit
 
        Set rst1 = .Fields("PHOTO").Value
        With rst1
            For Each strFileName In fdg.SelectedItems
                .AddNew
                .Fields("FileData").LoadFromFile strFileName
                .Update
            Next
        End With
        .Update
    End With
    End If
End With
rst.Close
Set rst = Nothing
Set rst1 = Nothing
Set fdg = Nothing
End Sub

[Crachover]

SUPER, Merciiiii

Sans abuser, pourrais-je encore demander quelques chose...

J'aimerais ne pas à avoir à choisir le fichier, toujours le même automatiquement

Encore une fois, un grand merci

[Crachover]

Salut,

Je n'y arrive pas, ne comprenant pas vraiment le code utilisé pour ajouter le fichier, je n'arrive pas à l'adapter pour qu'une image s'enregistre automatiquement à la création d'un enregistrement (ligne)...

Bonne journée

[Crachover]

J'ai trouvé comment ne lancer le code que lors de la création de l'enregistrement, mais toujours pas sans l'explorateur de fichier pour choisir l'image à insérer...

[tee_grandbois]

bonjour,

J'ai trouvé comment ne lancer le code que lors de la création de l'enregistrement, mais toujours pas sans l'explorateur de fichier pour choisir l'image à insérer...

il faut poster le dernier code pour qu'on puisse le corriger mais à priori, l'affichage du choix du fichier se fait dans cette partie du code, il faudrait donc supprimer ces lignes:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Dim fdg As Office.FileDialog                              ' <=== déclaration de l'objet boite de dialogue Fichier
 
Set fdg = Application.FileDialog(msoFileDialogFilePicker) ' <=== construction de l'objet
With fdg                                                  ' <=== ouverture de l'objet et renseignement des paramètres ...
    .Title = "Selectionnez le fichier à attacher"
    .ButtonName = "Selection Fichier"
    .AllowMultiSelect = False
    .InitialFileName = "F:\Users\luc\Desktop\...\IMAGE"
    .Filters.Add "Images", "*.bmp; *.gif; *.jpg; *.jpeg", 1
    If .Show <> 0 Then
    ' ....  etc <==== à priori cette partie de code ne change pas ou est à adapter
    End If	
End With                                                  ' <=== fin du code d'ouverture boite de dialogue
 
Set fdg = Nothing                                         ' <=== destruction de l'objet

[Crachover]

Bonjour,

Merci pour votre réponse, mais mon problème est surtout ou mettre le chemin et le nom du fichier à joindre sans passer par l'explorateur...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Private Sub Commande7_Click()
Dim rst As DAO.Recordset
Dim rst1 As DAO.Recordset2
Dim fld As DAO.Field2
Dim fdg As Office.FileDialog
Dim strFileName As Variant
 
Set fdg = Application.FileDialog(msoFileDialogFilePicker)
With fdg
    .Title = "Selectionnez le fichier à attacher"
    .ButtonName = "Selection Fichier"
    .AllowMultiSelect = False
    .InitialFileName = "F:\Users\luc\Desktop\...\IMAGE"
    .Filters.Add "Images", "*.bmp; *.gif; *.jpg; *.jpeg", 1
    If .Show <> 0 Then
        Me.Dirty = False
    Set rst = Me.RecordsetClone
    With rst
        .Bookmark = Me.Bookmark
        .Edit
 
        Set rst1 = .Fields("PHOTO").Value
        With rst1
            For Each strFileName In fdg.SelectedItems
                .AddNew
                .Fields("FileData").LoadFromFile strFileName
                .Update
            Next
        End With
        .Update
    End With
    End If
End With
rst.Close
Set rst = Nothing
Set rst1 = Nothing
Set fdg = Nothing
End Sub

Bonne soirée

[tee_grandbois]

bonsoir,

Merci pour votre réponse, mais mon problème est surtout ou mettre le chemin et le nom du fichier à joindre sans passer par l'explorateur...

d'où mon message précédent si tu l'as lu jusqu'au bout
et quel est le nom du fichier à joindre ? Ce qui me parait étonnant c'est que si on met le chemin et le nom du fichier directement dans le code, ce sera toujours le même ...
je constate également que c'est toujours le même code que posté précédemment

[Crachover]

Bonjour,

Message lu, jusqu'au bout... mais c'est toujours le même code parce que c'est le code que j'utilise depuis qu'il m'a été donné...

Et oui, cela sera toujours le même fichier, car mon but est d'afficher, donc d'ajouter à la création d'un enregistrement, une image par défaut dans le "cadre" ou se trouvera par la suite une photo de carte d'identité.

Ps : la seule chose que j'ai changé dans le code de départ, c'est le nom de mon champ (pièce jointe) qui est [PHOTO]

Bonne journée.

[tee_grandbois]

bonjour,

Message lu, jusqu'au bout... mais c'est toujours le même code parce que c'est le code que j'utilise depuis qu'il m'a été donné...

peut-être mais j'avais quand même indiqué quelles lignes il fallait supprimer pour ne plus avoir la fenêtre de dialogue pour le choix de fichier:

mais à priori, l'affichage du choix du fichier se fait dans cette partie du code, il faudrait donc supprimer ces lignes:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Dim fdg As Office.FileDialog                              ' <=== déclaration de l'objet boite de dialogue Fichier
 
Set fdg = Application.FileDialog(msoFileDialogFilePicker) ' <=== construction de l'objet
With fdg                                                  ' <=== ouverture de l'objet et renseignement des paramètres ...
    .Title = "Selectionnez le fichier à attacher"
    .ButtonName = "Selection Fichier"
    .AllowMultiSelect = False
    .InitialFileName = "F:\Users\luc\Desktop\...\IMAGE"
    .Filters.Add "Images", "*.bmp; *.gif; *.jpg; *.jpeg", 1
    If .Show <> 0 Then
    ' ....  etc <==== à priori cette partie de code ne change pas ou est à adapter
    End If	
End With                                                  ' <=== fin du code d'ouverture boite de dialogue
 
Set fdg = Nothing                                         ' <=== destruction de l'objet

et je constate que cela n'a pas été appliqué au dernier code posté.

Essaie ce code (pas testé):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Private Sub Commande7_Click()
Dim rst As DAO.Recordset
Dim rst1 As DAO.Recordset2
 
Dim strFileName As Variant
 
strFileName = "F:\Users\luc\Desktop\ajout fichier access vba/pic00.jpg"
 
    Set rst = Me.RecordsetClone
    With rst
        .Bookmark = Me.Bookmark
        .Edit
        Set rst1 = .Fields("PHOTO").Value
 
        With rst1
            .AddNew
            .Fields("FileData").LoadFromFile strFileName 
            .Update
        End With
 
        .Update
    End With
 
End With
rst.Close
Set rst = Nothing
Set rst1 = Nothing
End Sub

[hyperion13]

Voici le code qui revient au 1er enregistrement : Forms![frmProperties].Form.Requery

Remplacez simplement l'expression par Forms![frmProperties].Form.Refresh

[hyperion13]

Sur l'evenement surclick() d'un bouton de commande adaptez nom des objets (tbl et champ) avec le 1er exemple de cette méthode.

[Crachover]

Bonjour,

Ca fonctionne, grand merci